git.squeep.com Git - akkoma/blob - test/integration/mastodon_websocket_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Integration.MastodonWebsocketTest do
   6   use Pleroma.DataCase
   7
   8   import Pleroma.Factory
   9
  10   alias Pleroma.Integration.WebsocketClient
  11   alias Pleroma.Web.CommonAPI
  12   alias Pleroma.Web.OAuth
  13
  14   @path Pleroma.Web.Endpoint.url()
  15         |> URI.parse()
  16         |> Map.put(:scheme, "ws")
  17         |> Map.put(:path, "/api/v1/streaming")
  18         |> URI.to_string()
  19
  20   setup_all do
  21     start_supervised(Pleroma.Web.Streamer.supervisor())
  22     :ok
  23   end
  24
  25   def start_socket(qs \\ nil, headers \\ []) do
  26     path =
  27       case qs do
  28         nil -> @path
  29         qs -> @path <> qs
  30       end
  31
  32     WebsocketClient.start_link(self(), path, headers)
  33   end
  34
  35   test "refuses invalid requests" do
  36     capture_log(fn ->
  37       assert {:error, {400, _}} = start_socket()
  38       assert {:error, {404, _}} = start_socket("?stream=ncjdk")
  39       Process.sleep(30)
  40     end)
  41   end
  42
  43   test "requires authentication and a valid token for protected streams" do
  44     capture_log(fn ->
  45       assert {:error, {403, _}} = start_socket("?stream=user&access_token=aaaaaaaaaaaa")
  46       assert {:error, {403, _}} = start_socket("?stream=user")
  47       Process.sleep(30)
  48     end)
  49   end
  50
  51   test "allows public streams without authentication" do
  52     assert {:ok, _} = start_socket("?stream=public")
  53     assert {:ok, _} = start_socket("?stream=public:local")
  54     assert {:ok, _} = start_socket("?stream=hashtag&tag=lain")
  55   end
  56
  57   test "receives well formatted events" do
  58     user = insert(:user)
  59     {:ok, _} = start_socket("?stream=public")
  60     {:ok, activity} = CommonAPI.post(user, %{"status" => "nice echo chamber"})
  61
  62     assert_receive {:text, raw_json}, 1_000
  63     assert {:ok, json} = Jason.decode(raw_json)
  64
  65     assert "update" == json["event"]
  66     assert json["payload"]
  67     assert {:ok, json} = Jason.decode(json["payload"])
  68
  69     view_json =
  70       Pleroma.Web.MastodonAPI.StatusView.render("status.json", activity: activity, for: nil)
  71       |> Jason.encode!()
  72       |> Jason.decode!()
  73
  74     assert json == view_json
  75   end
  76
  77   describe "with a valid user token" do
  78     setup do
  79       {:ok, app} =
  80         Pleroma.Repo.insert(
  81           OAuth.App.register_changeset(%OAuth.App{}, %{
  82             client_name: "client",
  83             scopes: ["scope"],
  84             redirect_uris: "url"
  85           })
  86         )
  87
  88       user = insert(:user)
  89
  90       {:ok, auth} = OAuth.Authorization.create_authorization(app, user)
  91
  92       {:ok, token} = OAuth.Token.exchange_token(app, auth)
  93
  94       %{user: user, token: token}
  95     end
  96
  97     test "accepts valid tokens", state do
  98       assert {:ok, _} = start_socket("?stream=user&access_token=#{state.token.token}")
  99     end
 100
 101     test "accepts the 'user' stream", %{token: token} = _state do
 102       assert {:ok, _} = start_socket("?stream=user&access_token=#{token.token}")
 103
 104       assert capture_log(fn ->
 105                assert {:error, {403, "Forbidden"}} = start_socket("?stream=user")
 106                Process.sleep(30)
 107              end) =~ ":badarg"
 108     end
 109
 110     test "accepts the 'user:notification' stream", %{token: token} = _state do
 111       assert {:ok, _} = start_socket("?stream=user:notification&access_token=#{token.token}")
 112
 113       assert capture_log(fn ->
 114                assert {:error, {403, "Forbidden"}} = start_socket("?stream=user:notification")
 115                Process.sleep(30)
 116              end) =~ ":badarg"
 117     end
 118
 119     test "accepts valid token on Sec-WebSocket-Protocol header", %{token: token} do
 120       assert {:ok, _} = start_socket("?stream=user", [{"Sec-WebSocket-Protocol", token.token}])
 121
 122       assert capture_log(fn ->
 123                assert {:error, {403, "Forbidden"}} =
 124                         start_socket("?stream=user", [{"Sec-WebSocket-Protocol", "I am a friend"}])
 125
 126                Process.sleep(30)
 127              end) =~ ":badarg"
 128     end
 129   end
 130 end