git.squeep.com Git - akkoma/blob - mix.exs

   1 defmodule Pleroma.Mixfile do
   2   use Mix.Project
   3
   4   def project do
   5     [
   6       app: :pleroma,
   7       version: version("2.1.50"),
   8       elixir: "~> 1.9",
   9       elixirc_paths: elixirc_paths(Mix.env()),
  10       compilers: [:phoenix, :gettext] ++ Mix.compilers(),
  11       elixirc_options: [warnings_as_errors: warnings_as_errors(Mix.env())],
  12       xref: [exclude: [:eldap]],
  13       start_permanent: Mix.env() == :prod,
  14       aliases: aliases(),
  15       deps: deps(),
  16       test_coverage: [tool: ExCoveralls],
  17       preferred_cli_env: ["coveralls.html": :test],
  18       # Docs
  19       name: "Pleroma",
  20       homepage_url: "https://pleroma.social/",
  21       source_url: "https://git.pleroma.social/pleroma/pleroma",
  22       docs: [
  23         source_url_pattern:
  24           "https://git.pleroma.social/pleroma/pleroma/blob/develop/%{path}#L%{line}",
  25         logo: "priv/static/static/logo.png",
  26         extras: ["README.md", "CHANGELOG.md"] ++ Path.wildcard("docs/**/*.md"),
  27         groups_for_extras: [
  28           "Installation manuals": Path.wildcard("docs/installation/*.md"),
  29           Configuration: Path.wildcard("docs/config/*.md"),
  30           Administration: Path.wildcard("docs/admin/*.md"),
  31           "Pleroma's APIs and Mastodon API extensions": Path.wildcard("docs/api/*.md")
  32         ],
  33         main: "readme",
  34         output: "priv/static/doc"
  35       ],
  36       releases: [
  37         pleroma: [
  38           include_executables_for: [:unix],
  39           applications: [ex_syslogger: :load, syslog: :load, eldap: :transient],
  40           steps: [:assemble, &put_otp_version/1, &copy_files/1, &copy_nginx_config/1]
  41         ]
  42       ]
  43     ]
  44   end
  45
  46   def put_otp_version(%{path: target_path} = release) do
  47     File.write!(
  48       Path.join([target_path, "OTP_VERSION"]),
  49       Pleroma.OTPVersion.version()
  50     )
  51
  52     release
  53   end
  54
  55   def copy_files(%{path: target_path} = release) do
  56     File.cp_r!("./rel/files", target_path)
  57     release
  58   end
  59
  60   def copy_nginx_config(%{path: target_path} = release) do
  61     File.cp!(
  62       "./installation/pleroma.nginx",
  63       Path.join([target_path, "installation", "pleroma.nginx"])
  64     )
  65
  66     release
  67   end
  68
  69   # Configuration for the OTP application.
  70   #
  71   # Type `mix help compile.app` for more information.
  72   def application do
  73     [
  74       mod: {Pleroma.Application, []},
  75       extra_applications: [
  76         :logger,
  77         :runtime_tools,
  78         :comeonin,
  79         :quack,
  80         :fast_sanitize,
  81         :ssl
  82       ],
  83       included_applications: [:ex_syslogger]
  84     ]
  85   end
  86
  87   # Specifies which paths to compile per environment.
  88   defp elixirc_paths(:benchmark), do: ["lib", "benchmarks"]
  89   defp elixirc_paths(:test), do: ["lib", "test/support"]
  90   defp elixirc_paths(_), do: ["lib"]
  91
  92   defp warnings_as_errors(:prod), do: false
  93   defp warnings_as_errors(_), do: true
  94
  95   # Specifies OAuth dependencies.
  96   defp oauth_deps do
  97     oauth_strategy_packages =
  98       System.get_env("OAUTH_CONSUMER_STRATEGIES")
  99       |> to_string()
 100       |> String.split()
 101       |> Enum.map(fn strategy_entry ->
 102         with [_strategy, dependency] <- String.split(strategy_entry, ":") do
 103           dependency
 104         else
 105           [strategy] -> "ueberauth_#{strategy}"
 106         end
 107       end)
 108
 109     for s <- oauth_strategy_packages, do: {String.to_atom(s), ">= 0.0.0"}
 110   end
 111
 112   # Specifies your project dependencies.
 113   #
 114   # Type `mix help deps` for examples and options.
 115   defp deps do
 116     [
 117       {:phoenix, "~> 1.4.17"},
 118       {:tzdata, "~> 1.0.3"},
 119       {:plug_cowboy, "~> 2.3"},
 120       {:phoenix_pubsub, "~> 1.1"},
 121       {:phoenix_ecto, "~> 4.0"},
 122       {:ecto_enum, "~> 1.4"},
 123       {:ecto_sql, "~> 3.4.4"},
 124       {:postgrex, ">= 0.15.5"},
 125       {:oban, "~> 2.0.0"},
 126       {:gettext, "~> 0.18"},
 127       {:pbkdf2_elixir, "~> 1.2"},
 128       {:bcrypt_elixir, "~> 2.2"},
 129       {:trailing_format_plug, "~> 0.0.7"},
 130       {:fast_sanitize, "~> 0.2.0"},
 131       {:html_entities, "~> 0.5", override: true},
 132       {:phoenix_html, "~> 2.14"},
 133       {:calendar, "~> 1.0"},
 134       {:cachex, "~> 3.2"},
 135       {:poison, "~> 3.0", override: true},
 136       {:tesla,
 137        git: "https://github.com/teamon/tesla/",
 138        ref: "9f7261ca49f9f901ceb73b60219ad6f8a9f6aa30",
 139        override: true},
 140       {:castore, "~> 0.1"},
 141       {:cowlib, "~> 2.9", override: true},
 142       {:gun,
 143        github: "ninenines/gun", ref: "921c47146b2d9567eac7e9a4d2ccc60fffd4f327", override: true},
 144       {:jason, "~> 1.2"},
 145       {:mogrify, "~> 0.7.4"},
 146       {:ex_aws, "~> 2.1"},
 147       {:ex_aws_s3, "~> 2.0"},
 148       {:sweet_xml, "~> 0.6.6"},
 149       {:earmark, "1.4.3"},
 150       {:bbcode_pleroma, "~> 0.2.0"},
 151       {:crypt,
 152        git: "https://github.com/msantos/crypt.git",
 153        ref: "f63a705f92c26955977ee62a313012e309a4d77a"},
 154       {:cors_plug, "~> 2.0"},
 155       {:web_push_encryption, "~> 0.3"},
 156       {:swoosh, "~> 1.0"},
 157       {:phoenix_swoosh, "~> 0.3"},
 158       {:gen_smtp, "~> 0.13"},
 159       {:ex_syslogger, "~> 1.4"},
 160       {:floki, "~> 0.27"},
 161       {:timex, "~> 3.6"},
 162       {:ueberauth, "~> 0.4"},
 163       {:linkify, "~> 0.2.0"},
 164       {:http_signatures, "~> 0.1.0"},
 165       {:telemetry, "~> 0.3"},
 166       {:poolboy, "~> 1.5"},
 167       {:prometheus, "~> 4.6"},
 168       {:prometheus_ex, "~> 3.0"},
 169       {:prometheus_plugs, "~> 1.1"},
 170       {:prometheus_phoenix, "~> 1.3"},
 171       {:prometheus_ecto, "~> 1.4"},
 172       {:recon, "~> 2.5"},
 173       {:quack, "~> 0.1.1"},
 174       {:joken, "~> 2.0"},
 175       {:benchee, "~> 1.0"},
 176       {:pot, "~> 0.11"},
 177       {:esshd, "~> 0.1.0", runtime: Application.get_env(:esshd, :enabled, false)},
 178       {:ex_const, "~> 0.2"},
 179       {:plug_static_index_html, "~> 1.0.0"},
 180       {:flake_id, "~> 0.1.0"},
 181       {:concurrent_limiter,
 182        git: "https://git.pleroma.social/pleroma/elixir-libraries/concurrent_limiter.git",
 183        ref: "55e92f84b4ed531bd487952a71040a9c69dc2807"},
 184       {:remote_ip,
 185        git: "https://git.pleroma.social/pleroma/remote_ip.git",
 186        ref: "b647d0deecaa3acb140854fe4bda5b7e1dc6d1c8"},
 187       {:captcha,
 188        git: "https://git.pleroma.social/pleroma/elixir-libraries/elixir-captcha.git",
 189        ref: "e0f16822d578866e186a0974d65ad58cddc1e2ab"},
 190       {:restarter, path: "./restarter"},
 191       {:open_api_spex,
 192        git: "https://git.pleroma.social/pleroma/elixir-libraries/open_api_spex.git",
 193        ref: "f296ac0924ba3cf79c7a588c4c252889df4c2edd"},
 194
 195       ## dev & test
 196       {:ex_doc, "~> 0.22", only: :dev, runtime: false},
 197       {:ex_machina, "~> 2.4", only: :test},
 198       {:credo, "~> 1.4", only: [:dev, :test], runtime: false},
 199       {:mock, "~> 0.3.5", only: :test},
 200       # temporary downgrade for excoveralls, hackney until hackney max_connections bug will be fixed
 201       {:excoveralls, "0.12.3", only: :test},
 202       {:hackney, "1.15.2", override: true},
 203       {:mox, "~> 0.5", only: :test},
 204       {:websocket_client, git: "https://github.com/jeremyong/websocket_client.git", only: :test}
 205     ] ++ oauth_deps()
 206   end
 207
 208   # Aliases are shortcuts or tasks specific to the current project.
 209   # For example, to create, migrate and run the seeds file at once:
 210   #
 211   #     $ mix ecto.setup
 212   #
 213   # See the documentation for `Mix` for more info on aliases.
 214   defp aliases do
 215     [
 216       "ecto.migrate": ["pleroma.ecto.migrate"],
 217       "ecto.rollback": ["pleroma.ecto.rollback"],
 218       "ecto.setup": ["ecto.create", "ecto.migrate", "run priv/repo/seeds.exs"],
 219       "ecto.reset": ["ecto.drop", "ecto.setup"],
 220       test: ["ecto.create --quiet", "ecto.migrate", "test"],
 221       docs: ["pleroma.docs", "docs"],
 222       analyze: ["credo --strict --only=warnings,todo,fixme,consistency,readability"]
 223     ]
 224   end
 225
 226   # Builds a version string made of:
 227   # * the application version
 228   # * a pre-release if ahead of the tag: the describe string (-count-commithash)
 229   # * branch name
 230   # * build metadata:
 231   #   * a build name if `PLEROMA_BUILD_NAME` or `:pleroma, :build_name` is defined
 232   #   * the mix environment if different than prod
 233   defp version(version) do
 234     identifier_filter = ~r/[^0-9a-z\-]+/i
 235
 236     git_available? = match?({_output, 0}, System.cmd("sh", ["-c", "command -v git"]))
 237
 238     git_pre_release =
 239       if git_available? do
 240         {tag, tag_err} =
 241           System.cmd("git", ["describe", "--tags", "--abbrev=0"], stderr_to_stdout: true)
 242
 243         {describe, describe_err} = System.cmd("git", ["describe", "--tags", "--abbrev=8"])
 244         {commit_hash, commit_hash_err} = System.cmd("git", ["rev-parse", "--short", "HEAD"])
 245
 246         # Pre-release version, denoted from patch version with a hyphen
 247         cond do
 248           tag_err == 0 and describe_err == 0 ->
 249             describe
 250             |> String.trim()
 251             |> String.replace(String.trim(tag), "")
 252             |> String.trim_leading("-")
 253             |> String.trim()
 254
 255           commit_hash_err == 0 ->
 256             "0-g" <> String.trim(commit_hash)
 257
 258           true ->
 259             nil
 260         end
 261       end
 262
 263     # Branch name as pre-release version component, denoted with a dot
 264     branch_name =
 265       with true <- git_available?,
 266            {branch_name, 0} <- System.cmd("git", ["rev-parse", "--abbrev-ref", "HEAD"]),
 267            branch_name <- String.trim(branch_name),
 268            branch_name <- System.get_env("PLEROMA_BUILD_BRANCH") || branch_name,
 269            true <-
 270              !Enum.any?(["master", "HEAD", "release/", "stable"], fn name ->
 271                String.starts_with?(name, branch_name)
 272              end) do
 273         branch_name =
 274           branch_name
 275           |> String.trim()
 276           |> String.replace(identifier_filter, "-")
 277
 278         branch_name
 279       else
 280         _ -> ""
 281       end
 282
 283     build_name =
 284       cond do
 285         name = Application.get_env(:pleroma, :build_name) -> name
 286         name = System.get_env("PLEROMA_BUILD_NAME") -> name
 287         true -> nil
 288       end
 289
 290     env_name = if Mix.env() != :prod, do: to_string(Mix.env())
 291     env_override = System.get_env("PLEROMA_BUILD_ENV")
 292
 293     env_name =
 294       case env_override do
 295         nil -> env_name
 296         env_override when env_override in ["", "prod"] -> nil
 297         env_override -> env_override
 298       end
 299
 300     # Pre-release version, denoted by appending a hyphen
 301     # and a series of dot separated identifiers
 302     pre_release =
 303       [git_pre_release, branch_name]
 304       |> Enum.filter(fn string -> string && string != "" end)
 305       |> Enum.join(".")
 306       |> (fn
 307             "" -> nil
 308             string -> "-" <> String.replace(string, identifier_filter, "-")
 309           end).()
 310
 311     # Build metadata, denoted with a plus sign
 312     build_metadata =
 313       [build_name, env_name]
 314       |> Enum.filter(fn string -> string && string != "" end)
 315       |> Enum.join(".")
 316       |> (fn
 317             "" -> nil
 318             string -> "+" <> String.replace(string, identifier_filter, "-")
 319           end).()
 320
 321     [version, pre_release, build_metadata]
 322     |> Enum.filter(fn string -> string && string != "" end)
 323     |> Enum.join()
 324   end
 325 end