git.squeep.com Git - akkoma/blob - test/pleroma/web/admin_api/controllers/chat_controller_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.AdminAPI.ChatControllerTest do
   6   use Pleroma.Web.ConnCase
   7
   8   import Pleroma.Factory
   9
  10   alias Pleroma.Chat
  11   alias Pleroma.Chat.MessageReference
  12   alias Pleroma.Config
  13   alias Pleroma.ModerationLog
  14   alias Pleroma.Object
  15   alias Pleroma.Repo
  16   alias Pleroma.Web.CommonAPI
  17
  18   defp admin_setup do
  19     admin = insert(:user, is_admin: true)
  20     token = insert(:oauth_admin_token, user: admin)
  21
  22     conn =
  23       build_conn()
  24       |> assign(:user, admin)
  25       |> assign(:token, token)
  26
  27     {:ok, %{admin: admin, token: token, conn: conn}}
  28   end
  29
  30   describe "DELETE /api/pleroma/admin/chats/:id/messages/:message_id" do
  31     setup do: admin_setup()
  32
  33     test "it deletes a message from the chat", %{conn: conn, admin: admin} do
  34       user = insert(:user)
  35       recipient = insert(:user)
  36
  37       {:ok, message} =
  38         CommonAPI.post_chat_message(user, recipient, "Hello darkness my old friend")
  39
  40       object = Object.normalize(message, false)
  41
  42       chat = Chat.get(user.id, recipient.ap_id)
  43       recipient_chat = Chat.get(recipient.id, user.ap_id)
  44
  45       cm_ref = MessageReference.for_chat_and_object(chat, object)
  46       recipient_cm_ref = MessageReference.for_chat_and_object(recipient_chat, object)
  47
  48       result =
  49         conn
  50         |> put_req_header("content-type", "application/json")
  51         |> delete("/api/pleroma/admin/chats/#{chat.id}/messages/#{cm_ref.id}")
  52         |> json_response_and_validate_schema(200)
  53
  54       log_entry = Repo.one(ModerationLog)
  55
  56       assert ModerationLog.get_log_entry_message(log_entry) ==
  57                "@#{admin.nickname} deleted chat message ##{cm_ref.id}"
  58
  59       assert result["id"] == cm_ref.id
  60       refute MessageReference.get_by_id(cm_ref.id)
  61       refute MessageReference.get_by_id(recipient_cm_ref.id)
  62       assert %{data: %{"type" => "Tombstone"}} = Object.get_by_id(object.id)
  63     end
  64   end
  65
  66   describe "GET /api/pleroma/admin/chats/:id/messages" do
  67     setup do: admin_setup()
  68
  69     test "it paginates", %{conn: conn} do
  70       user = insert(:user)
  71       recipient = insert(:user)
  72
  73       Enum.each(1..30, fn _ ->
  74         {:ok, _} = CommonAPI.post_chat_message(user, recipient, "hey")
  75       end)
  76
  77       chat = Chat.get(user.id, recipient.ap_id)
  78
  79       result =
  80         conn
  81         |> get("/api/pleroma/admin/chats/#{chat.id}/messages")
  82         |> json_response_and_validate_schema(200)
  83
  84       assert length(result) == 20
  85
  86       result =
  87         conn
  88         |> get("/api/pleroma/admin/chats/#{chat.id}/messages?max_id=#{List.last(result)["id"]}")
  89         |> json_response_and_validate_schema(200)
  90
  91       assert length(result) == 10
  92     end
  93
  94     test "it returns the messages for a given chat", %{conn: conn} do
  95       user = insert(:user)
  96       other_user = insert(:user)
  97       third_user = insert(:user)
  98
  99       {:ok, _} = CommonAPI.post_chat_message(user, other_user, "hey")
 100       {:ok, _} = CommonAPI.post_chat_message(user, third_user, "hey")
 101       {:ok, _} = CommonAPI.post_chat_message(user, other_user, "how are you?")
 102       {:ok, _} = CommonAPI.post_chat_message(other_user, user, "fine, how about you?")
 103
 104       chat = Chat.get(user.id, other_user.ap_id)
 105
 106       result =
 107         conn
 108         |> get("/api/pleroma/admin/chats/#{chat.id}/messages")
 109         |> json_response_and_validate_schema(200)
 110
 111       result
 112       |> Enum.each(fn message ->
 113         assert message["chat_id"] == chat.id |> to_string()
 114       end)
 115
 116       assert length(result) == 3
 117     end
 118   end
 119
 120   describe "GET /api/pleroma/admin/chats/:id" do
 121     setup do: admin_setup()
 122
 123     test "it returns a chat", %{conn: conn} do
 124       user = insert(:user)
 125       other_user = insert(:user)
 126
 127       {:ok, chat} = Chat.get_or_create(user.id, other_user.ap_id)
 128
 129       result =
 130         conn
 131         |> get("/api/pleroma/admin/chats/#{chat.id}")
 132         |> json_response_and_validate_schema(200)
 133
 134       assert result["id"] == to_string(chat.id)
 135       assert %{} = result["sender"]
 136       assert %{} = result["receiver"]
 137       refute result["account"]
 138     end
 139   end
 140
 141   describe "unauthorized chat moderation" do
 142     setup do
 143       user = insert(:user)
 144       recipient = insert(:user)
 145
 146       {:ok, message} = CommonAPI.post_chat_message(user, recipient, "Yo")
 147       object = Object.normalize(message, false)
 148       chat = Chat.get(user.id, recipient.ap_id)
 149       cm_ref = MessageReference.for_chat_and_object(chat, object)
 150
 151       %{conn: conn} = oauth_access(["read:chats", "write:chats"])
 152       %{conn: conn, chat: chat, cm_ref: cm_ref}
 153     end
 154
 155     test "DELETE /api/pleroma/admin/chats/:id/messages/:message_id", %{
 156       conn: conn,
 157       chat: chat,
 158       cm_ref: cm_ref
 159     } do
 160       conn
 161       |> put_req_header("content-type", "application/json")
 162       |> delete("/api/pleroma/admin/chats/#{chat.id}/messages/#{cm_ref.id}")
 163       |> json_response(403)
 164
 165       assert MessageReference.get_by_id(cm_ref.id) == cm_ref
 166     end
 167
 168     test "GET /api/pleroma/admin/chats/:id/messages", %{conn: conn, chat: chat} do
 169       conn
 170       |> get("/api/pleroma/admin/chats/#{chat.id}/messages")
 171       |> json_response(403)
 172     end
 173
 174     test "GET /api/pleroma/admin/chats/:id", %{conn: conn, chat: chat} do
 175       conn
 176       |> get("/api/pleroma/admin/chats/#{chat.id}")
 177       |> json_response(403)
 178     end
 179   end
 180
 181   describe "unauthenticated chat moderation" do
 182     setup do
 183       user = insert(:user)
 184       recipient = insert(:user)
 185
 186       {:ok, message} = CommonAPI.post_chat_message(user, recipient, "Yo")
 187       object = Object.normalize(message, false)
 188       chat = Chat.get(user.id, recipient.ap_id)
 189       cm_ref = MessageReference.for_chat_and_object(chat, object)
 190
 191       %{conn: build_conn(), chat: chat, cm_ref: cm_ref}
 192     end
 193
 194     test "DELETE /api/pleroma/admin/chats/:id/messages/:message_id", %{
 195       conn: conn,
 196       chat: chat,
 197       cm_ref: cm_ref
 198     } do
 199       conn
 200       |> put_req_header("content-type", "application/json")
 201       |> delete("/api/pleroma/admin/chats/#{chat.id}/messages/#{cm_ref.id}")
 202       |> json_response(403)
 203
 204       assert MessageReference.get_by_id(cm_ref.id) == cm_ref
 205     end
 206
 207     test "GET /api/pleroma/admin/chats/:id/messages", %{conn: conn, chat: chat} do
 208       conn
 209       |> get("/api/pleroma/admin/chats/#{chat.id}/messages")
 210       |> json_response(403)
 211     end
 212
 213     test "GET /api/pleroma/admin/chats/:id", %{conn: conn, chat: chat} do
 214       conn
 215       |> get("/api/pleroma/admin/chats/#{chat.id}")
 216       |> json_response(403)
 217     end
 218   end
 219 end