git.squeep.com Git - akkoma/blob - test/object_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.ObjectTest do
   6   use Pleroma.DataCase
   7   use Oban.Testing, repo: Pleroma.Repo
   8   import ExUnit.CaptureLog
   9   import Pleroma.Factory
  10   import Tesla.Mock
  11   alias Pleroma.Activity
  12   alias Pleroma.Object
  13   alias Pleroma.Repo
  14   alias Pleroma.Tests.ObanHelpers
  15   alias Pleroma.Web.CommonAPI
  16
  17   setup do
  18     mock(fn env -> apply(HttpRequestMock, :request, [env]) end)
  19     :ok
  20   end
  21
  22   test "returns an object by it's AP id" do
  23     object = insert(:note)
  24     found_object = Object.get_by_ap_id(object.data["id"])
  25
  26     assert object == found_object
  27   end
  28
  29   describe "generic changeset" do
  30     test "it ensures uniqueness of the id" do
  31       object = insert(:note)
  32       cs = Object.change(%Object{}, %{data: %{id: object.data["id"]}})
  33       assert cs.valid?
  34
  35       {:error, _result} = Repo.insert(cs)
  36     end
  37   end
  38
  39   describe "deletion function" do
  40     test "deletes an object" do
  41       object = insert(:note)
  42       found_object = Object.get_by_ap_id(object.data["id"])
  43
  44       assert object == found_object
  45
  46       Object.delete(found_object)
  47
  48       found_object = Object.get_by_ap_id(object.data["id"])
  49
  50       refute object == found_object
  51
  52       assert found_object.data["type"] == "Tombstone"
  53     end
  54
  55     test "ensures cache is cleared for the object" do
  56       object = insert(:note)
  57       cached_object = Object.get_cached_by_ap_id(object.data["id"])
  58
  59       assert object == cached_object
  60
  61       Cachex.put(:web_resp_cache, URI.parse(object.data["id"]).path, "cofe")
  62
  63       Object.delete(cached_object)
  64
  65       {:ok, nil} = Cachex.get(:object_cache, "object:#{object.data["id"]}")
  66       {:ok, nil} = Cachex.get(:web_resp_cache, URI.parse(object.data["id"]).path)
  67
  68       cached_object = Object.get_cached_by_ap_id(object.data["id"])
  69
  70       refute object == cached_object
  71
  72       assert cached_object.data["type"] == "Tombstone"
  73     end
  74   end
  75
  76   describe "delete attachments" do
  77     clear_config([Pleroma.Upload])
  78
  79     test "in subdirectories" do
  80       Pleroma.Config.put([Pleroma.Upload, :uploader], Pleroma.Uploaders.Local)
  81
  82       file = %Plug.Upload{
  83         content_type: "image/jpg",
  84         path: Path.absname("test/fixtures/image.jpg"),
  85         filename: "an_image.jpg"
  86       }
  87
  88       user = insert(:user)
  89
  90       {:ok, %Object{} = attachment} =
  91         Pleroma.Web.ActivityPub.ActivityPub.upload(file, actor: user.ap_id)
  92
  93       %{data: %{"attachment" => [%{"url" => [%{"href" => href}]}]}} =
  94         note = insert(:note, %{user: user, data: %{"attachment" => [attachment.data]}})
  95
  96       uploads_dir = Pleroma.Config.get!([Pleroma.Uploaders.Local, :uploads])
  97
  98       path = href |> Path.dirname() |> Path.basename()
  99
 100       assert {:ok, ["an_image.jpg"]} == File.ls("#{uploads_dir}/#{path}")
 101
 102       Object.delete(note)
 103
 104       ObanHelpers.perform(all_enqueued(worker: Pleroma.Workers.AttachmentsCleanupWorker))
 105
 106       assert Object.get_by_id(attachment.id) == nil
 107
 108       assert {:ok, []} == File.ls("#{uploads_dir}/#{path}")
 109     end
 110
 111     test "with dedupe enabled" do
 112       Pleroma.Config.put([Pleroma.Upload, :uploader], Pleroma.Uploaders.Local)
 113       Pleroma.Config.put([Pleroma.Upload, :filters], [Pleroma.Upload.Filter.Dedupe])
 114
 115       uploads_dir = Pleroma.Config.get!([Pleroma.Uploaders.Local, :uploads])
 116
 117       File.mkdir_p!(uploads_dir)
 118
 119       file = %Plug.Upload{
 120         content_type: "image/jpg",
 121         path: Path.absname("test/fixtures/image.jpg"),
 122         filename: "an_image.jpg"
 123       }
 124
 125       user = insert(:user)
 126
 127       {:ok, %Object{} = attachment} =
 128         Pleroma.Web.ActivityPub.ActivityPub.upload(file, actor: user.ap_id)
 129
 130       %{data: %{"attachment" => [%{"url" => [%{"href" => href}]}]}} =
 131         note = insert(:note, %{user: user, data: %{"attachment" => [attachment.data]}})
 132
 133       filename = Path.basename(href)
 134
 135       assert {:ok, files} = File.ls(uploads_dir)
 136       assert filename in files
 137
 138       Object.delete(note)
 139
 140       ObanHelpers.perform(all_enqueued(worker: Pleroma.Workers.AttachmentsCleanupWorker))
 141
 142       assert Object.get_by_id(attachment.id) == nil
 143       assert {:ok, files} = File.ls(uploads_dir)
 144       refute filename in files
 145     end
 146
 147     test "with objects that have legacy data.url attribute" do
 148       Pleroma.Config.put([Pleroma.Upload, :uploader], Pleroma.Uploaders.Local)
 149
 150       file = %Plug.Upload{
 151         content_type: "image/jpg",
 152         path: Path.absname("test/fixtures/image.jpg"),
 153         filename: "an_image.jpg"
 154       }
 155
 156       user = insert(:user)
 157
 158       {:ok, %Object{} = attachment} =
 159         Pleroma.Web.ActivityPub.ActivityPub.upload(file, actor: user.ap_id)
 160
 161       {:ok, %Object{}} = Object.create(%{url: "https://google.com", actor: user.ap_id})
 162
 163       %{data: %{"attachment" => [%{"url" => [%{"href" => href}]}]}} =
 164         note = insert(:note, %{user: user, data: %{"attachment" => [attachment.data]}})
 165
 166       uploads_dir = Pleroma.Config.get!([Pleroma.Uploaders.Local, :uploads])
 167
 168       path = href |> Path.dirname() |> Path.basename()
 169
 170       assert {:ok, ["an_image.jpg"]} == File.ls("#{uploads_dir}/#{path}")
 171
 172       Object.delete(note)
 173
 174       ObanHelpers.perform(all_enqueued(worker: Pleroma.Workers.AttachmentsCleanupWorker))
 175
 176       assert Object.get_by_id(attachment.id) == nil
 177
 178       assert {:ok, []} == File.ls("#{uploads_dir}/#{path}")
 179     end
 180   end
 181
 182   describe "normalizer" do
 183     test "fetches unknown objects by default" do
 184       %Object{} =
 185         object = Object.normalize("http://mastodon.example.org/@admin/99541947525187367")
 186
 187       assert object.data["url"] == "http://mastodon.example.org/@admin/99541947525187367"
 188     end
 189
 190     test "fetches unknown objects when fetch_remote is explicitly true" do
 191       %Object{} =
 192         object = Object.normalize("http://mastodon.example.org/@admin/99541947525187367", true)
 193
 194       assert object.data["url"] == "http://mastodon.example.org/@admin/99541947525187367"
 195     end
 196
 197     test "does not fetch unknown objects when fetch_remote is false" do
 198       assert is_nil(
 199                Object.normalize("http://mastodon.example.org/@admin/99541947525187367", false)
 200              )
 201     end
 202   end
 203
 204   describe "get_by_id_and_maybe_refetch" do
 205     setup do
 206       mock(fn
 207         %{method: :get, url: "https://patch.cx/objects/9a172665-2bc5-452d-8428-2361d4c33b1d"} ->
 208           %Tesla.Env{status: 200, body: File.read!("test/fixtures/tesla_mock/poll_original.json")}
 209
 210         env ->
 211           apply(HttpRequestMock, :request, [env])
 212       end)
 213
 214       mock_modified = fn resp ->
 215         mock(fn
 216           %{method: :get, url: "https://patch.cx/objects/9a172665-2bc5-452d-8428-2361d4c33b1d"} ->
 217             resp
 218
 219           env ->
 220             apply(HttpRequestMock, :request, [env])
 221         end)
 222       end
 223
 224       on_exit(fn -> mock(fn env -> apply(HttpRequestMock, :request, [env]) end) end)
 225
 226       [mock_modified: mock_modified]
 227     end
 228
 229     test "refetches if the time since the last refetch is greater than the interval", %{
 230       mock_modified: mock_modified
 231     } do
 232       %Object{} =
 233         object = Object.normalize("https://patch.cx/objects/9a172665-2bc5-452d-8428-2361d4c33b1d")
 234
 235       Object.set_cache(object)
 236
 237       assert Enum.at(object.data["oneOf"], 0)["replies"]["totalItems"] == 4
 238       assert Enum.at(object.data["oneOf"], 1)["replies"]["totalItems"] == 0
 239
 240       mock_modified.(%Tesla.Env{
 241         status: 200,
 242         body: File.read!("test/fixtures/tesla_mock/poll_modified.json")
 243       })
 244
 245       updated_object = Object.get_by_id_and_maybe_refetch(object.id, interval: -1)
 246       object_in_cache = Object.get_cached_by_ap_id(object.data["id"])
 247       assert updated_object == object_in_cache
 248       assert Enum.at(updated_object.data["oneOf"], 0)["replies"]["totalItems"] == 8
 249       assert Enum.at(updated_object.data["oneOf"], 1)["replies"]["totalItems"] == 3
 250     end
 251
 252     test "returns the old object if refetch fails", %{mock_modified: mock_modified} do
 253       %Object{} =
 254         object = Object.normalize("https://patch.cx/objects/9a172665-2bc5-452d-8428-2361d4c33b1d")
 255
 256       Object.set_cache(object)
 257
 258       assert Enum.at(object.data["oneOf"], 0)["replies"]["totalItems"] == 4
 259       assert Enum.at(object.data["oneOf"], 1)["replies"]["totalItems"] == 0
 260
 261       assert capture_log(fn ->
 262                mock_modified.(%Tesla.Env{status: 404, body: ""})
 263
 264                updated_object = Object.get_by_id_and_maybe_refetch(object.id, interval: -1)
 265                object_in_cache = Object.get_cached_by_ap_id(object.data["id"])
 266                assert updated_object == object_in_cache
 267                assert Enum.at(updated_object.data["oneOf"], 0)["replies"]["totalItems"] == 4
 268                assert Enum.at(updated_object.data["oneOf"], 1)["replies"]["totalItems"] == 0
 269              end) =~
 270                "[error] Couldn't refresh https://patch.cx/objects/9a172665-2bc5-452d-8428-2361d4c33b1d"
 271     end
 272
 273     test "does not refetch if the time since the last refetch is greater than the interval", %{
 274       mock_modified: mock_modified
 275     } do
 276       %Object{} =
 277         object = Object.normalize("https://patch.cx/objects/9a172665-2bc5-452d-8428-2361d4c33b1d")
 278
 279       Object.set_cache(object)
 280
 281       assert Enum.at(object.data["oneOf"], 0)["replies"]["totalItems"] == 4
 282       assert Enum.at(object.data["oneOf"], 1)["replies"]["totalItems"] == 0
 283
 284       mock_modified.(%Tesla.Env{
 285         status: 200,
 286         body: File.read!("test/fixtures/tesla_mock/poll_modified.json")
 287       })
 288
 289       updated_object = Object.get_by_id_and_maybe_refetch(object.id, interval: 100)
 290       object_in_cache = Object.get_cached_by_ap_id(object.data["id"])
 291       assert updated_object == object_in_cache
 292       assert Enum.at(updated_object.data["oneOf"], 0)["replies"]["totalItems"] == 4
 293       assert Enum.at(updated_object.data["oneOf"], 1)["replies"]["totalItems"] == 0
 294     end
 295
 296     test "preserves internal fields on refetch", %{mock_modified: mock_modified} do
 297       %Object{} =
 298         object = Object.normalize("https://patch.cx/objects/9a172665-2bc5-452d-8428-2361d4c33b1d")
 299
 300       Object.set_cache(object)
 301
 302       assert Enum.at(object.data["oneOf"], 0)["replies"]["totalItems"] == 4
 303       assert Enum.at(object.data["oneOf"], 1)["replies"]["totalItems"] == 0
 304
 305       user = insert(:user)
 306       activity = Activity.get_create_by_object_ap_id(object.data["id"])
 307       {:ok, _activity, object} = CommonAPI.favorite(activity.id, user)
 308
 309       assert object.data["like_count"] == 1
 310
 311       mock_modified.(%Tesla.Env{
 312         status: 200,
 313         body: File.read!("test/fixtures/tesla_mock/poll_modified.json")
 314       })
 315
 316       updated_object = Object.get_by_id_and_maybe_refetch(object.id, interval: -1)
 317       object_in_cache = Object.get_cached_by_ap_id(object.data["id"])
 318       assert updated_object == object_in_cache
 319       assert Enum.at(updated_object.data["oneOf"], 0)["replies"]["totalItems"] == 8
 320       assert Enum.at(updated_object.data["oneOf"], 1)["replies"]["totalItems"] == 3
 321
 322       assert updated_object.data["like_count"] == 1
 323     end
 324   end
 325 end