git.squeep.com Git - akkoma/blob - priv/repo/migrations/20181218172826_users_and_activities_flake_id.exs

   1 defmodule Pleroma.Repo.Migrations.UsersAndActivitiesFlakeId do
   2   use Ecto.Migration
   3   alias Pleroma.Clippy
   4   require Integer
   5   import Ecto.Query
   6   alias Pleroma.Repo
   7
   8   # This migrates from int serial IDs to custom Flake:
   9   #   1- create a temporary uuid column
  10   #   2- fill this column with compatibility ids (see below)
  11   #   3- remove pkeys constraints
  12   #   4- update relation pkeys with the new ids
  13   #   5- rename the temporary column to id
  14   #   6- re-create the constraints
  15   def up do
  16     # Old serial int ids are transformed to 128bits with extra padding.
  17     # The application (in `Pleroma.FlakeId`) handles theses IDs properly as integers; to keep compatibility
  18     # with previously issued ids.
  19     #execute "update activities set external_id = CAST( LPAD( TO_HEX(id), 32, '0' ) AS uuid);"
  20     #execute "update users set external_id = CAST( LPAD( TO_HEX(id), 32, '0' ) AS uuid);"
  21
  22     clippy = start_clippy_heartbeats()
  23
  24     # Lock both tables to avoid a running server to meddling with our transaction
  25     execute "LOCK TABLE activities;"
  26     execute "LOCK TABLE users;"
  27
  28     execute """
  29       ALTER TABLE activities
  30       DROP CONSTRAINT activities_pkey CASCADE,
  31       ALTER COLUMN id DROP default,
  32       ALTER COLUMN id SET DATA TYPE uuid USING CAST( LPAD( TO_HEX(id), 32, '0' ) AS uuid),
  33       ADD PRIMARY KEY (id);
  34     """
  35
  36     execute """
  37     ALTER TABLE users
  38     DROP CONSTRAINT users_pkey CASCADE,
  39     ALTER COLUMN id DROP default,
  40     ALTER COLUMN id SET DATA TYPE uuid USING CAST( LPAD( TO_HEX(id), 32, '0' ) AS uuid),
  41     ADD PRIMARY KEY (id);
  42     """
  43
  44     execute "UPDATE users SET info = jsonb_set(info, '{pinned_activities}', array_to_json(ARRAY(select jsonb_array_elements_text(info->'pinned_activities')))::jsonb);"
  45
  46     # Fkeys:
  47     # Activities - Referenced by:
  48     #   TABLE "notifications" CONSTRAINT "notifications_activity_id_fkey" FOREIGN KEY (activity_id) REFERENCES activities(id) ON DELETE CASCADE
  49     # Users - Referenced by:
  50     #  TABLE "filters" CONSTRAINT "filters_user_id_fkey" FOREIGN KEY (user_id) REFERENCES users(id) ON DELETE CASCADE
  51     #  TABLE "lists" CONSTRAINT "lists_user_id_fkey" FOREIGN KEY (user_id) REFERENCES users(id) ON DELETE CASCADE
  52     #  TABLE "notifications" CONSTRAINT "notifications_user_id_fkey" FOREIGN KEY (user_id) REFERENCES users(id) ON DELETE CASCADE
  53     #  TABLE "oauth_authorizations" CONSTRAINT "oauth_authorizations_user_id_fkey" FOREIGN KEY (user_id) REFERENCES users(id)
  54     #  TABLE "oauth_tokens" CONSTRAINT "oauth_tokens_user_id_fkey" FOREIGN KEY (user_id) REFERENCES users(id)
  55     #  TABLE "password_reset_tokens" CONSTRAINT "password_reset_tokens_user_id_fkey" FOREIGN KEY (user_id) REFERENCES users(id)
  56     #  TABLE "push_subscriptions" CONSTRAINT "push_subscriptions_user_id_fkey" FOREIGN KEY (user_id) REFERENCES users(id) ON DELETE CASCADE
  57     #  TABLE "websub_client_subscriptions" CONSTRAINT "websub_client_subscriptions_user_id_fkey" FOREIGN KEY (user_id) REFERENCES users(id)
  58
  59     execute """
  60     ALTER TABLE notifications
  61     ALTER COLUMN activity_id SET DATA TYPE uuid USING CAST( LPAD( TO_HEX(activity_id), 32, '0' ) AS uuid),
  62     ADD CONSTRAINT notifications_activity_id_fkey FOREIGN KEY (activity_id) REFERENCES activities(id) ON DELETE CASCADE;
  63     """
  64
  65     for table <- ~w(notifications filters lists oauth_authorizations oauth_tokens password_reset_tokens push_subscriptions websub_client_subscriptions) do
  66       execute """
  67       ALTER TABLE #{table}
  68       ALTER COLUMN user_id SET DATA TYPE uuid USING CAST( LPAD( TO_HEX(user_id), 32, '0' ) AS uuid),
  69       ADD CONSTRAINT #{table}_user_id_fkey FOREIGN KEY (user_id) REFERENCES users(id) ON DELETE CASCADE;
  70       """
  71     end
  72
  73     flush()
  74
  75     stop_clippy_heartbeats(clippy)
  76   end
  77
  78   def down, do: :ok
  79
  80   defp start_clippy_heartbeats() do
  81     count = from(a in "activities", select: count(a.id)) |> Repo.one!
  82
  83     if count > 5000 do
  84       heartbeat_interval = :timer.minutes(2) + :timer.seconds(30)
  85       all_tips = Clippy.tips() ++ [
  86         "The migration is still running, maybe it's time for another “tea”?",
  87         "Happy rabbits practice a cute behavior known as a\n“binky:” they jump up in the air\nand twist\nand spin around!",
  88         "Nothing and everything.\n\nI still work.",
  89         "Pleroma runs on a Raspberry Pi!\n\n  … but this migration will take forever if you\nactually run on a raspberry pi",
  90         "Status? Stati? Post? Note? Toot?\nRepeat? Reboost? Boost? Retweet? Retoot??\n\nI-I'm confused.",
  91       ]
  92
  93       heartbeat = fn(heartbeat, runs, all_tips, tips) ->
  94         tips = if Integer.is_even(runs) do
  95           tips = if tips == [], do: all_tips, else: tips
  96           [tip | tips] = Enum.shuffle(tips)
  97           Clippy.puts(tip)
  98           tips
  99         else
 100           IO.puts "\n -- #{DateTime.to_string(DateTime.utc_now())} Migration still running, please wait…\n"
 101           tips
 102         end
 103         :timer.sleep(heartbeat_interval)
 104         heartbeat.(heartbeat, runs + 1, all_tips, tips)
 105       end
 106
 107       Clippy.puts [
 108         [:red, :bright, "It looks like you are running an older instance!"],
 109         [""],
 110         [:bright, "This migration may take a long time", :reset, " -- so you probably should"],
 111         ["go drink a cofe, or a tea, or a beer, a whiskey, a vodka,"],
 112         ["while it runs to deal with your temporary fediverse pause!"]
 113       ]
 114       :timer.sleep(heartbeat_interval)
 115       spawn_link(fn() -> heartbeat.(heartbeat, 1, all_tips, []) end)
 116     end
 117   end
 118
 119   defp stop_clippy_heartbeats(pid) do
 120     if pid do
 121       Process.unlink(pid)
 122       Process.exit(pid, :kill)
 123       Clippy.puts [[:green, :bright, "Hurray!!", "", "", "Migration completed!"]]
 124     end
 125   end
 126
 127 end