git.squeep.com Git - akkoma/blob - restarter/lib/pleroma.ex

   1 defmodule Restarter.Pleroma do
   2   use GenServer
   3
   4   require Logger
   5
   6   def start_link(_) do
   7     GenServer.start_link(__MODULE__, [], name: __MODULE__)
   8   end
   9
  10   def init(_), do: {:ok, %{need_reboot?: false}}
  11
  12   def need_reboot? do
  13     GenServer.call(__MODULE__, :need_reboot?)
  14   end
  15
  16   def need_reboot do
  17     GenServer.cast(__MODULE__, :need_reboot)
  18   end
  19
  20   def refresh do
  21     GenServer.cast(__MODULE__, :refresh)
  22   end
  23
  24   def restart(env, delay) do
  25     GenServer.cast(__MODULE__, {:restart, env, delay})
  26   end
  27
  28   def restart_after_boot(env) do
  29     GenServer.cast(__MODULE__, {:after_boot, env})
  30   end
  31
  32   def handle_call(:need_reboot?, _from, state) do
  33     {:reply, state[:need_reboot?], state}
  34   end
  35
  36   def handle_cast(:refresh, _state) do
  37     {:noreply, %{need_reboot?: false}}
  38   end
  39
  40   def handle_cast(:need_reboot, %{need_reboot?: true} = state), do: {:noreply, state}
  41
  42   def handle_cast(:need_reboot, state) do
  43     {:noreply, Map.put(state, :need_reboot?, true)}
  44   end
  45
  46   def handle_cast({:restart, :test, _}, state) do
  47     Logger.debug("pleroma manually restarted")
  48     {:noreply, Map.put(state, :need_reboot?, false)}
  49   end
  50
  51   def handle_cast({:restart, _, delay}, state) do
  52     Process.sleep(delay)
  53     do_restart(:pleroma)
  54     {:noreply, Map.put(state, :need_reboot?, false)}
  55   end
  56
  57   def handle_cast({:after_boot, _}, %{after_boot: true} = state), do: {:noreply, state}
  58
  59   def handle_cast({:after_boot, :test}, state) do
  60     Logger.debug("pleroma restarted after boot")
  61     {:noreply, Map.put(state, :after_boot, true)}
  62   end
  63
  64   def handle_cast({:after_boot, _}, state) do
  65     do_restart(:pleroma)
  66     {:noreply, Map.put(state, :after_boot, true)}
  67   end
  68
  69   defp do_restart(app) do
  70     :ok = Application.ensure_started(app)
  71     :ok = Application.stop(app)
  72     :ok = Application.start(app)
  73   end
  74 end