git.squeep.com Git - akkoma/blob - test/pleroma/integration/mastodon_websocket_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Integration.MastodonWebsocketTest do
   6   use Pleroma.DataCase
   7
   8   import ExUnit.CaptureLog
   9   import Pleroma.Factory
  10
  11   alias Pleroma.Integration.WebsocketClient
  12   alias Pleroma.Web.CommonAPI
  13   alias Pleroma.Web.OAuth
  14
  15   @moduletag needs_streamer: true, capture_log: true
  16
  17   @path Pleroma.Web.Endpoint.url()
  18         |> URI.parse()
  19         |> Map.put(:scheme, "ws")
  20         |> Map.put(:path, "/api/v1/streaming")
  21         |> URI.to_string()
  22
  23   def start_socket(qs \\ nil, headers \\ []) do
  24     path =
  25       case qs do
  26         nil -> @path
  27         qs -> @path <> qs
  28       end
  29
  30     WebsocketClient.start_link(self(), path, headers)
  31   end
  32
  33   test "refuses invalid requests" do
  34     capture_log(fn ->
  35       assert {:error, {404, _}} = start_socket()
  36       assert {:error, {404, _}} = start_socket("?stream=ncjdk")
  37       Process.sleep(30)
  38     end)
  39   end
  40
  41   test "requires authentication and a valid token for protected streams" do
  42     capture_log(fn ->
  43       assert {:error, {401, _}} = start_socket("?stream=user&access_token=aaaaaaaaaaaa")
  44       assert {:error, {401, _}} = start_socket("?stream=user")
  45       Process.sleep(30)
  46     end)
  47   end
  48
  49   test "allows public streams without authentication" do
  50     assert {:ok, _} = start_socket("?stream=public")
  51     assert {:ok, _} = start_socket("?stream=public:local")
  52     assert {:ok, _} = start_socket("?stream=public:remote&instance=lain.com")
  53     assert {:ok, _} = start_socket("?stream=hashtag&tag=lain")
  54   end
  55
  56   test "receives well formatted events" do
  57     user = insert(:user)
  58     {:ok, _} = start_socket("?stream=public")
  59     {:ok, activity} = CommonAPI.post(user, %{status: "nice echo chamber"})
  60
  61     assert_receive {:text, raw_json}, 1_000
  62     assert {:ok, json} = Jason.decode(raw_json)
  63
  64     assert "update" == json["event"]
  65     assert json["payload"]
  66     assert {:ok, json} = Jason.decode(json["payload"])
  67
  68     view_json =
  69       Pleroma.Web.MastodonAPI.StatusView.render("show.json", activity: activity, for: nil)
  70       |> Jason.encode!()
  71       |> Jason.decode!()
  72
  73     assert json == view_json
  74   end
  75
  76   describe "with a valid user token" do
  77     setup do
  78       {:ok, app} =
  79         Pleroma.Repo.insert(
  80           OAuth.App.register_changeset(%OAuth.App{}, %{
  81             client_name: "client",
  82             scopes: ["read"],
  83             redirect_uris: "url"
  84           })
  85         )
  86
  87       user = insert(:user)
  88
  89       {:ok, auth} = OAuth.Authorization.create_authorization(app, user)
  90
  91       {:ok, token} = OAuth.Token.exchange_token(app, auth)
  92
  93       %{user: user, token: token}
  94     end
  95
  96     test "accepts valid tokens", state do
  97       assert {:ok, _} = start_socket("?stream=user&access_token=#{state.token.token}")
  98     end
  99
 100     test "accepts the 'user' stream", %{token: token} = _state do
 101       assert {:ok, _} = start_socket("?stream=user&access_token=#{token.token}")
 102
 103       capture_log(fn ->
 104         assert {:error, {401, _}} = start_socket("?stream=user")
 105         Process.sleep(30)
 106       end)
 107     end
 108
 109     test "accepts the 'user:notification' stream", %{token: token} = _state do
 110       assert {:ok, _} = start_socket("?stream=user:notification&access_token=#{token.token}")
 111
 112       capture_log(fn ->
 113         assert {:error, {401, _}} = start_socket("?stream=user:notification")
 114         Process.sleep(30)
 115       end)
 116     end
 117
 118     test "accepts valid token on Sec-WebSocket-Protocol header", %{token: token} do
 119       assert {:ok, _} = start_socket("?stream=user", [{"Sec-WebSocket-Protocol", token.token}])
 120
 121       capture_log(fn ->
 122         assert {:error, {401, _}} =
 123                  start_socket("?stream=user", [{"Sec-WebSocket-Protocol", "I am a friend"}])
 124
 125         Process.sleep(30)
 126       end)
 127     end
 128   end
 129 end