git.squeep.com Git - akkoma/blob - test/conversation/participation_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Conversation.ParticipationTest do
   6   use Pleroma.DataCase
   7   import Pleroma.Factory
   8   alias Pleroma.Conversation
   9   alias Pleroma.Conversation.Participation
  10   alias Pleroma.Repo
  11   alias Pleroma.User
  12   alias Pleroma.Web.CommonAPI
  13
  14   test "getting a participation will also preload things" do
  15     user = insert(:user)
  16     other_user = insert(:user)
  17
  18     {:ok, _activity} =
  19       CommonAPI.post(user, %{"status" => "Hey @#{other_user.nickname}.", "visibility" => "direct"})
  20
  21     [participation] = Participation.for_user(user)
  22
  23     participation = Participation.get(participation.id, preload: [:conversation])
  24
  25     assert %Pleroma.Conversation{} = participation.conversation
  26   end
  27
  28   test "for a new conversation or a reply, it doesn't mark the author's participation as unread" do
  29     user = insert(:user)
  30     other_user = insert(:user)
  31
  32     {:ok, _} =
  33       CommonAPI.post(user, %{"status" => "Hey @#{other_user.nickname}.", "visibility" => "direct"})
  34
  35     user = User.get_cached_by_id(user.id)
  36     other_user = User.get_cached_by_id(other_user.id)
  37
  38     [%{read: true}] = Participation.for_user(user)
  39     [%{read: false} = participation] = Participation.for_user(other_user)
  40
  41     assert User.get_cached_by_id(user.id).unread_conversation_count == 0
  42     assert User.get_cached_by_id(other_user.id).unread_conversation_count == 1
  43
  44     {:ok, _} =
  45       CommonAPI.post(other_user, %{
  46         "status" => "Hey @#{user.nickname}.",
  47         "visibility" => "direct",
  48         "in_reply_to_conversation_id" => participation.id
  49       })
  50
  51     user = User.get_cached_by_id(user.id)
  52     other_user = User.get_cached_by_id(other_user.id)
  53
  54     [%{read: false}] = Participation.for_user(user)
  55     [%{read: true}] = Participation.for_user(other_user)
  56
  57     assert User.get_cached_by_id(user.id).unread_conversation_count == 1
  58     assert User.get_cached_by_id(other_user.id).unread_conversation_count == 0
  59   end
  60
  61   test "for a new conversation, it sets the recipents of the participation" do
  62     user = insert(:user)
  63     other_user = insert(:user)
  64     third_user = insert(:user)
  65
  66     {:ok, activity} =
  67       CommonAPI.post(user, %{"status" => "Hey @#{other_user.nickname}.", "visibility" => "direct"})
  68
  69     user = User.get_cached_by_id(user.id)
  70     other_user = User.get_cached_by_id(other_user.id)
  71     [participation] = Participation.for_user(user)
  72     participation = Pleroma.Repo.preload(participation, :recipients)
  73
  74     assert length(participation.recipients) == 2
  75     assert user in participation.recipients
  76     assert other_user in participation.recipients
  77
  78     # Mentioning another user in the same conversation will not add a new recipients.
  79
  80     {:ok, _activity} =
  81       CommonAPI.post(user, %{
  82         "in_reply_to_status_id" => activity.id,
  83         "status" => "Hey @#{third_user.nickname}.",
  84         "visibility" => "direct"
  85       })
  86
  87     [participation] = Participation.for_user(user)
  88     participation = Pleroma.Repo.preload(participation, :recipients)
  89
  90     assert length(participation.recipients) == 2
  91   end
  92
  93   test "it creates a participation for a conversation and a user" do
  94     user = insert(:user)
  95     conversation = insert(:conversation)
  96
  97     {:ok, %Participation{} = participation} =
  98       Participation.create_for_user_and_conversation(user, conversation)
  99
 100     assert participation.user_id == user.id
 101     assert participation.conversation_id == conversation.id
 102
 103     # Needed because updated_at is accurate down to a second
 104     :timer.sleep(1000)
 105
 106     # Creating again returns the same participation
 107     {:ok, %Participation{} = participation_two} =
 108       Participation.create_for_user_and_conversation(user, conversation)
 109
 110     assert participation.id == participation_two.id
 111     refute participation.updated_at == participation_two.updated_at
 112   end
 113
 114   test "recreating an existing participations sets it to unread" do
 115     participation = insert(:participation, %{read: true})
 116
 117     {:ok, participation} =
 118       Participation.create_for_user_and_conversation(
 119         participation.user,
 120         participation.conversation
 121       )
 122
 123     refute participation.read
 124   end
 125
 126   test "it marks a participation as read" do
 127     participation = insert(:participation, %{read: false})
 128     {:ok, participation} = Participation.mark_as_read(participation)
 129
 130     assert participation.read
 131   end
 132
 133   test "it marks a participation as unread" do
 134     participation = insert(:participation, %{read: true})
 135     {:ok, participation} = Participation.mark_as_unread(participation)
 136
 137     refute participation.read
 138   end
 139
 140   test "it marks all the user's participations as read" do
 141     user = insert(:user)
 142     other_user = insert(:user)
 143     participation1 = insert(:participation, %{read: false, user: user})
 144     participation2 = insert(:participation, %{read: false, user: user})
 145     participation3 = insert(:participation, %{read: false, user: other_user})
 146
 147     {:ok, _, [%{read: true}, %{read: true}]} = Participation.mark_all_as_read(user)
 148
 149     assert Participation.get(participation1.id).read == true
 150     assert Participation.get(participation2.id).read == true
 151     assert Participation.get(participation3.id).read == false
 152   end
 153
 154   test "gets all the participations for a user, ordered by updated at descending" do
 155     user = insert(:user)
 156     {:ok, activity_one} = CommonAPI.post(user, %{"status" => "x", "visibility" => "direct"})
 157     {:ok, activity_two} = CommonAPI.post(user, %{"status" => "x", "visibility" => "direct"})
 158
 159     {:ok, activity_three} =
 160       CommonAPI.post(user, %{
 161         "status" => "x",
 162         "visibility" => "direct",
 163         "in_reply_to_status_id" => activity_one.id
 164       })
 165
 166     # Offset participations because the accuracy of updated_at is down to a second
 167
 168     for {activity, offset} <- [{activity_two, 1}, {activity_three, 2}] do
 169       conversation = Conversation.get_for_ap_id(activity.data["context"])
 170       participation = Participation.for_user_and_conversation(user, conversation)
 171       updated_at = NaiveDateTime.add(Map.get(participation, :updated_at), offset)
 172
 173       Ecto.Changeset.change(participation, %{updated_at: updated_at})
 174       |> Repo.update!()
 175     end
 176
 177     assert [participation_one, participation_two] = Participation.for_user(user)
 178
 179     object2 = Pleroma.Object.normalize(activity_two)
 180     object3 = Pleroma.Object.normalize(activity_three)
 181
 182     user = Repo.get(Pleroma.User, user.id)
 183
 184     assert participation_one.conversation.ap_id == object3.data["context"]
 185     assert participation_two.conversation.ap_id == object2.data["context"]
 186     assert participation_one.conversation.users == [user]
 187
 188     # Pagination
 189     assert [participation_one] = Participation.for_user(user, %{"limit" => 1})
 190
 191     assert participation_one.conversation.ap_id == object3.data["context"]
 192
 193     # With last_activity_id
 194     assert [participation_one] =
 195              Participation.for_user_with_last_activity_id(user, %{"limit" => 1})
 196
 197     assert participation_one.last_activity_id == activity_three.id
 198   end
 199
 200   test "Doesn't die when the conversation gets empty" do
 201     user = insert(:user)
 202
 203     {:ok, activity} = CommonAPI.post(user, %{"status" => ".", "visibility" => "direct"})
 204     [participation] = Participation.for_user_with_last_activity_id(user)
 205
 206     assert participation.last_activity_id == activity.id
 207
 208     {:ok, _} = CommonAPI.delete(activity.id, user)
 209
 210     [] = Participation.for_user_with_last_activity_id(user)
 211   end
 212
 213   test "it sets recipients, always keeping the owner of the participation even when not explicitly set" do
 214     user = insert(:user)
 215     other_user = insert(:user)
 216
 217     {:ok, _activity} = CommonAPI.post(user, %{"status" => ".", "visibility" => "direct"})
 218     [participation] = Participation.for_user_with_last_activity_id(user)
 219
 220     participation = Repo.preload(participation, :recipients)
 221     user = User.get_cached_by_id(user.id)
 222
 223     assert participation.recipients |> length() == 1
 224     assert user in participation.recipients
 225
 226     {:ok, participation} = Participation.set_recipients(participation, [other_user.id])
 227
 228     assert participation.recipients |> length() == 2
 229     assert user in participation.recipients
 230     assert other_user in participation.recipients
 231   end
 232
 233   describe "blocking" do
 234     test "when the user blocks a recipient, the existing conversations with them are marked as read" do
 235       blocker = insert(:user)
 236       blocked = insert(:user)
 237       third_user = insert(:user)
 238
 239       {:ok, _direct1} =
 240         CommonAPI.post(third_user, %{
 241           "status" => "Hi @#{blocker.nickname}",
 242           "visibility" => "direct"
 243         })
 244
 245       {:ok, _direct2} =
 246         CommonAPI.post(third_user, %{
 247           "status" => "Hi @#{blocker.nickname}, @#{blocked.nickname}",
 248           "visibility" => "direct"
 249         })
 250
 251       {:ok, _direct3} =
 252         CommonAPI.post(blocked, %{
 253           "status" => "Hi @#{blocker.nickname}",
 254           "visibility" => "direct"
 255         })
 256
 257       {:ok, _direct4} =
 258         CommonAPI.post(blocked, %{
 259           "status" => "Hi @#{blocker.nickname}, @#{third_user.nickname}",
 260           "visibility" => "direct"
 261         })
 262
 263       assert [%{read: false}, %{read: false}, %{read: false}, %{read: false}] =
 264                Participation.for_user(blocker)
 265
 266       assert User.get_cached_by_id(blocker.id).unread_conversation_count == 4
 267
 268       {:ok, _user_relationship} = User.block(blocker, blocked)
 269
 270       # The conversations with the blocked user are marked as read
 271       assert [%{read: true}, %{read: true}, %{read: true}, %{read: false}] =
 272                Participation.for_user(blocker)
 273
 274       assert User.get_cached_by_id(blocker.id).unread_conversation_count == 1
 275
 276       # The conversation is not marked as read for the blocked user
 277       assert [_, _, %{read: false}] = Participation.for_user(blocked)
 278       assert User.get_cached_by_id(blocked.id).unread_conversation_count == 1
 279
 280       # The conversation is not marked as read for the third user
 281       assert [%{read: false}, _, _] = Participation.for_user(third_user)
 282       assert User.get_cached_by_id(third_user.id).unread_conversation_count == 1
 283     end
 284
 285     test "the new conversation with the blocked user is not marked as unread " do
 286       blocker = insert(:user)
 287       blocked = insert(:user)
 288       third_user = insert(:user)
 289
 290       {:ok, _user_relationship} = User.block(blocker, blocked)
 291
 292       # When the blocked user is the author
 293       {:ok, _direct1} =
 294         CommonAPI.post(blocked, %{
 295           "status" => "Hi @#{blocker.nickname}",
 296           "visibility" => "direct"
 297         })
 298
 299       assert [%{read: true}] = Participation.for_user(blocker)
 300       assert User.get_cached_by_id(blocker.id).unread_conversation_count == 0
 301
 302       # When the blocked user is a recipient
 303       {:ok, _direct2} =
 304         CommonAPI.post(third_user, %{
 305           "status" => "Hi @#{blocker.nickname}, @#{blocked.nickname}",
 306           "visibility" => "direct"
 307         })
 308
 309       assert [%{read: true}, %{read: true}] = Participation.for_user(blocker)
 310       assert User.get_cached_by_id(blocker.id).unread_conversation_count == 0
 311
 312       assert [%{read: false}, _] = Participation.for_user(blocked)
 313       assert User.get_cached_by_id(blocked.id).unread_conversation_count == 1
 314     end
 315
 316     test "the conversation with the blocked user is not marked as unread on a reply" do
 317       blocker = insert(:user)
 318       blocked = insert(:user)
 319       third_user = insert(:user)
 320
 321       {:ok, _direct1} =
 322         CommonAPI.post(blocker, %{
 323           "status" => "Hi @#{third_user.nickname}, @#{blocked.nickname}",
 324           "visibility" => "direct"
 325         })
 326
 327       {:ok, _user_relationship} = User.block(blocker, blocked)
 328       assert [%{read: true}] = Participation.for_user(blocker)
 329       assert User.get_cached_by_id(blocker.id).unread_conversation_count == 0
 330
 331       assert [blocked_participation] = Participation.for_user(blocked)
 332
 333       # When it's a reply from the blocked user
 334       {:ok, _direct2} =
 335         CommonAPI.post(blocked, %{
 336           "status" => "reply",
 337           "visibility" => "direct",
 338           "in_reply_to_conversation_id" => blocked_participation.id
 339         })
 340
 341       assert [%{read: true}] = Participation.for_user(blocker)
 342       assert User.get_cached_by_id(blocker.id).unread_conversation_count == 0
 343
 344       assert [third_user_participation] = Participation.for_user(third_user)
 345
 346       # When it's a reply from the third user
 347       {:ok, _direct3} =
 348         CommonAPI.post(third_user, %{
 349           "status" => "reply",
 350           "visibility" => "direct",
 351           "in_reply_to_conversation_id" => third_user_participation.id
 352         })
 353
 354       assert [%{read: true}] = Participation.for_user(blocker)
 355       assert User.get_cached_by_id(blocker.id).unread_conversation_count == 0
 356
 357       # Marked as unread for the blocked user
 358       assert [%{read: false}] = Participation.for_user(blocked)
 359       assert User.get_cached_by_id(blocked.id).unread_conversation_count == 1
 360     end
 361   end
 362 end