git.squeep.com Git - akkoma/blob - mix.exs

   1 defmodule Pleroma.Mixfile do
   2   use Mix.Project
   3
   4   def project do
   5     [
   6       app: :pleroma,
   7       version: version("2.0.50"),
   8       elixir: "~> 1.8",
   9       elixirc_paths: elixirc_paths(Mix.env()),
  10       compilers: [:phoenix, :gettext] ++ Mix.compilers(),
  11       elixirc_options: [warnings_as_errors: warnings_as_errors(Mix.env())],
  12       xref: [exclude: [:eldap]],
  13       start_permanent: Mix.env() == :prod,
  14       aliases: aliases(),
  15       deps: deps(),
  16       test_coverage: [tool: ExCoveralls],
  17       preferred_cli_env: ["coveralls.html": :test],
  18       # Docs
  19       name: "Pleroma",
  20       homepage_url: "https://pleroma.social/",
  21       source_url: "https://git.pleroma.social/pleroma/pleroma",
  22       docs: [
  23         source_url_pattern:
  24           "https://git.pleroma.social/pleroma/pleroma/blob/develop/%{path}#L%{line}",
  25         logo: "priv/static/static/logo.png",
  26         extras: ["README.md", "CHANGELOG.md"] ++ Path.wildcard("docs/**/*.md"),
  27         groups_for_extras: [
  28           "Installation manuals": Path.wildcard("docs/installation/*.md"),
  29           Configuration: Path.wildcard("docs/config/*.md"),
  30           Administration: Path.wildcard("docs/admin/*.md"),
  31           "Pleroma's APIs and Mastodon API extensions": Path.wildcard("docs/api/*.md")
  32         ],
  33         main: "readme",
  34         output: "priv/static/doc"
  35       ],
  36       releases: [
  37         pleroma: [
  38           include_executables_for: [:unix],
  39           applications: [ex_syslogger: :load, syslog: :load],
  40           steps: [:assemble, &copy_files/1, &copy_nginx_config/1]
  41         ]
  42       ]
  43     ]
  44   end
  45
  46   def copy_files(%{path: target_path} = release) do
  47     File.cp_r!("./rel/files", target_path)
  48     release
  49   end
  50
  51   def copy_nginx_config(%{path: target_path} = release) do
  52     File.cp!(
  53       "./installation/pleroma.nginx",
  54       Path.join([target_path, "installation", "pleroma.nginx"])
  55     )
  56
  57     release
  58   end
  59
  60   # Configuration for the OTP application.
  61   #
  62   # Type `mix help compile.app` for more information.
  63   def application do
  64     [
  65       mod: {Pleroma.Application, []},
  66       extra_applications: [:logger, :runtime_tools, :comeonin, :quack, :fast_sanitize, :ssl],
  67       included_applications: [:ex_syslogger]
  68     ]
  69   end
  70
  71   # Specifies which paths to compile per environment.
  72   defp elixirc_paths(:benchmark), do: ["lib", "benchmarks"]
  73   defp elixirc_paths(:test), do: ["lib", "test/support"]
  74   defp elixirc_paths(_), do: ["lib"]
  75
  76   defp warnings_as_errors(:prod), do: false
  77   # Uncomment this if you need testing configurable_from_database logic
  78   # defp warnings_as_errors(:dev), do: false
  79   defp warnings_as_errors(_), do: true
  80
  81   # Specifies OAuth dependencies.
  82   defp oauth_deps do
  83     oauth_strategy_packages =
  84       System.get_env("OAUTH_CONSUMER_STRATEGIES")
  85       |> to_string()
  86       |> String.split()
  87       |> Enum.map(fn strategy_entry ->
  88         with [_strategy, dependency] <- String.split(strategy_entry, ":") do
  89           dependency
  90         else
  91           [strategy] -> "ueberauth_#{strategy}"
  92         end
  93       end)
  94
  95     for s <- oauth_strategy_packages, do: {String.to_atom(s), ">= 0.0.0"}
  96   end
  97
  98   # Specifies your project dependencies.
  99   #
 100   # Type `mix help deps` for examples and options.
 101   defp deps do
 102     [
 103       {:phoenix, "~> 1.4.8"},
 104       {:tzdata, "~> 0.5.21"},
 105       {:plug_cowboy, "~> 2.0"},
 106       {:phoenix_pubsub, "~> 1.1"},
 107       {:phoenix_ecto, "~> 4.0"},
 108       {:ecto_enum, "~> 1.4"},
 109       {:ecto_sql, "~> 3.3.2"},
 110       {:postgrex, ">= 0.13.5"},
 111       {:oban, "~> 0.12.1"},
 112       {:gettext, "~> 0.15"},
 113       {:comeonin, "~> 4.1.1"},
 114       {:pbkdf2_elixir, "~> 0.12.3"},
 115       {:trailing_format_plug, "~> 0.0.7"},
 116       {:fast_sanitize, "~> 0.1"},
 117       {:html_entities, "~> 0.5", override: true},
 118       {:phoenix_html, "~> 2.10"},
 119       {:calendar, "~> 0.17.4"},
 120       {:cachex, "~> 3.2"},
 121       {:poison, "~> 3.0", override: true},
 122       # {:tesla, "~> 1.3", override: true},
 123       {:tesla,
 124        git: "https://git.pleroma.social/pleroma/elixir-libraries/tesla.git",
 125        ref: "61b7503cef33f00834f78ddfafe0d5d9dec2270b",
 126        override: true},
 127       {:castore, "~> 0.1"},
 128       {:cowlib, "~> 2.8", override: true},
 129       {:gun,
 130        github: "ninenines/gun", ref: "e1a69b36b180a574c0ac314ced9613fdd52312cc", override: true},
 131       {:jason, "~> 1.0"},
 132       {:mogrify, "~> 0.6.1"},
 133       {:ex_aws, "~> 2.1"},
 134       {:ex_aws_s3, "~> 2.0"},
 135       {:sweet_xml, "~> 0.6.6"},
 136       {:earmark, "~> 1.3"},
 137       {:bbcode_pleroma, "~> 0.2.0"},
 138       {:ex_machina, "~> 2.3", only: :test},
 139       {:credo, "~> 1.1.0", only: [:dev, :test], runtime: false},
 140       {:mock, "~> 0.3.3", only: :test},
 141       {:crypt,
 142        git: "https://github.com/msantos/crypt", ref: "1f2b58927ab57e72910191a7ebaeff984382a1d3"},
 143       {:cors_plug, "~> 1.5"},
 144       {:ex_doc, "~> 0.21", only: :dev, runtime: false},
 145       {:web_push_encryption, "~> 0.2.1"},
 146       {:swoosh, "~> 0.23.2"},
 147       {:phoenix_swoosh, "~> 0.2"},
 148       {:gen_smtp, "~> 0.13"},
 149       {:websocket_client, git: "https://github.com/jeremyong/websocket_client.git", only: :test},
 150       {:ex_syslogger, "~> 1.4"},
 151       {:floki, "~> 0.25"},
 152       {:timex, "~> 3.5"},
 153       {:ueberauth, "~> 0.4"},
 154       {:auto_linker,
 155        git: "https://git.pleroma.social/pleroma/auto_linker.git",
 156        ref: "95e8188490e97505c56636c1379ffdf036c1fdde"},
 157       {:http_signatures,
 158        git: "https://git.pleroma.social/pleroma/http_signatures.git",
 159        ref: "293d77bb6f4a67ac8bde1428735c3b42f22cbb30"},
 160       {:telemetry, "~> 0.3"},
 161       {:poolboy, "~> 1.5"},
 162       {:prometheus_ex, "~> 3.0"},
 163       {:prometheus_plugs, "~> 1.1"},
 164       {:prometheus_phoenix, "~> 1.3"},
 165       {:prometheus_ecto, "~> 1.4"},
 166       {:recon, "~> 2.5"},
 167       {:quack, "~> 0.1.1"},
 168       {:joken, "~> 2.0"},
 169       {:benchee, "~> 1.0"},
 170       {:esshd, "~> 0.1.0", runtime: Application.get_env(:esshd, :enabled, false)},
 171       {:ex_const, "~> 0.2"},
 172       {:plug_static_index_html, "~> 1.0.0"},
 173       {:excoveralls, "~> 0.12.1", only: :test},
 174       {:flake_id, "~> 0.1.0"},
 175       {:remote_ip,
 176        git: "https://git.pleroma.social/pleroma/remote_ip.git",
 177        ref: "825dc00aaba5a1b7c4202a532b696b595dd3bcb3"},
 178       {:captcha,
 179        git: "https://git.pleroma.social/pleroma/elixir-libraries/elixir-captcha.git",
 180        ref: "e0f16822d578866e186a0974d65ad58cddc1e2ab"},
 181       {:mox, "~> 0.5", only: :test},
 182       {:restarter, path: "./restarter"},
 183       {:open_api_spex, "~> 3.6"}
 184     ] ++ oauth_deps()
 185   end
 186
 187   # Aliases are shortcuts or tasks specific to the current project.
 188   # For example, to create, migrate and run the seeds file at once:
 189   #
 190   #     $ mix ecto.setup
 191   #
 192   # See the documentation for `Mix` for more info on aliases.
 193   defp aliases do
 194     [
 195       "ecto.migrate": ["pleroma.ecto.migrate"],
 196       "ecto.rollback": ["pleroma.ecto.rollback"],
 197       "ecto.setup": ["ecto.create", "ecto.migrate", "run priv/repo/seeds.exs"],
 198       "ecto.reset": ["ecto.drop", "ecto.setup"],
 199       test: ["ecto.create --quiet", "ecto.migrate", "test"],
 200       docs: ["pleroma.docs", "docs"]
 201     ]
 202   end
 203
 204   # Builds a version string made of:
 205   # * the application version
 206   # * a pre-release if ahead of the tag: the describe string (-count-commithash)
 207   # * branch name
 208   # * build metadata:
 209   #   * a build name if `PLEROMA_BUILD_NAME` or `:pleroma, :build_name` is defined
 210   #   * the mix environment if different than prod
 211   defp version(version) do
 212     identifier_filter = ~r/[^0-9a-z\-]+/i
 213
 214     # Pre-release version, denoted from patch version with a hyphen
 215     git_pre_release =
 216       with {tag, 0} <-
 217              System.cmd("git", ["describe", "--tags", "--abbrev=0"], stderr_to_stdout: true),
 218            {describe, 0} <- System.cmd("git", ["describe", "--tags", "--abbrev=8"]) do
 219         describe
 220         |> String.trim()
 221         |> String.replace(String.trim(tag), "")
 222         |> String.trim_leading("-")
 223         |> String.trim()
 224       else
 225         _ ->
 226           {commit_hash, 0} = System.cmd("git", ["rev-parse", "--short", "HEAD"])
 227           "0-g" <> String.trim(commit_hash)
 228       end
 229
 230     # Branch name as pre-release version component, denoted with a dot
 231     branch_name =
 232       with {branch_name, 0} <- System.cmd("git", ["rev-parse", "--abbrev-ref", "HEAD"]),
 233            branch_name <- String.trim(branch_name),
 234            branch_name <- System.get_env("PLEROMA_BUILD_BRANCH") || branch_name,
 235            true <-
 236              !Enum.any?(["master", "HEAD", "release/", "stable"], fn name ->
 237                String.starts_with?(name, branch_name)
 238              end) do
 239         branch_name =
 240           branch_name
 241           |> String.trim()
 242           |> String.replace(identifier_filter, "-")
 243
 244         branch_name
 245       end
 246
 247     build_name =
 248       cond do
 249         name = Application.get_env(:pleroma, :build_name) -> name
 250         name = System.get_env("PLEROMA_BUILD_NAME") -> name
 251         true -> nil
 252       end
 253
 254     env_name = if Mix.env() != :prod, do: to_string(Mix.env())
 255     env_override = System.get_env("PLEROMA_BUILD_ENV")
 256
 257     env_name =
 258       case env_override do
 259         nil -> env_name
 260         env_override when env_override in ["", "prod"] -> nil
 261         env_override -> env_override
 262       end
 263
 264     # Pre-release version, denoted by appending a hyphen
 265     # and a series of dot separated identifiers
 266     pre_release =
 267       [git_pre_release, branch_name]
 268       |> Enum.filter(fn string -> string && string != "" end)
 269       |> Enum.join(".")
 270       |> (fn
 271             "" -> nil
 272             string -> "-" <> String.replace(string, identifier_filter, "-")
 273           end).()
 274
 275     # Build metadata, denoted with a plus sign
 276     build_metadata =
 277       [build_name, env_name]
 278       |> Enum.filter(fn string -> string && string != "" end)
 279       |> Enum.join(".")
 280       |> (fn
 281             "" -> nil
 282             string -> "+" <> String.replace(string, identifier_filter, "-")
 283           end).()
 284
 285     [version, pre_release, build_metadata]
 286     |> Enum.filter(fn string -> string && string != "" end)
 287     |> Enum.join()
 288   end
 289 end