git.squeep.com Git - akkoma/blob - mix.exs

   1 defmodule Pleroma.Mixfile do
   2   use Mix.Project
   3
   4   def project do
   5     [
   6       app: :pleroma,
   7       version: version("1.1.50"),
   8       elixir: "~> 1.8",
   9       elixirc_paths: elixirc_paths(Mix.env()),
  10       compilers: [:phoenix, :gettext] ++ Mix.compilers(),
  11       elixirc_options: [warnings_as_errors: true],
  12       xref: [exclude: [:eldap]],
  13       start_permanent: Mix.env() == :prod,
  14       aliases: aliases(),
  15       deps: deps(),
  16       test_coverage: [tool: ExCoveralls],
  17       preferred_cli_env: ["coveralls.html": :test],
  18       # Docs
  19       name: "Pleroma",
  20       homepage_url: "https://pleroma.social/",
  21       source_url: "https://git.pleroma.social/pleroma/pleroma",
  22       docs: [
  23         source_url_pattern:
  24           "https://git.pleroma.social/pleroma/pleroma/blob/develop/%{path}#L%{line}",
  25         logo: "priv/static/static/logo.png",
  26         extras: ["README.md", "CHANGELOG.md"] ++ Path.wildcard("docs/**/*.md"),
  27         groups_for_extras: [
  28           "Installation manuals": Path.wildcard("docs/installation/*.md"),
  29           Configuration: Path.wildcard("docs/config/*.md"),
  30           Administration: Path.wildcard("docs/admin/*.md"),
  31           "Pleroma's APIs and Mastodon API extensions": Path.wildcard("docs/api/*.md")
  32         ],
  33         main: "readme",
  34         output: "priv/static/doc"
  35       ],
  36       releases: [
  37         pleroma: [
  38           include_executables_for: [:unix],
  39           applications: [ex_syslogger: :load, syslog: :load],
  40           steps: [:assemble, &copy_files/1, &copy_nginx_config/1]
  41         ]
  42       ]
  43     ]
  44   end
  45
  46   def copy_files(%{path: target_path} = release) do
  47     File.cp_r!("./rel/files", target_path)
  48     release
  49   end
  50
  51   def copy_nginx_config(%{path: target_path} = release) do
  52     File.cp!(
  53       "./installation/pleroma.nginx",
  54       Path.join([target_path, "installation", "pleroma.nginx"])
  55     )
  56
  57     release
  58   end
  59
  60   # Configuration for the OTP application.
  61   #
  62   # Type `mix help compile.app` for more information.
  63   def application do
  64     [
  65       mod: {Pleroma.Application, []},
  66       extra_applications: [:logger, :runtime_tools, :comeonin, :quack, :myhtmlex, :swarm],
  67       included_applications: [:ex_syslogger]
  68     ]
  69   end
  70
  71   # Specifies which paths to compile per environment.
  72   defp elixirc_paths(:benchmark), do: ["lib", "benchmarks"]
  73   defp elixirc_paths(:test), do: ["lib", "test/support"]
  74   defp elixirc_paths(_), do: ["lib"]
  75
  76   # Specifies OAuth dependencies.
  77   defp oauth_deps do
  78     oauth_strategy_packages =
  79       System.get_env("OAUTH_CONSUMER_STRATEGIES")
  80       |> to_string()
  81       |> String.split()
  82       |> Enum.map(fn strategy_entry ->
  83         with [_strategy, dependency] <- String.split(strategy_entry, ":") do
  84           dependency
  85         else
  86           [strategy] -> "ueberauth_#{strategy}"
  87         end
  88       end)
  89
  90     for s <- oauth_strategy_packages, do: {String.to_atom(s), ">= 0.0.0"}
  91   end
  92
  93   # Specifies your project dependencies.
  94   #
  95   # Type `mix help deps` for examples and options.
  96   defp deps do
  97     [
  98       {:phoenix, "~> 1.4.8"},
  99       {:tzdata, "~> 0.5.21"},
 100       {:plug_cowboy, "~> 2.0"},
 101       {:phoenix_pubsub, "~> 1.1"},
 102       {:phoenix_ecto, "~> 4.0"},
 103       {:ecto_sql, "~> 3.2"},
 104       {:postgrex, ">= 0.13.5"},
 105       {:oban, "~> 0.8.1"},
 106       {:quantum, "~> 2.3"},
 107       {:gettext, "~> 0.15"},
 108       {:comeonin, "~> 4.1.1"},
 109       {:pbkdf2_elixir, "~> 0.12.3"},
 110       {:trailing_format_plug, "~> 0.0.7"},
 111       {:html_sanitize_ex, "~> 1.3.0"},
 112       {:fast_sanitize,
 113        git: "https://git.pleroma.social/pleroma/fast_sanitize.git",
 114        ref: "37f55e2bbe6eb44e8a9c4b3831a5ce73a2f6955c"},
 115       {:html_entities, "~> 0.4"},
 116       {:phoenix_html, "~> 2.10"},
 117       {:calendar, "~> 0.17.4"},
 118       {:cachex, "~> 3.0.2"},
 119       {:poison, "~> 3.0", override: true},
 120       {:tesla, "~> 1.3", override: true},
 121       {:jason, "~> 1.0"},
 122       {:mogrify, "~> 0.6.1"},
 123       {:ex_aws, "~> 2.1"},
 124       {:ex_aws_s3, "~> 2.0"},
 125       {:sweet_xml, "~> 0.6.6"},
 126       {:earmark, "~> 1.3"},
 127       {:bbcode, "~> 0.1.1"},
 128       {:ex_machina, "~> 2.3", only: :test},
 129       {:credo, "~> 0.9.3", only: [:dev, :test]},
 130       {:mock, "~> 0.3.3", only: :test},
 131       {:crypt,
 132        git: "https://github.com/msantos/crypt", ref: "1f2b58927ab57e72910191a7ebaeff984382a1d3"},
 133       {:cors_plug, "~> 1.5"},
 134       {:ex_doc, "~> 0.21", only: :dev, runtime: false},
 135       {:web_push_encryption, "~> 0.2.1"},
 136       {:swoosh, "~> 0.23.2"},
 137       {:phoenix_swoosh, "~> 0.2"},
 138       {:gen_smtp, "~> 0.13"},
 139       {:websocket_client, git: "https://github.com/jeremyong/websocket_client.git", only: :test},
 140       {:floki, "~> 0.23.0"},
 141       {:ex_syslogger, github: "slashmili/ex_syslogger", tag: "1.4.0"},
 142       {:timex, "~> 3.5"},
 143       {:ueberauth, "~> 0.4"},
 144       {:auto_linker,
 145        git: "https://git.pleroma.social/pleroma/auto_linker.git",
 146        ref: "95e8188490e97505c56636c1379ffdf036c1fdde"},
 147       {:http_signatures,
 148        git: "https://git.pleroma.social/pleroma/http_signatures.git",
 149        ref: "293d77bb6f4a67ac8bde1428735c3b42f22cbb30"},
 150       {:telemetry, "~> 0.3"},
 151       {:poolboy, "~> 1.5"},
 152       {:prometheus_ex, "~> 3.0"},
 153       {:prometheus_plugs, "~> 1.1"},
 154       {:prometheus_phoenix, "~> 1.3"},
 155       {:prometheus_ecto, "~> 1.4"},
 156       {:recon, github: "ferd/recon", tag: "2.4.0"},
 157       {:quack, "~> 0.1.1"},
 158       {:joken, "~> 2.0"},
 159       {:benchee, "~> 1.0"},
 160       {:esshd, "~> 0.1.0", runtime: Application.get_env(:esshd, :enabled, false)},
 161       {:ex_rated, "~> 1.3"},
 162       {:ex_const, "~> 0.2"},
 163       {:plug_static_index_html, "~> 1.0.0"},
 164       {:excoveralls, "~> 0.11.1", only: :test},
 165       {:flake_id, "~> 0.1.0"},
 166       {:remote_ip,
 167        git: "https://git.pleroma.social/pleroma/remote_ip.git",
 168        ref: "825dc00aaba5a1b7c4202a532b696b595dd3bcb3"},
 169       {:mox, "~> 0.5", only: :test}
 170     ] ++ oauth_deps()
 171   end
 172
 173   # Aliases are shortcuts or tasks specific to the current project.
 174   # For example, to create, migrate and run the seeds file at once:
 175   #
 176   #     $ mix ecto.setup
 177   #
 178   # See the documentation for `Mix` for more info on aliases.
 179   defp aliases do
 180     [
 181       "ecto.migrate": ["pleroma.ecto.migrate"],
 182       "ecto.rollback": ["pleroma.ecto.rollback"],
 183       "ecto.setup": ["ecto.create", "ecto.migrate", "run priv/repo/seeds.exs"],
 184       "ecto.reset": ["ecto.drop", "ecto.setup"],
 185       test: ["ecto.create --quiet", "ecto.migrate", "test"],
 186       docs: ["pleroma.docs", "docs"]
 187     ]
 188   end
 189
 190   # Builds a version string made of:
 191   # * the application version
 192   # * a pre-release if ahead of the tag: the describe string (-count-commithash)
 193   # * branch name
 194   # * build metadata:
 195   #   * a build name if `PLEROMA_BUILD_NAME` or `:pleroma, :build_name` is defined
 196   #   * the mix environment if different than prod
 197   defp version(version) do
 198     identifier_filter = ~r/[^0-9a-z\-]+/i
 199
 200     # Pre-release version, denoted from patch version with a hyphen
 201     {git_tag, git_pre_release} =
 202       with {tag, 0} <-
 203              System.cmd("git", ["describe", "--tags", "--abbrev=0"], stderr_to_stdout: true),
 204            tag = String.trim(tag),
 205            {describe, 0} <- System.cmd("git", ["describe", "--tags", "--abbrev=8"]),
 206            describe = String.trim(describe),
 207            ahead <- String.replace(describe, tag, ""),
 208            ahead <- String.trim_leading(ahead, "-") do
 209         {String.replace_prefix(tag, "v", ""), if(ahead != "", do: String.trim(ahead))}
 210       else
 211         _ ->
 212           {commit_hash, 0} = System.cmd("git", ["rev-parse", "--short", "HEAD"])
 213           {nil, "0-g" <> String.trim(commit_hash)}
 214       end
 215
 216     if git_tag && version != git_tag do
 217       Mix.shell().error(
 218         "Application version #{inspect(version)} does not match git tag #{inspect(git_tag)}"
 219       )
 220     end
 221
 222     # Branch name as pre-release version component, denoted with a dot
 223     branch_name =
 224       with {branch_name, 0} <- System.cmd("git", ["rev-parse", "--abbrev-ref", "HEAD"]),
 225            branch_name <- String.trim(branch_name),
 226            branch_name <- System.get_env("PLEROMA_BUILD_BRANCH") || branch_name,
 227            true <-
 228              !Enum.any?(["master", "HEAD", "release/", "stable"], fn name ->
 229                String.starts_with?(name, branch_name)
 230              end) do
 231         branch_name =
 232           branch_name
 233           |> String.trim()
 234           |> String.replace(identifier_filter, "-")
 235
 236         branch_name
 237       end
 238
 239     build_name =
 240       cond do
 241         name = Application.get_env(:pleroma, :build_name) -> name
 242         name = System.get_env("PLEROMA_BUILD_NAME") -> name
 243         true -> nil
 244       end
 245
 246     env_name = if Mix.env() != :prod, do: to_string(Mix.env())
 247     env_override = System.get_env("PLEROMA_BUILD_ENV")
 248
 249     env_name =
 250       case env_override do
 251         nil -> env_name
 252         env_override when env_override in ["", "prod"] -> nil
 253         env_override -> env_override
 254       end
 255
 256     # Pre-release version, denoted by appending a hyphen
 257     # and a series of dot separated identifiers
 258     pre_release =
 259       [git_pre_release, branch_name]
 260       |> Enum.filter(fn string -> string && string != "" end)
 261       |> Enum.join(".")
 262       |> (fn
 263             "" -> nil
 264             string -> "-" <> String.replace(string, identifier_filter, "-")
 265           end).()
 266
 267     # Build metadata, denoted with a plus sign
 268     build_metadata =
 269       [build_name, env_name]
 270       |> Enum.filter(fn string -> string && string != "" end)
 271       |> Enum.join(".")
 272       |> (fn
 273             "" -> nil
 274             string -> "+" <> String.replace(string, identifier_filter, "-")
 275           end).()
 276
 277     [version, pre_release, build_metadata]
 278     |> Enum.filter(fn string -> string && string != "" end)
 279     |> Enum.join()
 280   end
 281 end