git.squeep.com Git - akkoma/blob - test/media_proxy_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.MediaProxyTest do
   6   use ExUnit.Case
   7   import Pleroma.Web.MediaProxy
   8   alias Pleroma.Web.MediaProxy.MediaProxyController
   9
  10   setup do
  11     enabled = Pleroma.Config.get([:media_proxy, :enabled])
  12     on_exit(fn -> Pleroma.Config.put([:media_proxy, :enabled], enabled) end)
  13     :ok
  14   end
  15
  16   describe "when enabled" do
  17     setup do
  18       Pleroma.Config.put([:media_proxy, :enabled], true)
  19       :ok
  20     end
  21
  22     test "ignores invalid url" do
  23       assert url(nil) == nil
  24       assert url("") == nil
  25     end
  26
  27     test "ignores relative url" do
  28       assert url("/local") == "/local"
  29       assert url("/") == "/"
  30     end
  31
  32     test "ignores local url" do
  33       local_url = Pleroma.Web.Endpoint.url() <> "/hello"
  34       local_root = Pleroma.Web.Endpoint.url()
  35       assert url(local_url) == local_url
  36       assert url(local_root) == local_root
  37     end
  38
  39     test "encodes and decodes URL" do
  40       url = "https://pleroma.soykaf.com/static/logo.png"
  41       encoded = url(url)
  42
  43       assert String.starts_with?(
  44                encoded,
  45                Pleroma.Config.get([:media_proxy, :base_url], Pleroma.Web.base_url())
  46              )
  47
  48       assert String.ends_with?(encoded, "/logo.png")
  49
  50       assert decode_result(encoded) == url
  51     end
  52
  53     test "encodes and decodes URL without a path" do
  54       url = "https://pleroma.soykaf.com"
  55       encoded = url(url)
  56       assert decode_result(encoded) == url
  57     end
  58
  59     test "encodes and decodes URL without an extension" do
  60       url = "https://pleroma.soykaf.com/path/"
  61       encoded = url(url)
  62       assert String.ends_with?(encoded, "/path")
  63       assert decode_result(encoded) == url
  64     end
  65
  66     test "encodes and decodes URL and ignores query params for the path" do
  67       url = "https://pleroma.soykaf.com/static/logo.png?93939393939&bunny=true"
  68       encoded = url(url)
  69       assert String.ends_with?(encoded, "/logo.png")
  70       assert decode_result(encoded) == url
  71     end
  72
  73     test "validates signature" do
  74       secret_key_base = Pleroma.Config.get([Pleroma.Web.Endpoint, :secret_key_base])
  75
  76       on_exit(fn ->
  77         Pleroma.Config.put([Pleroma.Web.Endpoint, :secret_key_base], secret_key_base)
  78       end)
  79
  80       encoded = url("https://pleroma.social")
  81
  82       Pleroma.Config.put(
  83         [Pleroma.Web.Endpoint, :secret_key_base],
  84         "00000000000000000000000000000000000000000000000"
  85       )
  86
  87       [_, "proxy", sig, base64 | _] = URI.parse(encoded).path |> String.split("/")
  88       assert decode_url(sig, base64) == {:error, :invalid_signature}
  89     end
  90
  91     test "filename_matches matches url encoded paths" do
  92       assert MediaProxyController.filename_matches(
  93                true,
  94                "/Hello%20world.jpg",
  95                "http://pleroma.social/Hello world.jpg"
  96              ) == :ok
  97
  98       assert MediaProxyController.filename_matches(
  99                true,
 100                "/Hello%20world.jpg",
 101                "http://pleroma.social/Hello%20world.jpg"
 102              ) == :ok
 103     end
 104
 105     test "filename_matches matches non-url encoded paths" do
 106       assert MediaProxyController.filename_matches(
 107                true,
 108                "/Hello world.jpg",
 109                "http://pleroma.social/Hello%20world.jpg"
 110              ) == :ok
 111
 112       assert MediaProxyController.filename_matches(
 113                true,
 114                "/Hello world.jpg",
 115                "http://pleroma.social/Hello world.jpg"
 116              ) == :ok
 117     end
 118
 119     test "uses the configured base_url" do
 120       base_url = Pleroma.Config.get([:media_proxy, :base_url])
 121
 122       if base_url do
 123         on_exit(fn ->
 124           Pleroma.Config.put([:media_proxy, :base_url], base_url)
 125         end)
 126       end
 127
 128       Pleroma.Config.put([:media_proxy, :base_url], "https://cache.pleroma.social")
 129
 130       url = "https://pleroma.soykaf.com/static/logo.png"
 131       encoded = url(url)
 132
 133       assert String.starts_with?(encoded, Pleroma.Config.get([:media_proxy, :base_url]))
 134     end
 135
 136     # Some sites expect ASCII encoded characters in the URL to be preserved even if
 137     # unnecessary.
 138     # Issues: https://git.pleroma.social/pleroma/pleroma/issues/580
 139     #         https://git.pleroma.social/pleroma/pleroma/issues/1055
 140     test "preserve ASCII encoding" do
 141       url =
 142         "https://pleroma.com/%20/%21/%22/%23/%24/%25/%26/%27/%28/%29/%2A/%2B/%2C/%2D/%2E/%2F/%30/%31/%32/%33/%34/%35/%36/%37/%38/%39/%3A/%3B/%3C/%3D/%3E/%3F/%40/%41/%42/%43/%44/%45/%46/%47/%48/%49/%4A/%4B/%4C/%4D/%4E/%4F/%50/%51/%52/%53/%54/%55/%56/%57/%58/%59/%5A/%5B/%5C/%5D/%5E/%5F/%60/%61/%62/%63/%64/%65/%66/%67/%68/%69/%6A/%6B/%6C/%6D/%6E/%6F/%70/%71/%72/%73/%74/%75/%76/%77/%78/%79/%7A/%7B/%7C/%7D/%7E/%7F/%80/%81/%82/%83/%84/%85/%86/%87/%88/%89/%8A/%8B/%8C/%8D/%8E/%8F/%90/%91/%92/%93/%94/%95/%96/%97/%98/%99/%9A/%9B/%9C/%9D/%9E/%9F/%C2%A0/%A1/%A2/%A3/%A4/%A5/%A6/%A7/%A8/%A9/%AA/%AB/%AC/%C2%AD/%AE/%AF/%B0/%B1/%B2/%B3/%B4/%B5/%B6/%B7/%B8/%B9/%BA/%BB/%BC/%BD/%BE/%BF/%C0/%C1/%C2/%C3/%C4/%C5/%C6/%C7/%C8/%C9/%CA/%CB/%CC/%CD/%CE/%CF/%D0/%D1/%D2/%D3/%D4/%D5/%D6/%D7/%D8/%D9/%DA/%DB/%DC/%DD/%DE/%DF/%E0/%E1/%E2/%E3/%E4/%E5/%E6/%E7/%E8/%E9/%EA/%EB/%EC/%ED/%EE/%EF/%F0/%F1/%F2/%F3/%F4/%F5/%F6/%F7/%F8/%F9/%FA/%FB/%FC/%FD/%FE/%FF"
 143
 144       encoded = url(url)
 145       assert decode_result(encoded) == url
 146     end
 147
 148     # This includes unsafe/reserved characters which are not interpreted as part of the URL
 149     # and would otherwise have to be ASCII encoded. It is our role to ensure the proxied URL
 150     # is unmodified, so we are testing these characters anyway.
 151     test "preserve non-unicode characters per RFC3986" do
 152       url =
 153         "https://pleroma.com/ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz1234567890-._~:/?#[]@!$&'()*+,;=|^`{}"
 154
 155       encoded = url(url)
 156       assert decode_result(encoded) == url
 157     end
 158
 159     test "does not change whitelisted urls" do
 160       upload_config = Pleroma.Config.get([Pleroma.Upload])
 161       media_url = "https://media.pleroma.social"
 162       Pleroma.Config.put([Pleroma.Upload, :base_url], media_url)
 163       Pleroma.Config.put([:media_proxy, :whitelist], ["media.pleroma.social"])
 164       Pleroma.Config.put([:media_proxy, :base_url], "https://cache.pleroma.social")
 165
 166       url = "#{media_url}/static/logo.png"
 167       encoded = url(url)
 168
 169       assert String.starts_with?(encoded, media_url)
 170
 171       Pleroma.Config.put([Pleroma.Upload], upload_config)
 172     end
 173   end
 174
 175   describe "when disabled" do
 176     setup do
 177       enabled = Pleroma.Config.get([:media_proxy, :enabled])
 178
 179       if enabled do
 180         Pleroma.Config.put([:media_proxy, :enabled], false)
 181
 182         on_exit(fn ->
 183           Pleroma.Config.put([:media_proxy, :enabled], enabled)
 184           :ok
 185         end)
 186       end
 187
 188       :ok
 189     end
 190
 191     test "does not encode remote urls" do
 192       assert url("https://google.fr") == "https://google.fr"
 193     end
 194   end
 195
 196   defp decode_result(encoded) do
 197     [_, "proxy", sig, base64 | _] = URI.parse(encoded).path |> String.split("/")
 198     {:ok, decoded} = decode_url(sig, base64)
 199     decoded
 200   end
 201
 202   test "mediaproxy whitelist" do
 203     Pleroma.Config.put([:media_proxy, :enabled], true)
 204     Pleroma.Config.put([:media_proxy, :whitelist], ["google.com", "feld.me"])
 205     url = "https://feld.me/foo.png"
 206
 207     unencoded = url(url)
 208     assert unencoded == url
 209   end
 210 end