git.squeep.com Git - akkoma/blob - mix.exs

   1 defmodule Pleroma.Mixfile do
   2   use Mix.Project
   3
   4   def project do
   5     [
   6       app: :pleroma,
   7       version: version("1.1.50"),
   8       elixir: "~> 1.8",
   9       elixirc_paths: elixirc_paths(Mix.env()),
  10       compilers: [:phoenix, :gettext] ++ Mix.compilers(),
  11       elixirc_options: [warnings_as_errors: true],
  12       xref: [exclude: [:eldap]],
  13       start_permanent: Mix.env() == :prod,
  14       aliases: aliases(),
  15       deps: deps(),
  16       test_coverage: [tool: ExCoveralls],
  17       preferred_cli_env: ["coveralls.html": :test],
  18       # Docs
  19       name: "Pleroma",
  20       homepage_url: "https://pleroma.social/",
  21       source_url: "https://git.pleroma.social/pleroma/pleroma",
  22       docs: [
  23         source_url_pattern:
  24           "https://git.pleroma.social/pleroma/pleroma/blob/develop/%{path}#L%{line}",
  25         logo: "priv/static/static/logo.png",
  26         extras: ["README.md", "CHANGELOG.md"] ++ Path.wildcard("docs/**/*.md"),
  27         groups_for_extras: [
  28           "Installation manuals": Path.wildcard("docs/installation/*.md"),
  29           Configuration: Path.wildcard("docs/config/*.md"),
  30           Administration: Path.wildcard("docs/admin/*.md"),
  31           "Pleroma's APIs and Mastodon API extensions": Path.wildcard("docs/api/*.md")
  32         ],
  33         main: "readme",
  34         output: "priv/static/doc"
  35       ],
  36       releases: [
  37         pleroma: [
  38           include_executables_for: [:unix],
  39           applications: [ex_syslogger: :load, syslog: :load],
  40           steps: [:assemble, &copy_files/1, &copy_nginx_config/1]
  41         ]
  42       ]
  43     ]
  44   end
  45
  46   def copy_files(%{path: target_path} = release) do
  47     File.cp_r!("./rel/files", target_path)
  48     release
  49   end
  50
  51   def copy_nginx_config(%{path: target_path} = release) do
  52     File.cp!(
  53       "./installation/pleroma.nginx",
  54       Path.join([target_path, "installation", "pleroma.nginx"])
  55     )
  56
  57     release
  58   end
  59
  60   # Configuration for the OTP application.
  61   #
  62   # Type `mix help compile.app` for more information.
  63   def application do
  64     [
  65       mod: {Pleroma.Application, []},
  66       extra_applications: [:logger, :runtime_tools, :comeonin, :quack, :myhtmlex, :swarm],
  67       included_applications: [:ex_syslogger]
  68     ]
  69   end
  70
  71   # Specifies which paths to compile per environment.
  72   defp elixirc_paths(:benchmark), do: ["lib", "benchmarks"]
  73   defp elixirc_paths(:test), do: ["lib", "test/support"]
  74   defp elixirc_paths(_), do: ["lib"]
  75
  76   # Specifies OAuth dependencies.
  77   defp oauth_deps do
  78     oauth_strategy_packages =
  79       System.get_env("OAUTH_CONSUMER_STRATEGIES")
  80       |> to_string()
  81       |> String.split()
  82       |> Enum.map(fn strategy_entry ->
  83         with [_strategy, dependency] <- String.split(strategy_entry, ":") do
  84           dependency
  85         else
  86           [strategy] -> "ueberauth_#{strategy}"
  87         end
  88       end)
  89
  90     for s <- oauth_strategy_packages, do: {String.to_atom(s), ">= 0.0.0"}
  91   end
  92
  93   # Specifies your project dependencies.
  94   #
  95   # Type `mix help deps` for examples and options.
  96   defp deps do
  97     [
  98       {:phoenix, "~> 1.4.8"},
  99       {:tzdata, "~> 0.5.21"},
 100       {:plug_cowboy, "~> 2.0"},
 101       {:phoenix_pubsub, "~> 1.1"},
 102       {:phoenix_ecto, "~> 4.0"},
 103       {:ecto_sql, "~> 3.2"},
 104       {:postgrex, ">= 0.13.5"},
 105       {:oban, "~> 0.8.1"},
 106       {:quantum, "~> 2.3"},
 107       {:gettext, "~> 0.15"},
 108       {:comeonin, "~> 4.1.1"},
 109       {:pbkdf2_elixir, "~> 0.12.3"},
 110       {:trailing_format_plug, "~> 0.0.7"},
 111       {:fast_sanitize,
 112        git: "https://git.pleroma.social/pleroma/fast_sanitize.git",
 113        ref: "757e816bbd2cdd3f8357d02a3ed11230e9ff80f2"},
 114       {:html_entities, "~> 0.4"},
 115       {:phoenix_html, "~> 2.10"},
 116       {:calendar, "~> 0.17.4"},
 117       {:cachex, "~> 3.0.2"},
 118       {:poison, "~> 3.0", override: true},
 119       {:tesla, "~> 1.3", override: true},
 120       {:jason, "~> 1.0"},
 121       {:mogrify, "~> 0.6.1"},
 122       {:ex_aws, "~> 2.1"},
 123       {:ex_aws_s3, "~> 2.0"},
 124       {:sweet_xml, "~> 0.6.6"},
 125       {:earmark, "~> 1.3"},
 126       {:bbcode, "~> 0.1.1"},
 127       {:ex_machina, "~> 2.3", only: :test},
 128       {:credo, "~> 0.9.3", only: [:dev, :test]},
 129       {:mock, "~> 0.3.3", only: :test},
 130       {:crypt,
 131        git: "https://github.com/msantos/crypt", ref: "1f2b58927ab57e72910191a7ebaeff984382a1d3"},
 132       {:cors_plug, "~> 1.5"},
 133       {:ex_doc, "~> 0.21", only: :dev, runtime: false},
 134       {:web_push_encryption, "~> 0.2.1"},
 135       {:swoosh, "~> 0.23.2"},
 136       {:phoenix_swoosh, "~> 0.2"},
 137       {:gen_smtp, "~> 0.13"},
 138       {:websocket_client, git: "https://github.com/jeremyong/websocket_client.git", only: :test},
 139       {:floki, "~> 0.23.0"},
 140       {:ex_syslogger, github: "slashmili/ex_syslogger", tag: "1.4.0"},
 141       {:timex, "~> 3.5"},
 142       {:ueberauth, "~> 0.4"},
 143       {:auto_linker,
 144        git: "https://git.pleroma.social/pleroma/auto_linker.git",
 145        ref: "95e8188490e97505c56636c1379ffdf036c1fdde"},
 146       {:http_signatures,
 147        git: "https://git.pleroma.social/pleroma/http_signatures.git",
 148        ref: "293d77bb6f4a67ac8bde1428735c3b42f22cbb30"},
 149       {:telemetry, "~> 0.3"},
 150       {:poolboy, "~> 1.5"},
 151       {:prometheus_ex, "~> 3.0"},
 152       {:prometheus_plugs, "~> 1.1"},
 153       {:prometheus_phoenix, "~> 1.3"},
 154       {:prometheus_ecto, "~> 1.4"},
 155       {:recon, github: "ferd/recon", tag: "2.4.0"},
 156       {:quack, "~> 0.1.1"},
 157       {:joken, "~> 2.0"},
 158       {:benchee, "~> 1.0"},
 159       {:esshd, "~> 0.1.0", runtime: Application.get_env(:esshd, :enabled, false)},
 160       {:ex_rated, "~> 1.3"},
 161       {:ex_const, "~> 0.2"},
 162       {:plug_static_index_html, "~> 1.0.0"},
 163       {:excoveralls, "~> 0.11.1", only: :test},
 164       {:flake_id, "~> 0.1.0"},
 165       {:remote_ip,
 166        git: "https://git.pleroma.social/pleroma/remote_ip.git",
 167        ref: "825dc00aaba5a1b7c4202a532b696b595dd3bcb3"},
 168       {:mox, "~> 0.5", only: :test}
 169     ] ++ oauth_deps()
 170   end
 171
 172   # Aliases are shortcuts or tasks specific to the current project.
 173   # For example, to create, migrate and run the seeds file at once:
 174   #
 175   #     $ mix ecto.setup
 176   #
 177   # See the documentation for `Mix` for more info on aliases.
 178   defp aliases do
 179     [
 180       "ecto.migrate": ["pleroma.ecto.migrate"],
 181       "ecto.rollback": ["pleroma.ecto.rollback"],
 182       "ecto.setup": ["ecto.create", "ecto.migrate", "run priv/repo/seeds.exs"],
 183       "ecto.reset": ["ecto.drop", "ecto.setup"],
 184       test: ["ecto.create --quiet", "ecto.migrate", "test"],
 185       docs: ["pleroma.docs", "docs"]
 186     ]
 187   end
 188
 189   # Builds a version string made of:
 190   # * the application version
 191   # * a pre-release if ahead of the tag: the describe string (-count-commithash)
 192   # * branch name
 193   # * build metadata:
 194   #   * a build name if `PLEROMA_BUILD_NAME` or `:pleroma, :build_name` is defined
 195   #   * the mix environment if different than prod
 196   defp version(version) do
 197     identifier_filter = ~r/[^0-9a-z\-]+/i
 198
 199     # Pre-release version, denoted from patch version with a hyphen
 200     {git_tag, git_pre_release} =
 201       with {tag, 0} <-
 202              System.cmd("git", ["describe", "--tags", "--abbrev=0"], stderr_to_stdout: true),
 203            tag = String.trim(tag),
 204            {describe, 0} <- System.cmd("git", ["describe", "--tags", "--abbrev=8"]),
 205            describe = String.trim(describe),
 206            ahead <- String.replace(describe, tag, ""),
 207            ahead <- String.trim_leading(ahead, "-") do
 208         {String.replace_prefix(tag, "v", ""), if(ahead != "", do: String.trim(ahead))}
 209       else
 210         _ ->
 211           {commit_hash, 0} = System.cmd("git", ["rev-parse", "--short", "HEAD"])
 212           {nil, "0-g" <> String.trim(commit_hash)}
 213       end
 214
 215     if git_tag && version != git_tag do
 216       Mix.shell().error(
 217         "Application version #{inspect(version)} does not match git tag #{inspect(git_tag)}"
 218       )
 219     end
 220
 221     # Branch name as pre-release version component, denoted with a dot
 222     branch_name =
 223       with {branch_name, 0} <- System.cmd("git", ["rev-parse", "--abbrev-ref", "HEAD"]),
 224            branch_name <- String.trim(branch_name),
 225            branch_name <- System.get_env("PLEROMA_BUILD_BRANCH") || branch_name,
 226            true <-
 227              !Enum.any?(["master", "HEAD", "release/", "stable"], fn name ->
 228                String.starts_with?(name, branch_name)
 229              end) do
 230         branch_name =
 231           branch_name
 232           |> String.trim()
 233           |> String.replace(identifier_filter, "-")
 234
 235         branch_name
 236       end
 237
 238     build_name =
 239       cond do
 240         name = Application.get_env(:pleroma, :build_name) -> name
 241         name = System.get_env("PLEROMA_BUILD_NAME") -> name
 242         true -> nil
 243       end
 244
 245     env_name = if Mix.env() != :prod, do: to_string(Mix.env())
 246     env_override = System.get_env("PLEROMA_BUILD_ENV")
 247
 248     env_name =
 249       case env_override do
 250         nil -> env_name
 251         env_override when env_override in ["", "prod"] -> nil
 252         env_override -> env_override
 253       end
 254
 255     # Pre-release version, denoted by appending a hyphen
 256     # and a series of dot separated identifiers
 257     pre_release =
 258       [git_pre_release, branch_name]
 259       |> Enum.filter(fn string -> string && string != "" end)
 260       |> Enum.join(".")
 261       |> (fn
 262             "" -> nil
 263             string -> "-" <> String.replace(string, identifier_filter, "-")
 264           end).()
 265
 266     # Build metadata, denoted with a plus sign
 267     build_metadata =
 268       [build_name, env_name]
 269       |> Enum.filter(fn string -> string && string != "" end)
 270       |> Enum.join(".")
 271       |> (fn
 272             "" -> nil
 273             string -> "+" <> String.replace(string, identifier_filter, "-")
 274           end).()
 275
 276     [version, pre_release, build_metadata]
 277     |> Enum.filter(fn string -> string && string != "" end)
 278     |> Enum.join()
 279   end
 280 end