git.squeep.com Git - akkoma/blob - test/pleroma/integration/mastodon_websocket_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Integration.MastodonWebsocketTest do
   6   # Needs a streamer, needs to stay synchronous
   7   use Pleroma.DataCase
   8
   9   import ExUnit.CaptureLog
  10   import Pleroma.Factory
  11
  12   alias Pleroma.Integration.WebsocketClient
  13   alias Pleroma.Web.CommonAPI
  14   alias Pleroma.Web.OAuth
  15
  16   @moduletag needs_streamer: true, capture_log: true
  17
  18   @path Pleroma.Web.Endpoint.url()
  19         |> URI.parse()
  20         |> Map.put(:scheme, "ws")
  21         |> Map.put(:path, "/api/v1/streaming")
  22         |> URI.to_string()
  23
  24   def start_socket(qs \\ nil, headers \\ []) do
  25     path =
  26       case qs do
  27         nil -> @path
  28         qs -> @path <> qs
  29       end
  30
  31     WebsocketClient.start_link(self(), path, headers)
  32   end
  33
  34   test "refuses invalid requests" do
  35     capture_log(fn ->
  36       assert {:error, {404, _}} = start_socket()
  37       assert {:error, {404, _}} = start_socket("?stream=ncjdk")
  38       Process.sleep(30)
  39     end)
  40   end
  41
  42   test "requires authentication and a valid token for protected streams" do
  43     capture_log(fn ->
  44       assert {:error, {401, _}} = start_socket("?stream=user&access_token=aaaaaaaaaaaa")
  45       assert {:error, {401, _}} = start_socket("?stream=user")
  46       Process.sleep(30)
  47     end)
  48   end
  49
  50   test "allows public streams without authentication" do
  51     assert {:ok, _} = start_socket("?stream=public")
  52     assert {:ok, _} = start_socket("?stream=public:local")
  53     assert {:ok, _} = start_socket("?stream=public:remote&instance=lain.com")
  54     assert {:ok, _} = start_socket("?stream=hashtag&tag=lain")
  55   end
  56
  57   test "receives well formatted events" do
  58     user = insert(:user)
  59     {:ok, _} = start_socket("?stream=public")
  60     {:ok, activity} = CommonAPI.post(user, %{status: "nice echo chamber"})
  61
  62     assert_receive {:text, raw_json}, 1_000
  63     assert {:ok, json} = Jason.decode(raw_json)
  64
  65     assert "update" == json["event"]
  66     assert json["payload"]
  67     assert {:ok, json} = Jason.decode(json["payload"])
  68
  69     view_json =
  70       Pleroma.Web.MastodonAPI.StatusView.render("show.json", activity: activity, for: nil)
  71       |> Jason.encode!()
  72       |> Jason.decode!()
  73
  74     assert json == view_json
  75   end
  76
  77   describe "with a valid user token" do
  78     setup do
  79       {:ok, app} =
  80         Pleroma.Repo.insert(
  81           OAuth.App.register_changeset(%OAuth.App{}, %{
  82             client_name: "client",
  83             scopes: ["read"],
  84             redirect_uris: "url"
  85           })
  86         )
  87
  88       user = insert(:user)
  89
  90       {:ok, auth} = OAuth.Authorization.create_authorization(app, user)
  91
  92       {:ok, token} = OAuth.Token.exchange_token(app, auth)
  93
  94       %{user: user, token: token}
  95     end
  96
  97     test "accepts valid tokens", state do
  98       assert {:ok, _} = start_socket("?stream=user&access_token=#{state.token.token}")
  99     end
 100
 101     test "accepts the 'user' stream", %{token: token} = _state do
 102       assert {:ok, _} = start_socket("?stream=user&access_token=#{token.token}")
 103
 104       capture_log(fn ->
 105         assert {:error, {401, _}} = start_socket("?stream=user")
 106         Process.sleep(30)
 107       end)
 108     end
 109
 110     test "accepts the 'user:notification' stream", %{token: token} = _state do
 111       assert {:ok, _} = start_socket("?stream=user:notification&access_token=#{token.token}")
 112
 113       capture_log(fn ->
 114         assert {:error, {401, _}} = start_socket("?stream=user:notification")
 115         Process.sleep(30)
 116       end)
 117     end
 118
 119     test "accepts valid token on Sec-WebSocket-Protocol header", %{token: token} do
 120       assert {:ok, _} = start_socket("?stream=user", [{"Sec-WebSocket-Protocol", token.token}])
 121
 122       capture_log(fn ->
 123         assert {:error, {401, _}} =
 124                  start_socket("?stream=user", [{"Sec-WebSocket-Protocol", "I am a friend"}])
 125
 126         Process.sleep(30)
 127       end)
 128     end
 129   end
 130 end