git.squeep.com Git - akkoma/blob - test/mix/tasks/pleroma/database_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Mix.Tasks.Pleroma.DatabaseTest do
   6   use Pleroma.DataCase
   7   use Oban.Testing, repo: Pleroma.Repo
   8
   9   alias Pleroma.Activity
  10   alias Pleroma.Object
  11   alias Pleroma.Repo
  12   alias Pleroma.User
  13   alias Pleroma.Web.CommonAPI
  14
  15   import Pleroma.Factory
  16
  17   setup_all do
  18     Mix.shell(Mix.Shell.Process)
  19
  20     on_exit(fn ->
  21       Mix.shell(Mix.Shell.IO)
  22     end)
  23
  24     :ok
  25   end
  26
  27   describe "running remove_embedded_objects" do
  28     test "it replaces objects with references" do
  29       user = insert(:user)
  30       {:ok, activity} = CommonAPI.post(user, %{status: "test"})
  31       new_data = Map.put(activity.data, "object", activity.object.data)
  32
  33       {:ok, activity} =
  34         activity
  35         |> Activity.change(%{data: new_data})
  36         |> Repo.update()
  37
  38       assert is_map(activity.data["object"])
  39
  40       Mix.Tasks.Pleroma.Database.run(["remove_embedded_objects"])
  41
  42       activity = Activity.get_by_id_with_object(activity.id)
  43       assert is_binary(activity.data["object"])
  44     end
  45   end
  46
  47   describe "prune_objects" do
  48     test "it prunes old objects from the database" do
  49       insert(:note)
  50       deadline = Pleroma.Config.get([:instance, :remote_post_retention_days]) + 1
  51
  52       date =
  53         Timex.now()
  54         |> Timex.shift(days: -deadline)
  55         |> Timex.to_naive_datetime()
  56         |> NaiveDateTime.truncate(:second)
  57
  58       %{id: id} =
  59         :note
  60         |> insert()
  61         |> Ecto.Changeset.change(%{inserted_at: date})
  62         |> Repo.update!()
  63
  64       assert length(Repo.all(Object)) == 2
  65
  66       Mix.Tasks.Pleroma.Database.run(["prune_objects"])
  67
  68       assert length(Repo.all(Object)) == 1
  69       refute Object.get_by_id(id)
  70     end
  71   end
  72
  73   describe "running update_users_following_followers_counts" do
  74     test "following and followers count are updated" do
  75       [user, user2] = insert_pair(:user)
  76       {:ok, %User{} = user, _user2} = User.follow(user, user2)
  77
  78       following = User.following(user)
  79
  80       assert length(following) == 2
  81       assert user.follower_count == 0
  82
  83       {:ok, user} =
  84         user
  85         |> Ecto.Changeset.change(%{follower_count: 3})
  86         |> Repo.update()
  87
  88       assert user.follower_count == 3
  89
  90       assert :ok == Mix.Tasks.Pleroma.Database.run(["update_users_following_followers_counts"])
  91
  92       user = User.get_by_id(user.id)
  93
  94       assert length(User.following(user)) == 2
  95       assert user.follower_count == 0
  96     end
  97   end
  98
  99   describe "running fix_likes_collections" do
 100     test "it turns OrderedCollection likes into empty arrays" do
 101       [user, user2] = insert_pair(:user)
 102
 103       {:ok, %{id: id, object: object}} = CommonAPI.post(user, %{status: "test"})
 104       {:ok, %{object: object2}} = CommonAPI.post(user, %{status: "test test"})
 105
 106       CommonAPI.favorite(user2, id)
 107
 108       likes = %{
 109         "first" =>
 110           "http://mastodon.example.org/objects/dbdbc507-52c8-490d-9b7c-1e1d52e5c132/likes?page=1",
 111         "id" => "http://mastodon.example.org/objects/dbdbc507-52c8-490d-9b7c-1e1d52e5c132/likes",
 112         "totalItems" => 3,
 113         "type" => "OrderedCollection"
 114       }
 115
 116       new_data = Map.put(object2.data, "likes", likes)
 117
 118       object2
 119       |> Ecto.Changeset.change(%{data: new_data})
 120       |> Repo.update()
 121
 122       assert length(Object.get_by_id(object.id).data["likes"]) == 1
 123       assert is_map(Object.get_by_id(object2.id).data["likes"])
 124
 125       assert :ok == Mix.Tasks.Pleroma.Database.run(["fix_likes_collections"])
 126
 127       assert length(Object.get_by_id(object.id).data["likes"]) == 1
 128       assert Enum.empty?(Object.get_by_id(object2.id).data["likes"])
 129     end
 130   end
 131
 132   describe "ensure_expiration" do
 133     test "it adds to expiration old statuses" do
 134       activity1 = insert(:note_activity)
 135
 136       {:ok, inserted_at, 0} = DateTime.from_iso8601("2015-01-23T23:50:07Z")
 137       activity2 = insert(:note_activity, %{inserted_at: inserted_at})
 138
 139       %{id: activity_id3} = insert(:note_activity)
 140
 141       expires_at = DateTime.add(DateTime.utc_now(), 60 * 61)
 142
 143       Pleroma.Workers.PurgeExpiredActivity.enqueue(%{
 144         activity_id: activity_id3,
 145         expires_at: expires_at
 146       })
 147
 148       Mix.Tasks.Pleroma.Database.run(["ensure_expiration"])
 149
 150       assert_enqueued(
 151         worker: Pleroma.Workers.PurgeExpiredActivity,
 152         args: %{activity_id: activity1.id},
 153         scheduled_at:
 154           activity1.inserted_at
 155           |> DateTime.from_naive!("Etc/UTC")
 156           |> Timex.shift(days: 365)
 157       )
 158
 159       assert_enqueued(
 160         worker: Pleroma.Workers.PurgeExpiredActivity,
 161         args: %{activity_id: activity2.id},
 162         scheduled_at:
 163           activity2.inserted_at
 164           |> DateTime.from_naive!("Etc/UTC")
 165           |> Timex.shift(days: 365)
 166       )
 167
 168       assert_enqueued(
 169         worker: Pleroma.Workers.PurgeExpiredActivity,
 170         args: %{activity_id: activity_id3},
 171         scheduled_at: expires_at
 172       )
 173     end
 174   end
 175 end