git.squeep.com Git - akkoma/blob - test/conversation/participation_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Conversation.ParticipationTest do
   6   use Pleroma.DataCase
   7   import Pleroma.Factory
   8   alias Pleroma.Conversation.Participation
   9   alias Pleroma.User
  10   alias Pleroma.Web.CommonAPI
  11
  12   test "getting a participation will also preload things" do
  13     user = insert(:user)
  14     other_user = insert(:user)
  15
  16     {:ok, _activity} =
  17       CommonAPI.post(user, %{"status" => "Hey @#{other_user.nickname}.", "visibility" => "direct"})
  18
  19     [participation] = Participation.for_user(user)
  20
  21     participation = Participation.get(participation.id, preload: [:conversation])
  22
  23     assert %Pleroma.Conversation{} = participation.conversation
  24   end
  25
  26   test "for a new conversation or a reply, it doesn't mark the author's participation as unread" do
  27     user = insert(:user)
  28     other_user = insert(:user)
  29
  30     {:ok, _} =
  31       CommonAPI.post(user, %{"status" => "Hey @#{other_user.nickname}.", "visibility" => "direct"})
  32
  33     user = User.get_cached_by_id(user.id)
  34     other_user = User.get_cached_by_id(other_user.id)
  35
  36     [%{read: true}] = Participation.for_user(user)
  37     [%{read: false} = participation] = Participation.for_user(other_user)
  38
  39     assert User.get_cached_by_id(user.id).info.unread_conversation_count == 0
  40     assert User.get_cached_by_id(other_user.id).info.unread_conversation_count == 1
  41
  42     {:ok, _} =
  43       CommonAPI.post(other_user, %{
  44         "status" => "Hey @#{user.nickname}.",
  45         "visibility" => "direct",
  46         "in_reply_to_conversation_id" => participation.id
  47       })
  48
  49     user = User.get_cached_by_id(user.id)
  50     other_user = User.get_cached_by_id(other_user.id)
  51
  52     [%{read: false}] = Participation.for_user(user)
  53     [%{read: true}] = Participation.for_user(other_user)
  54
  55     assert User.get_cached_by_id(user.id).info.unread_conversation_count == 1
  56     assert User.get_cached_by_id(other_user.id).info.unread_conversation_count == 0
  57   end
  58
  59   test "for a new conversation, it sets the recipents of the participation" do
  60     user = insert(:user)
  61     other_user = insert(:user)
  62     third_user = insert(:user)
  63
  64     {:ok, activity} =
  65       CommonAPI.post(user, %{"status" => "Hey @#{other_user.nickname}.", "visibility" => "direct"})
  66
  67     user = User.get_cached_by_id(user.id)
  68     other_user = User.get_cached_by_id(other_user.id)
  69     [participation] = Participation.for_user(user)
  70     participation = Pleroma.Repo.preload(participation, :recipients)
  71
  72     assert length(participation.recipients) == 2
  73     assert user in participation.recipients
  74     assert other_user in participation.recipients
  75
  76     # Mentioning another user in the same conversation will not add a new recipients.
  77
  78     {:ok, _activity} =
  79       CommonAPI.post(user, %{
  80         "in_reply_to_status_id" => activity.id,
  81         "status" => "Hey @#{third_user.nickname}.",
  82         "visibility" => "direct"
  83       })
  84
  85     [participation] = Participation.for_user(user)
  86     participation = Pleroma.Repo.preload(participation, :recipients)
  87
  88     assert length(participation.recipients) == 2
  89   end
  90
  91   test "it creates a participation for a conversation and a user" do
  92     user = insert(:user)
  93     conversation = insert(:conversation)
  94
  95     {:ok, %Participation{} = participation} =
  96       Participation.create_for_user_and_conversation(user, conversation)
  97
  98     assert participation.user_id == user.id
  99     assert participation.conversation_id == conversation.id
 100
 101     :timer.sleep(1000)
 102     # Creating again returns the same participation
 103     {:ok, %Participation{} = participation_two} =
 104       Participation.create_for_user_and_conversation(user, conversation)
 105
 106     assert participation.id == participation_two.id
 107     refute participation.updated_at == participation_two.updated_at
 108   end
 109
 110   test "recreating an existing participations sets it to unread" do
 111     participation = insert(:participation, %{read: true})
 112
 113     {:ok, participation} =
 114       Participation.create_for_user_and_conversation(
 115         participation.user,
 116         participation.conversation
 117       )
 118
 119     refute participation.read
 120   end
 121
 122   test "it marks a participation as read" do
 123     participation = insert(:participation, %{read: false})
 124     {:ok, participation} = Participation.mark_as_read(participation)
 125
 126     assert participation.read
 127   end
 128
 129   test "it marks a participation as unread" do
 130     participation = insert(:participation, %{read: true})
 131     {:ok, participation} = Participation.mark_as_unread(participation)
 132
 133     refute participation.read
 134   end
 135
 136   test "gets all the participations for a user, ordered by updated at descending" do
 137     user = insert(:user)
 138     {:ok, activity_one} = CommonAPI.post(user, %{"status" => "x", "visibility" => "direct"})
 139     :timer.sleep(1000)
 140     {:ok, activity_two} = CommonAPI.post(user, %{"status" => "x", "visibility" => "direct"})
 141     :timer.sleep(1000)
 142
 143     {:ok, activity_three} =
 144       CommonAPI.post(user, %{
 145         "status" => "x",
 146         "visibility" => "direct",
 147         "in_reply_to_status_id" => activity_one.id
 148       })
 149
 150     assert [participation_one, participation_two] = Participation.for_user(user)
 151
 152     object2 = Pleroma.Object.normalize(activity_two)
 153     object3 = Pleroma.Object.normalize(activity_three)
 154
 155     user = Repo.get(Pleroma.User, user.id)
 156
 157     assert participation_one.conversation.ap_id == object3.data["context"]
 158     assert participation_two.conversation.ap_id == object2.data["context"]
 159     assert participation_one.conversation.users == [user]
 160
 161     # Pagination
 162     assert [participation_one] = Participation.for_user(user, %{"limit" => 1})
 163
 164     assert participation_one.conversation.ap_id == object3.data["context"]
 165
 166     # With last_activity_id
 167     assert [participation_one] =
 168              Participation.for_user_with_last_activity_id(user, %{"limit" => 1})
 169
 170     assert participation_one.last_activity_id == activity_three.id
 171   end
 172
 173   test "Doesn't die when the conversation gets empty" do
 174     user = insert(:user)
 175
 176     {:ok, activity} = CommonAPI.post(user, %{"status" => ".", "visibility" => "direct"})
 177     [participation] = Participation.for_user_with_last_activity_id(user)
 178
 179     assert participation.last_activity_id == activity.id
 180
 181     {:ok, _} = CommonAPI.delete(activity.id, user)
 182
 183     [] = Participation.for_user_with_last_activity_id(user)
 184   end
 185
 186   test "it sets recipients, always keeping the owner of the participation even when not explicitly set" do
 187     user = insert(:user)
 188     other_user = insert(:user)
 189
 190     {:ok, _activity} = CommonAPI.post(user, %{"status" => ".", "visibility" => "direct"})
 191     [participation] = Participation.for_user_with_last_activity_id(user)
 192
 193     participation = Repo.preload(participation, :recipients)
 194     user = User.get_cached_by_id(user.id)
 195
 196     assert participation.recipients |> length() == 1
 197     assert user in participation.recipients
 198
 199     {:ok, participation} = Participation.set_recipients(participation, [other_user.id])
 200
 201     assert participation.recipients |> length() == 2
 202     assert user in participation.recipients
 203     assert other_user in participation.recipients
 204   end
 205 end