git.squeep.com Git - akkoma/blob - mix.exs

   1 defmodule Pleroma.Mixfile do
   2   use Mix.Project
   3
   4   def project do
   5     [
   6       app: :pleroma,
   7       version: version("0.9.0"),
   8       elixir: "~> 1.4",
   9       elixirc_paths: elixirc_paths(Mix.env()),
  10       compilers: [:phoenix, :gettext] ++ Mix.compilers(),
  11       elixirc_options: [warnings_as_errors: true],
  12       start_permanent: Mix.env() == :prod,
  13       aliases: aliases(),
  14       deps: deps(),
  15
  16       # Docs
  17       name: "Pleroma",
  18       source_url: "https://git.pleroma.social/pleroma/pleroma",
  19       source_url_pattern:
  20         "https://git.pleroma.social/pleroma/pleroma/blob/develop/%{path}#L%{line}",
  21       homepage_url: "https://pleroma.social/",
  22       docs: [
  23         logo: "priv/static/static/logo.png",
  24         extras: ["README.md", "config/config.md"],
  25         main: "readme"
  26       ]
  27     ]
  28   end
  29
  30   # Configuration for the OTP application.
  31   #
  32   # Type `mix help compile.app` for more information.
  33   def application do
  34     [mod: {Pleroma.Application, []}, extra_applications: [:logger, :runtime_tools, :comeonin]]
  35   end
  36
  37   # Specifies which paths to compile per environment.
  38   defp elixirc_paths(:test), do: ["lib", "test/support"]
  39   defp elixirc_paths(_), do: ["lib"]
  40
  41   # Specifies your project dependencies.
  42   #
  43   # Type `mix help deps` for examples and options.
  44   defp deps do
  45     [
  46       # Until Phoenix 1.4.1 is released
  47       {:phoenix, github: "phoenixframework/phoenix", branch: "v1.4"},
  48       {:plug_cowboy, "~> 1.0"},
  49       {:phoenix_pubsub, "~> 1.1"},
  50       {:phoenix_ecto, "~> 3.3"},
  51       {:postgrex, ">= 0.13.5"},
  52       {:gettext, "~> 0.15"},
  53       {:comeonin, "~> 4.1.1"},
  54       {:pbkdf2_elixir, "~> 0.12.3"},
  55       {:trailing_format_plug, "~> 0.0.7"},
  56       {:html_sanitize_ex, "~> 1.3.0"},
  57       {:phoenix_html, "~> 2.10"},
  58       {:calendar, "~> 0.17.4"},
  59       {:cachex, "~> 3.0.2"},
  60       {:httpoison, "~> 1.2.0"},
  61       {:tesla, "~> 1.2"},
  62       {:jason, "~> 1.0"},
  63       {:mogrify, "~> 0.6.1"},
  64       {:ex_aws, "~> 2.0"},
  65       {:ex_aws_s3, "~> 2.0"},
  66       {:earmark, "~> 1.3"},
  67       {:ex_machina, "~> 2.2", only: :test},
  68       {:credo, "~> 0.9.3", only: [:dev, :test]},
  69       {:mock, "~> 0.3.1", only: :test},
  70       {:crypt,
  71        git: "https://github.com/msantos/crypt", ref: "1f2b58927ab57e72910191a7ebaeff984382a1d3"},
  72       {:cors_plug, "~> 1.5"},
  73       {:ex_doc, "> 0.18.3 and < 0.20.0", only: :dev, runtime: false},
  74       {:web_push_encryption, "~> 0.2.1"},
  75       {:swoosh, "~> 0.20"},
  76       {:gen_smtp, "~> 0.13"},
  77       {:websocket_client, git: "https://github.com/jeremyong/websocket_client.git", only: :test}
  78     ]
  79   end
  80
  81   # Aliases are shortcuts or tasks specific to the current project.
  82   # For example, to create, migrate and run the seeds file at once:
  83   #
  84   #     $ mix ecto.setup
  85   #
  86   # See the documentation for `Mix` for more info on aliases.
  87   defp aliases do
  88     [
  89       "ecto.setup": ["ecto.create", "ecto.migrate", "run priv/repo/seeds.exs"],
  90       "ecto.reset": ["ecto.drop", "ecto.setup"],
  91       test: ["ecto.create --quiet", "ecto.migrate", "test"]
  92     ]
  93   end
  94
  95   # Builds a version string made of:
  96   # * the application version
  97   # * a pre-release if ahead of the tag: the describe string (-count-commithash)
  98   # * build info:
  99   #   * a build name if `PLEROMA_BUILD_NAME` or `:pleroma, :build_name` is defined
 100   #   * the mix environment if different than prod
 101   defp version(version) do
 102     {git_tag, git_pre_release} =
 103       with {tag, 0} <- System.cmd("git", ["describe", "--tags", "--abbrev=0"]),
 104            tag = String.trim(tag),
 105            {describe, 0} <- System.cmd("git", ["describe", "--tags", "--abbrev=8"]),
 106            describe = String.trim(describe),
 107            ahead <- String.replace(describe, tag, "") do
 108         {String.replace_prefix(tag, "v", ""), if(ahead != "", do: String.trim(ahead))}
 109       else
 110         _ -> {nil, nil}
 111       end
 112
 113     if git_tag && version != git_tag do
 114       Mix.shell().error(
 115         "Application version #{inspect(version)} does not match git tag #{inspect(git_tag)}"
 116       )
 117     end
 118
 119     build_name =
 120       cond do
 121         name = Application.get_env(:pleroma, :build_name) -> name
 122         name = System.get_env("PLEROMA_BUILD_NAME") -> name
 123         true -> nil
 124       end
 125
 126     env_name = if Mix.env() != :prod, do: to_string(Mix.env())
 127
 128     build =
 129       [build_name, env_name]
 130       |> Enum.filter(fn string -> string && string != "" end)
 131       |> Enum.join("-")
 132       |> (fn
 133             "" -> nil
 134             string -> "+" <> string
 135           end).()
 136
 137     [version, git_pre_release, build]
 138     |> Enum.filter(fn string -> string && string != "" end)
 139     |> Enum.join()
 140   end
 141 end