git.squeep.com Git - akkoma/blob - mix.exs

   1 defmodule Pleroma.Mixfile do
   2   use Mix.Project
   3
   4   def project do
   5     [
   6       app: :pleroma,
   7       version: version("0.9.0"),
   8       elixir: "~> 1.7",
   9       elixirc_paths: elixirc_paths(Mix.env()),
  10       compilers: [:phoenix, :gettext] ++ Mix.compilers(),
  11       elixirc_options: [warnings_as_errors: true],
  12       start_permanent: Mix.env() == :prod,
  13       aliases: aliases(),
  14       deps: deps(),
  15
  16       # Docs
  17       name: "Pleroma",
  18       source_url: "https://git.pleroma.social/pleroma/pleroma",
  19       source_url_pattern:
  20         "https://git.pleroma.social/pleroma/pleroma/blob/develop/%{path}#L%{line}",
  21       homepage_url: "https://pleroma.social/",
  22       docs: [
  23         logo: "priv/static/static/logo.png",
  24         extras: [
  25           "README.md",
  26           "docs/config.md",
  27           "docs/Pleroma-API.md",
  28           "docs/Admin-API.md",
  29           "docs/Differences-in-MastodonAPI-Responses.md"
  30         ],
  31         main: "readme",
  32         output: "priv/static/doc"
  33       ]
  34     ]
  35   end
  36
  37   # Configuration for the OTP application.
  38   #
  39   # Type `mix help compile.app` for more information.
  40   def application do
  41     [
  42       mod: {Pleroma.Application, []},
  43       extra_applications: [:logger, :runtime_tools, :comeonin],
  44       included_applications: [:ex_syslogger]
  45     ]
  46   end
  47
  48   # Specifies which paths to compile per environment.
  49   defp elixirc_paths(:test), do: ["lib", "test/support"]
  50   defp elixirc_paths(_), do: ["lib"]
  51
  52   # Specifies your project dependencies.
  53   #
  54   # Type `mix help deps` for examples and options.
  55   defp deps do
  56     [
  57       # Until Phoenix 1.4.1 is released
  58       {:phoenix, github: "phoenixframework/phoenix", branch: "v1.4"},
  59       {:plug_cowboy, "~> 1.0"},
  60       {:phoenix_pubsub, "~> 1.1"},
  61       {:phoenix_ecto, "~> 3.3"},
  62       {:postgrex, ">= 0.13.5"},
  63       {:gettext, "~> 0.15"},
  64       {:comeonin, "~> 4.1.1"},
  65       {:pbkdf2_elixir, "~> 0.12.3"},
  66       {:trailing_format_plug, "~> 0.0.7"},
  67       {:html_sanitize_ex, "~> 1.3.0"},
  68       {:html_entities, "~> 0.4"},
  69       {:phoenix_html, "~> 2.10"},
  70       {:calendar, "~> 0.17.4"},
  71       {:cachex, "~> 3.0.2"},
  72       {:httpoison, "~> 1.2.0"},
  73       {:tesla, "~> 1.2"},
  74       {:jason, "~> 1.0"},
  75       {:mogrify, "~> 0.6.1"},
  76       {:ex_aws, "~> 2.0"},
  77       {:ex_aws_s3, "~> 2.0"},
  78       {:earmark, "~> 1.3"},
  79       {:ex_machina, "~> 2.2", only: :test},
  80       {:credo, "~> 0.9.3", only: [:dev, :test]},
  81       {:mock, "~> 0.3.1", only: :test},
  82       {:crypt,
  83        git: "https://github.com/msantos/crypt", ref: "1f2b58927ab57e72910191a7ebaeff984382a1d3"},
  84       {:cors_plug, "~> 1.5"},
  85       {:ex_doc, "~> 0.19", only: :dev, runtime: false},
  86       {:web_push_encryption, "~> 0.2.1"},
  87       {:swoosh, "~> 0.20"},
  88       {:gen_smtp, "~> 0.13"},
  89       {:websocket_client, git: "https://github.com/jeremyong/websocket_client.git", only: :test},
  90       {:floki, "~> 0.20.0"},
  91       {:ex_syslogger, github: "slashmili/ex_syslogger", tag: "1.4.0"}
  92     ]
  93   end
  94
  95   # Aliases are shortcuts or tasks specific to the current project.
  96   # For example, to create, migrate and run the seeds file at once:
  97   #
  98   #     $ mix ecto.setup
  99   #
 100   # See the documentation for `Mix` for more info on aliases.
 101   defp aliases do
 102     [
 103       "ecto.setup": ["ecto.create", "ecto.migrate", "run priv/repo/seeds.exs"],
 104       "ecto.reset": ["ecto.drop", "ecto.setup"],
 105       test: ["ecto.create --quiet", "ecto.migrate", "test"]
 106     ]
 107   end
 108
 109   # Builds a version string made of:
 110   # * the application version
 111   # * a pre-release if ahead of the tag: the describe string (-count-commithash)
 112   # * build info:
 113   #   * a build name if `PLEROMA_BUILD_NAME` or `:pleroma, :build_name` is defined
 114   #   * the mix environment if different than prod
 115   defp version(version) do
 116     {git_tag, git_pre_release} =
 117       with {tag, 0} <- System.cmd("git", ["describe", "--tags", "--abbrev=0"]),
 118            tag = String.trim(tag),
 119            {describe, 0} <- System.cmd("git", ["describe", "--tags", "--abbrev=8"]),
 120            describe = String.trim(describe),
 121            ahead <- String.replace(describe, tag, "") do
 122         {String.replace_prefix(tag, "v", ""), if(ahead != "", do: String.trim(ahead))}
 123       else
 124         _ -> {nil, nil}
 125       end
 126
 127     if git_tag && version != git_tag do
 128       Mix.shell().error(
 129         "Application version #{inspect(version)} does not match git tag #{inspect(git_tag)}"
 130       )
 131     end
 132
 133     build_name =
 134       cond do
 135         name = Application.get_env(:pleroma, :build_name) -> name
 136         name = System.get_env("PLEROMA_BUILD_NAME") -> name
 137         true -> nil
 138       end
 139
 140     env_name = if Mix.env() != :prod, do: to_string(Mix.env())
 141
 142     build =
 143       [build_name, env_name]
 144       |> Enum.filter(fn string -> string && string != "" end)
 145       |> Enum.join("-")
 146       |> (fn
 147             "" -> nil
 148             string -> "+" <> string
 149           end).()
 150
 151     [version, git_pre_release, build]
 152     |> Enum.filter(fn string -> string && string != "" end)
 153     |> Enum.join()
 154   end
 155 end