git.squeep.com Git - akkoma/blob - mix.exs

   1 defmodule Pleroma.Mixfile do
   2   use Mix.Project
   3
   4   def project do
   5     [
   6       app: :pleroma,
   7       version: version("1.0.0"),
   8       elixir: "~> 1.8",
   9       elixirc_paths: elixirc_paths(Mix.env()),
  10       compilers: [:phoenix, :gettext] ++ Mix.compilers(),
  11       elixirc_options: [warnings_as_errors: true],
  12       xref: [exclude: [:eldap]],
  13       start_permanent: Mix.env() == :prod,
  14       aliases: aliases(),
  15       deps: deps(),
  16       test_coverage: [tool: ExCoveralls],
  17       preferred_cli_env: ["coveralls.html": :test],
  18       # Docs
  19       name: "Pleroma",
  20       homepage_url: "https://pleroma.social/",
  21       source_url: "https://git.pleroma.social/pleroma/pleroma",
  22       docs: [
  23         source_url_pattern:
  24           "https://git.pleroma.social/pleroma/pleroma/blob/develop/%{path}#L%{line}",
  25         logo: "priv/static/static/logo.png",
  26         extras: ["README.md", "CHANGELOG.md"] ++ Path.wildcard("docs/**/*.md"),
  27         groups_for_extras: [
  28           "Installation manuals": Path.wildcard("docs/installation/*.md"),
  29           Configuration: Path.wildcard("docs/config/*.md"),
  30           Administration: Path.wildcard("docs/admin/*.md"),
  31           "Pleroma's APIs and Mastodon API extensions": Path.wildcard("docs/api/*.md")
  32         ],
  33         main: "readme",
  34         output: "priv/static/doc"
  35       ],
  36       releases: [
  37         pleroma: [
  38           include_executables_for: [:unix],
  39           applications: [ex_syslogger: :load, syslog: :load],
  40           steps: [:assemble, &copy_files/1, &copy_nginx_config/1]
  41         ]
  42       ]
  43     ]
  44   end
  45
  46   def copy_files(%{path: target_path} = release) do
  47     File.cp_r!("./rel/files", target_path)
  48     release
  49   end
  50
  51   def copy_nginx_config(%{path: target_path} = release) do
  52     File.cp!(
  53       "./installation/pleroma.nginx",
  54       Path.join([target_path, "installation", "pleroma.nginx"])
  55     )
  56
  57     release
  58   end
  59
  60   # Configuration for the OTP application.
  61   #
  62   # Type `mix help compile.app` for more information.
  63   def application do
  64     [
  65       mod: {Pleroma.Application, []},
  66       extra_applications: [:logger, :runtime_tools, :comeonin, :quack],
  67       included_applications: [:ex_syslogger]
  68     ]
  69   end
  70
  71   # Specifies which paths to compile per environment.
  72   defp elixirc_paths(:test), do: ["lib", "test/support"]
  73   defp elixirc_paths(_), do: ["lib"]
  74
  75   # Specifies OAuth dependencies.
  76   defp oauth_deps do
  77     oauth_strategy_packages =
  78       System.get_env("OAUTH_CONSUMER_STRATEGIES")
  79       |> to_string()
  80       |> String.split()
  81       |> Enum.map(fn strategy_entry ->
  82         with [_strategy, dependency] <- String.split(strategy_entry, ":") do
  83           dependency
  84         else
  85           [strategy] -> "ueberauth_#{strategy}"
  86         end
  87       end)
  88
  89     for s <- oauth_strategy_packages, do: {String.to_atom(s), ">= 0.0.0"}
  90   end
  91
  92   # Specifies your project dependencies.
  93   #
  94   # Type `mix help deps` for examples and options.
  95   defp deps do
  96     [
  97       {:phoenix, "~> 1.4.8"},
  98       {:tzdata, "~> 0.5.21"},
  99       {:plug_cowboy, "~> 2.0"},
 100       {:phoenix_pubsub, "~> 1.1"},
 101       {:phoenix_ecto, "~> 4.0"},
 102       {:ecto_sql, "~> 3.2"},
 103       {:postgrex, ">= 0.13.5"},
 104       {:oban, "~> 0.8.1"},
 105       {:quantum, "~> 2.3"},
 106       {:gettext, "~> 0.15"},
 107       {:comeonin, "~> 4.1.1"},
 108       {:pbkdf2_elixir, "~> 0.12.3"},
 109       {:trailing_format_plug, "~> 0.0.7"},
 110       {:html_sanitize_ex, "~> 1.3.0"},
 111       {:html_entities, "~> 0.4"},
 112       {:phoenix_html, "~> 2.10"},
 113       {:calendar, "~> 0.17.4"},
 114       {:cachex, "~> 3.0.2"},
 115       {:poison, "~> 3.0", override: true},
 116       {:tesla, "~> 1.3", override: true},
 117       {:jason, "~> 1.0"},
 118       {:mogrify, "~> 0.6.1"},
 119       {:ex_aws, "~> 2.1"},
 120       {:ex_aws_s3, "~> 2.0"},
 121       {:sweet_xml, "~> 0.6.6"},
 122       {:earmark, "~> 1.3"},
 123       {:bbcode, "~> 0.1.1"},
 124       {:ex_machina, "~> 2.3", only: :test},
 125       {:credo, "~> 0.9.3", only: [:dev, :test]},
 126       {:mock, "~> 0.3.3", only: :test},
 127       {:crypt,
 128        git: "https://github.com/msantos/crypt", ref: "1f2b58927ab57e72910191a7ebaeff984382a1d3"},
 129       {:cors_plug, "~> 1.5"},
 130       {:ex_doc, "~> 0.21", only: :dev, runtime: false},
 131       {:web_push_encryption, "~> 0.2.1"},
 132       {:swoosh, "~> 0.23.2"},
 133       {:phoenix_swoosh, "~> 0.2"},
 134       {:gen_smtp, "~> 0.13"},
 135       {:websocket_client, git: "https://github.com/jeremyong/websocket_client.git", only: :test},
 136       {:floki, "~> 0.23.0"},
 137       {:ex_syslogger, github: "slashmili/ex_syslogger", tag: "1.4.0"},
 138       {:timex, "~> 3.5"},
 139       {:ueberauth, "~> 0.4"},
 140       {:auto_linker,
 141        git: "https://git.pleroma.social/pleroma/auto_linker.git",
 142        ref: "95e8188490e97505c56636c1379ffdf036c1fdde"},
 143       {:http_signatures,
 144        git: "https://git.pleroma.social/pleroma/http_signatures.git",
 145        ref: "293d77bb6f4a67ac8bde1428735c3b42f22cbb30"},
 146       {:telemetry, "~> 0.3"},
 147       {:poolboy, "~> 1.5"},
 148       {:prometheus_ex, "~> 3.0"},
 149       {:prometheus_plugs, "~> 1.1"},
 150       {:prometheus_phoenix, "~> 1.3"},
 151       {:prometheus_ecto, "~> 1.4"},
 152       {:recon, github: "ferd/recon", tag: "2.4.0"},
 153       {:quack, "~> 0.1.1"},
 154       {:joken, "~> 2.0"},
 155       {:benchee, "~> 1.0"},
 156       {:esshd, "~> 0.1.0", runtime: Application.get_env(:esshd, :enabled, false)},
 157       {:ex_rated, "~> 1.3"},
 158       {:ex_const, "~> 0.2"},
 159       {:plug_static_index_html, "~> 1.0.0"},
 160       {:excoveralls, "~> 0.11.1", only: :test},
 161       {:mox, "~> 0.5", only: :test}
 162     ] ++ oauth_deps()
 163   end
 164
 165   # Aliases are shortcuts or tasks specific to the current project.
 166   # For example, to create, migrate and run the seeds file at once:
 167   #
 168   #     $ mix ecto.setup
 169   #
 170   # See the documentation for `Mix` for more info on aliases.
 171   defp aliases do
 172     [
 173       "ecto.migrate": ["pleroma.ecto.migrate"],
 174       "ecto.rollback": ["pleroma.ecto.rollback"],
 175       "ecto.setup": ["ecto.create", "ecto.migrate", "run priv/repo/seeds.exs"],
 176       "ecto.reset": ["ecto.drop", "ecto.setup"],
 177       test: ["ecto.create --quiet", "ecto.migrate", "test"],
 178       docs: ["pleroma.docs", "docs"]
 179     ]
 180   end
 181
 182   # Builds a version string made of:
 183   # * the application version
 184   # * a pre-release if ahead of the tag: the describe string (-count-commithash)
 185   # * branch name
 186   # * build metadata:
 187   #   * a build name if `PLEROMA_BUILD_NAME` or `:pleroma, :build_name` is defined
 188   #   * the mix environment if different than prod
 189   defp version(version) do
 190     identifier_filter = ~r/[^0-9a-z\-]+/i
 191
 192     # Pre-release version, denoted from patch version with a hyphen
 193     {git_tag, git_pre_release} =
 194       with {tag, 0} <-
 195              System.cmd("git", ["describe", "--tags", "--abbrev=0"], stderr_to_stdout: true),
 196            tag = String.trim(tag),
 197            {describe, 0} <- System.cmd("git", ["describe", "--tags", "--abbrev=8"]),
 198            describe = String.trim(describe),
 199            ahead <- String.replace(describe, tag, ""),
 200            ahead <- String.trim_leading(ahead, "-") do
 201         {String.replace_prefix(tag, "v", ""), if(ahead != "", do: String.trim(ahead))}
 202       else
 203         _ ->
 204           {commit_hash, 0} = System.cmd("git", ["rev-parse", "--short", "HEAD"])
 205           {nil, "0-g" <> String.trim(commit_hash)}
 206       end
 207
 208     if git_tag && version != git_tag do
 209       Mix.shell().error(
 210         "Application version #{inspect(version)} does not match git tag #{inspect(git_tag)}"
 211       )
 212     end
 213
 214     # Branch name as pre-release version component, denoted with a dot
 215     branch_name =
 216       with {branch_name, 0} <- System.cmd("git", ["rev-parse", "--abbrev-ref", "HEAD"]),
 217            branch_name <- String.trim(branch_name),
 218            branch_name <- System.get_env("PLEROMA_BUILD_BRANCH") || branch_name,
 219            true <- branch_name not in ["master", "HEAD"] do
 220         branch_name =
 221           branch_name
 222           |> String.trim()
 223           |> String.replace(identifier_filter, "-")
 224
 225         branch_name
 226       end
 227
 228     build_name =
 229       cond do
 230         name = Application.get_env(:pleroma, :build_name) -> name
 231         name = System.get_env("PLEROMA_BUILD_NAME") -> name
 232         true -> nil
 233       end
 234
 235     env_name = if Mix.env() != :prod, do: to_string(Mix.env())
 236     env_override = System.get_env("PLEROMA_BUILD_ENV")
 237
 238     env_name =
 239       case env_override do
 240         nil -> env_name
 241         env_override when env_override in ["", "prod"] -> nil
 242         env_override -> env_override
 243       end
 244
 245     # Pre-release version, denoted by appending a hyphen
 246     # and a series of dot separated identifiers
 247     pre_release =
 248       [git_pre_release, branch_name]
 249       |> Enum.filter(fn string -> string && string != "" end)
 250       |> Enum.join(".")
 251       |> (fn
 252             "" -> nil
 253             string -> "-" <> String.replace(string, identifier_filter, "-")
 254           end).()
 255
 256     # Build metadata, denoted with a plus sign
 257     build_metadata =
 258       [build_name, env_name]
 259       |> Enum.filter(fn string -> string && string != "" end)
 260       |> Enum.join(".")
 261       |> (fn
 262             "" -> nil
 263             string -> "+" <> String.replace(string, identifier_filter, "-")
 264           end).()
 265
 266     [version, pre_release, build_metadata]
 267     |> Enum.filter(fn string -> string && string != "" end)
 268     |> Enum.join()
 269   end
 270 end