git.squeep.com Git - akkoma/blob - test/media_proxy_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.MediaProxyTest do
   6   use ExUnit.Case
   7   import Pleroma.Web.MediaProxy
   8   alias Pleroma.Web.MediaProxy.MediaProxyController
   9
  10   setup do
  11     enabled = Pleroma.Config.get([:media_proxy, :enabled])
  12     on_exit(fn -> Pleroma.Config.put([:media_proxy, :enabled], enabled) end)
  13     :ok
  14   end
  15
  16   describe "when enabled" do
  17     setup do
  18       Pleroma.Config.put([:media_proxy, :enabled], true)
  19       :ok
  20     end
  21
  22     test "ignores invalid url" do
  23       assert url(nil) == nil
  24       assert url("") == nil
  25     end
  26
  27     test "ignores relative url" do
  28       assert url("/local") == "/local"
  29       assert url("/") == "/"
  30     end
  31
  32     test "ignores local url" do
  33       local_url = Pleroma.Web.Endpoint.url() <> "/hello"
  34       local_root = Pleroma.Web.Endpoint.url()
  35       assert url(local_url) == local_url
  36       assert url(local_root) == local_root
  37     end
  38
  39     test "encodes and decodes URL" do
  40       url = "https://pleroma.soykaf.com/static/logo.png"
  41       encoded = url(url)
  42
  43       assert String.starts_with?(
  44                encoded,
  45                Pleroma.Config.get([:media_proxy, :base_url], Pleroma.Web.base_url())
  46              )
  47
  48       assert String.ends_with?(encoded, "/logo.png")
  49
  50       assert decode_result(encoded) == url
  51     end
  52
  53     test "encodes and decodes URL without a path" do
  54       url = "https://pleroma.soykaf.com"
  55       encoded = url(url)
  56       assert decode_result(encoded) == url
  57     end
  58
  59     test "encodes and decodes URL without an extension" do
  60       url = "https://pleroma.soykaf.com/path/"
  61       encoded = url(url)
  62       assert String.ends_with?(encoded, "/path")
  63       assert decode_result(encoded) == url
  64     end
  65
  66     test "encodes and decodes URL and ignores query params for the path" do
  67       url = "https://pleroma.soykaf.com/static/logo.png?93939393939&bunny=true"
  68       encoded = url(url)
  69       assert String.ends_with?(encoded, "/logo.png")
  70       assert decode_result(encoded) == url
  71     end
  72
  73     # Some of the signed url expect the special character in the url to be same
  74     # for the proxy to work.
  75     # Issue https://git.pleroma.social/pleroma/pleroma/issues/1055
  76     test "ensures urls are maintained (character are not encoded or decoded)" do
  77       assert decode_result(url("https://pleroma.social/Hello world.jpg")) ==
  78                "https://pleroma.social/Hello world.jpg"
  79
  80       assert decode_result(url("https://pleroma.social/Hello%20world.jpg")) ==
  81                "https://pleroma.social/Hello%20world.jpg"
  82     end
  83
  84     test "validates signature" do
  85       secret_key_base = Pleroma.Config.get([Pleroma.Web.Endpoint, :secret_key_base])
  86
  87       on_exit(fn ->
  88         Pleroma.Config.put([Pleroma.Web.Endpoint, :secret_key_base], secret_key_base)
  89       end)
  90
  91       encoded = url("https://pleroma.social")
  92
  93       Pleroma.Config.put(
  94         [Pleroma.Web.Endpoint, :secret_key_base],
  95         "00000000000000000000000000000000000000000000000"
  96       )
  97
  98       [_, "proxy", sig, base64 | _] = URI.parse(encoded).path |> String.split("/")
  99       assert decode_url(sig, base64) == {:error, :invalid_signature}
 100     end
 101
 102     test "filename_matches matches url encoded paths" do
 103       assert MediaProxyController.filename_matches(
 104                true,
 105                "/Hello%20world.jpg",
 106                "http://pleroma.social/Hello world.jpg"
 107              ) == :ok
 108
 109       assert MediaProxyController.filename_matches(
 110                true,
 111                "/Hello%20world.jpg",
 112                "http://pleroma.social/Hello%20world.jpg"
 113              ) == :ok
 114     end
 115
 116     test "filename_matches matches non-url encoded paths" do
 117       assert MediaProxyController.filename_matches(
 118                true,
 119                "/Hello world.jpg",
 120                "http://pleroma.social/Hello%20world.jpg"
 121              ) == :ok
 122
 123       assert MediaProxyController.filename_matches(
 124                true,
 125                "/Hello world.jpg",
 126                "http://pleroma.social/Hello world.jpg"
 127              ) == :ok
 128     end
 129
 130     test "uses the configured base_url" do
 131       base_url = Pleroma.Config.get([:media_proxy, :base_url])
 132
 133       if base_url do
 134         on_exit(fn ->
 135           Pleroma.Config.put([:media_proxy, :base_url], base_url)
 136         end)
 137       end
 138
 139       Pleroma.Config.put([:media_proxy, :base_url], "https://cache.pleroma.social")
 140
 141       url = "https://pleroma.soykaf.com/static/logo.png"
 142       encoded = url(url)
 143
 144       assert String.starts_with?(encoded, Pleroma.Config.get([:media_proxy, :base_url]))
 145     end
 146
 147     # https://git.pleroma.social/pleroma/pleroma/issues/580
 148     test "preserve ASCII encoding" do
 149       url =
 150         "https://pleroma.com/%20/%21/%22/%23/%24/%25/%26/%27/%28/%29/%2A/%2B/%2C/%2D/%2E/%2F/%30/%31/%32/%33/%34/%35/%36/%37/%38/%39/%3A/%3B/%3C/%3D/%3E/%3F/%40/%41/%42/%43/%44/%45/%46/%47/%48/%49/%4A/%4B/%4C/%4D/%4E/%4F/%50/%51/%52/%53/%54/%55/%56/%57/%58/%59/%5A/%5B/%5C/%5D/%5E/%5F/%60/%61/%62/%63/%64/%65/%66/%67/%68/%69/%6A/%6B/%6C/%6D/%6E/%6F/%70/%71/%72/%73/%74/%75/%76/%77/%78/%79/%7A/%7B/%7C/%7D/%7E/%7F/%80/%81/%82/%83/%84/%85/%86/%87/%88/%89/%8A/%8B/%8C/%8D/%8E/%8F/%90/%91/%92/%93/%94/%95/%96/%97/%98/%99/%9A/%9B/%9C/%9D/%9E/%9F/%C2%A0/%A1/%A2/%A3/%A4/%A5/%A6/%A7/%A8/%A9/%AA/%AB/%AC/%C2%AD/%AE/%AF/%B0/%B1/%B2/%B3/%B4/%B5/%B6/%B7/%B8/%B9/%BA/%BB/%BC/%BD/%BE/%BF/%C0/%C1/%C2/%C3/%C4/%C5/%C6/%C7/%C8/%C9/%CA/%CB/%CC/%CD/%CE/%CF/%D0/%D1/%D2/%D3/%D4/%D5/%D6/%D7/%D8/%D9/%DA/%DB/%DC/%DD/%DE/%DF/%E0/%E1/%E2/%E3/%E4/%E5/%E6/%E7/%E8/%E9/%EA/%EB/%EC/%ED/%EE/%EF/%F0/%F1/%F2/%F3/%F4/%F5/%F6/%F7/%F8/%F9/%FA/%FB/%FC/%FD/%FE/%FF"
 151
 152       encoded = url(url)
 153       assert decode_result(encoded) == url
 154     end
 155
 156     # This includes unsafe/reserved characters which are not interpreted as part of the URL
 157     # and would otherwise have to be ASCII encoded. It is our role to ensure the proxied URL
 158     # is unmodified, so we are testing these characters anyway.
 159     test "preserve non-unicode characters per RFC3986" do
 160       url =
 161         "https://pleroma.com/ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz1234567890-._~:/?#[]@!$&'()*+,;=|^`{}"
 162
 163       encoded = url(url)
 164       assert decode_result(encoded) == url
 165     end
 166
 167     test "does not change whitelisted urls" do
 168       upload_config = Pleroma.Config.get([Pleroma.Upload])
 169       media_url = "https://media.pleroma.social"
 170       Pleroma.Config.put([Pleroma.Upload, :base_url], media_url)
 171       Pleroma.Config.put([:media_proxy, :whitelist], ["media.pleroma.social"])
 172       Pleroma.Config.put([:media_proxy, :base_url], "https://cache.pleroma.social")
 173
 174       url = "#{media_url}/static/logo.png"
 175       encoded = url(url)
 176
 177       assert String.starts_with?(encoded, media_url)
 178
 179       Pleroma.Config.put([Pleroma.Upload], upload_config)
 180     end
 181   end
 182
 183   describe "when disabled" do
 184     setup do
 185       enabled = Pleroma.Config.get([:media_proxy, :enabled])
 186
 187       if enabled do
 188         Pleroma.Config.put([:media_proxy, :enabled], false)
 189
 190         on_exit(fn ->
 191           Pleroma.Config.put([:media_proxy, :enabled], enabled)
 192           :ok
 193         end)
 194       end
 195
 196       :ok
 197     end
 198
 199     test "does not encode remote urls" do
 200       assert url("https://google.fr") == "https://google.fr"
 201     end
 202   end
 203
 204   defp decode_result(encoded) do
 205     [_, "proxy", sig, base64 | _] = URI.parse(encoded).path |> String.split("/")
 206     {:ok, decoded} = decode_url(sig, base64)
 207     decoded
 208   end
 209
 210   test "mediaproxy whitelist" do
 211     Pleroma.Config.put([:media_proxy, :enabled], true)
 212     Pleroma.Config.put([:media_proxy, :whitelist], ["google.com", "feld.me"])
 213     url = "https://feld.me/foo.png"
 214
 215     unencoded = url(url)
 216     assert unencoded == url
 217   end
 218 end