git.squeep.com Git - akkoma/blob - test/media_proxy_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.MediaProxyTest do
   6   use ExUnit.Case
   7   import Pleroma.Web.MediaProxy
   8   alias Pleroma.Web.MediaProxy.MediaProxyController
   9
  10   setup do
  11     enabled = Pleroma.Config.get([:media_proxy, :enabled])
  12     on_exit(fn -> Pleroma.Config.put([:media_proxy, :enabled], enabled) end)
  13     :ok
  14   end
  15
  16   describe "when enabled" do
  17     setup do
  18       Pleroma.Config.put([:media_proxy, :enabled], true)
  19       :ok
  20     end
  21
  22     test "ignores invalid url" do
  23       assert url(nil) == nil
  24       assert url("") == nil
  25     end
  26
  27     test "ignores relative url" do
  28       assert url("/local") == "/local"
  29       assert url("/") == "/"
  30     end
  31
  32     test "ignores local url" do
  33       local_url = Pleroma.Web.Endpoint.url() <> "/hello"
  34       local_root = Pleroma.Web.Endpoint.url()
  35       assert url(local_url) == local_url
  36       assert url(local_root) == local_root
  37     end
  38
  39     test "encodes and decodes URL" do
  40       url = "https://pleroma.soykaf.com/static/logo.png"
  41       encoded = url(url)
  42
  43       assert String.starts_with?(
  44                encoded,
  45                Pleroma.Config.get([:media_proxy, :base_url], Pleroma.Web.base_url())
  46              )
  47
  48       assert String.ends_with?(encoded, "/logo.png")
  49
  50       assert decode_result(encoded) == url
  51     end
  52
  53     test "encodes and decodes URL without a path" do
  54       url = "https://pleroma.soykaf.com"
  55       encoded = url(url)
  56       assert decode_result(encoded) == url
  57     end
  58
  59     test "encodes and decodes URL without an extension" do
  60       url = "https://pleroma.soykaf.com/path/"
  61       encoded = url(url)
  62       assert String.ends_with?(encoded, "/path")
  63       assert decode_result(encoded) == url
  64     end
  65
  66     test "encodes and decodes URL and ignores query params for the path" do
  67       url = "https://pleroma.soykaf.com/static/logo.png?93939393939&bunny=true"
  68       encoded = url(url)
  69       assert String.ends_with?(encoded, "/logo.png")
  70       assert decode_result(encoded) == url
  71     end
  72
  73     # Some of the signed url expect the special character in the url to be same
  74     # for the proxy to work.
  75     # Issue https://git.pleroma.social/pleroma/pleroma/issues/1055
  76     test "ensures urls are maintained (character are not encoded or decoded)" do
  77       assert decode_result(url("https://pleroma.social/Hello world.jpg")) ==
  78                "https://pleroma.social/Hello world.jpg"
  79
  80       assert decode_result(url("https://pleroma.social/Hello%20world.jpg")) ==
  81                "https://pleroma.social/Hello%20world.jpg"
  82     end
  83
  84     test "validates signature" do
  85       secret_key_base = Pleroma.Config.get([Pleroma.Web.Endpoint, :secret_key_base])
  86
  87       on_exit(fn ->
  88         Pleroma.Config.put([Pleroma.Web.Endpoint, :secret_key_base], secret_key_base)
  89       end)
  90
  91       encoded = url("https://pleroma.social")
  92
  93       Pleroma.Config.put(
  94         [Pleroma.Web.Endpoint, :secret_key_base],
  95         "00000000000000000000000000000000000000000000000"
  96       )
  97
  98       [_, "proxy", sig, base64 | _] = URI.parse(encoded).path |> String.split("/")
  99       assert decode_url(sig, base64) == {:error, :invalid_signature}
 100     end
 101
 102     test "filename_matches matches url encoded paths" do
 103       assert MediaProxyController.filename_matches(
 104                true,
 105                "/Hello%20world.jpg",
 106                "http://pleroma.social/Hello world.jpg"
 107              ) == :ok
 108
 109       assert MediaProxyController.filename_matches(
 110                true,
 111                "/Hello%20world.jpg",
 112                "http://pleroma.social/Hello%20world.jpg"
 113              ) == :ok
 114     end
 115
 116     test "filename_matches matches non-url encoded paths" do
 117       assert MediaProxyController.filename_matches(
 118                true,
 119                "/Hello world.jpg",
 120                "http://pleroma.social/Hello%20world.jpg"
 121              ) == :ok
 122
 123       assert MediaProxyController.filename_matches(
 124                true,
 125                "/Hello world.jpg",
 126                "http://pleroma.social/Hello world.jpg"
 127              ) == :ok
 128     end
 129
 130     test "uses the configured base_url" do
 131       base_url = Pleroma.Config.get([:media_proxy, :base_url])
 132
 133       if base_url do
 134         on_exit(fn ->
 135           Pleroma.Config.put([:media_proxy, :base_url], base_url)
 136         end)
 137       end
 138
 139       Pleroma.Config.put([:media_proxy, :base_url], "https://cache.pleroma.social")
 140
 141       url = "https://pleroma.soykaf.com/static/logo.png"
 142       encoded = url(url)
 143
 144       assert String.starts_with?(encoded, Pleroma.Config.get([:media_proxy, :base_url]))
 145     end
 146
 147     # https://git.pleroma.social/pleroma/pleroma/issues/580
 148     test "encoding S3 links (must preserve `%2F`)" do
 149       url =
 150         "https://s3.amazonaws.com/example/test.png?X-Amz-Credential=your-access-key-id%2F20130721%2Fus-east-1%2Fs3%2Faws4_request"
 151
 152       encoded = url(url)
 153       assert decode_result(encoded) == url
 154     end
 155
 156     test "does not change whitelisted urls" do
 157       upload_config = Pleroma.Config.get([Pleroma.Upload])
 158       media_url = "https://media.pleroma.social"
 159       Pleroma.Config.put([Pleroma.Upload, :base_url], media_url)
 160       Pleroma.Config.put([:media_proxy, :whitelist], ["media.pleroma.social"])
 161       Pleroma.Config.put([:media_proxy, :base_url], "https://cache.pleroma.social")
 162
 163       url = "#{media_url}/static/logo.png"
 164       encoded = url(url)
 165
 166       assert String.starts_with?(encoded, media_url)
 167
 168       Pleroma.Config.put([Pleroma.Upload], upload_config)
 169     end
 170   end
 171
 172   describe "when disabled" do
 173     setup do
 174       enabled = Pleroma.Config.get([:media_proxy, :enabled])
 175
 176       if enabled do
 177         Pleroma.Config.put([:media_proxy, :enabled], false)
 178
 179         on_exit(fn ->
 180           Pleroma.Config.put([:media_proxy, :enabled], enabled)
 181           :ok
 182         end)
 183       end
 184
 185       :ok
 186     end
 187
 188     test "does not encode remote urls" do
 189       assert url("https://google.fr") == "https://google.fr"
 190     end
 191   end
 192
 193   defp decode_result(encoded) do
 194     [_, "proxy", sig, base64 | _] = URI.parse(encoded).path |> String.split("/")
 195     {:ok, decoded} = decode_url(sig, base64)
 196     decoded
 197   end
 198
 199   test "mediaproxy whitelist" do
 200     Pleroma.Config.put([:media_proxy, :enabled], true)
 201     Pleroma.Config.put([:media_proxy, :whitelist], ["google.com", "feld.me"])
 202     url = "https://feld.me/foo.png"
 203
 204     unencoded = url(url)
 205     assert unencoded == url
 206   end
 207 end