git.squeep.com Git - akkoma/blob - mix.exs

   1 defmodule Pleroma.Mixfile do
   2   use Mix.Project
   3
   4   def project do
   5     [
   6       app: :pleroma,
   7       version: version("1.1.50"),
   8       elixir: "~> 1.8",
   9       elixirc_paths: elixirc_paths(Mix.env()),
  10       compilers: [:phoenix, :gettext] ++ Mix.compilers(),
  11       elixirc_options: [warnings_as_errors: warnings_as_errors(Mix.env())],
  12       xref: [exclude: [:eldap]],
  13       start_permanent: Mix.env() == :prod,
  14       aliases: aliases(),
  15       deps: deps(),
  16       test_coverage: [tool: ExCoveralls],
  17       preferred_cli_env: ["coveralls.html": :test],
  18       # Docs
  19       name: "Pleroma",
  20       homepage_url: "https://pleroma.social/",
  21       source_url: "https://git.pleroma.social/pleroma/pleroma",
  22       docs: [
  23         source_url_pattern:
  24           "https://git.pleroma.social/pleroma/pleroma/blob/develop/%{path}#L%{line}",
  25         logo: "priv/static/static/logo.png",
  26         extras: ["README.md", "CHANGELOG.md"] ++ Path.wildcard("docs/**/*.md"),
  27         groups_for_extras: [
  28           "Installation manuals": Path.wildcard("docs/installation/*.md"),
  29           Configuration: Path.wildcard("docs/config/*.md"),
  30           Administration: Path.wildcard("docs/admin/*.md"),
  31           "Pleroma's APIs and Mastodon API extensions": Path.wildcard("docs/api/*.md")
  32         ],
  33         main: "readme",
  34         output: "priv/static/doc"
  35       ],
  36       releases: [
  37         pleroma: [
  38           include_executables_for: [:unix],
  39           applications: [ex_syslogger: :load, syslog: :load],
  40           steps: [:assemble, &copy_files/1, &copy_nginx_config/1]
  41         ]
  42       ]
  43     ]
  44   end
  45
  46   def copy_files(%{path: target_path} = release) do
  47     File.cp_r!("./rel/files", target_path)
  48     release
  49   end
  50
  51   def copy_nginx_config(%{path: target_path} = release) do
  52     File.cp!(
  53       "./installation/pleroma.nginx",
  54       Path.join([target_path, "installation", "pleroma.nginx"])
  55     )
  56
  57     release
  58   end
  59
  60   # Configuration for the OTP application.
  61   #
  62   # Type `mix help compile.app` for more information.
  63   def application do
  64     [
  65       mod: {Pleroma.Application, []},
  66       extra_applications: [:logger, :runtime_tools, :comeonin, :quack, :fast_sanitize],
  67       included_applications: [:ex_syslogger]
  68     ]
  69   end
  70
  71   # Specifies which paths to compile per environment.
  72   defp elixirc_paths(:benchmark), do: ["lib", "benchmarks"]
  73   defp elixirc_paths(:test), do: ["lib", "test/support"]
  74   defp elixirc_paths(_), do: ["lib"]
  75
  76   defp warnings_as_errors(:prod), do: false
  77   # Uncomment this if you need testing configurable_from_database logic
  78   # defp warnings_as_errors(:dev), do: false
  79   defp warnings_as_errors(_), do: true
  80
  81   # Specifies OAuth dependencies.
  82   defp oauth_deps do
  83     oauth_strategy_packages =
  84       System.get_env("OAUTH_CONSUMER_STRATEGIES")
  85       |> to_string()
  86       |> String.split()
  87       |> Enum.map(fn strategy_entry ->
  88         with [_strategy, dependency] <- String.split(strategy_entry, ":") do
  89           dependency
  90         else
  91           [strategy] -> "ueberauth_#{strategy}"
  92         end
  93       end)
  94
  95     for s <- oauth_strategy_packages, do: {String.to_atom(s), ">= 0.0.0"}
  96   end
  97
  98   # Specifies your project dependencies.
  99   #
 100   # Type `mix help deps` for examples and options.
 101   defp deps do
 102     [
 103       {:phoenix, "~> 1.4.8"},
 104       {:tzdata, "~> 0.5.21"},
 105       {:plug_cowboy, "~> 2.0"},
 106       {:phoenix_pubsub, "~> 1.1"},
 107       {:phoenix_ecto, "~> 4.0"},
 108       {:ecto_enum, "~> 1.4"},
 109       {:ecto_sql, "~> 3.3.2"},
 110       {:postgrex, ">= 0.13.5"},
 111       {:oban, "~> 0.12.1"},
 112       {:gettext, "~> 0.15"},
 113       {:comeonin, "~> 4.1.1"},
 114       {:pbkdf2_elixir, "~> 0.12.3"},
 115       {:trailing_format_plug, "~> 0.0.7"},
 116       {:fast_sanitize, "~> 0.1"},
 117       {:html_entities, "~> 0.5", override: true},
 118       {:phoenix_html, "~> 2.10"},
 119       {:calendar, "~> 0.17.4"},
 120       {:cachex, "~> 3.0.2"},
 121       {:poison, "~> 3.0", override: true},
 122       {:tesla, "~> 1.3", override: true},
 123       {:castore, "~> 0.1"},
 124       {:cowlib, "~> 2.8", override: true},
 125       {:gun,
 126        github: "ninenines/gun", ref: "bd6425ab87428cf4c95f4d23e0a48fd065fbd714", override: true},
 127       {:jason, "~> 1.0"},
 128       {:mogrify, "~> 0.6.1"},
 129       {:ex_aws, "~> 2.1"},
 130       {:ex_aws_s3, "~> 2.0"},
 131       {:sweet_xml, "~> 0.6.6"},
 132       {:earmark, "~> 1.3"},
 133       {:bbcode, "~> 0.1.1"},
 134       {:ex_machina, "~> 2.3", only: :test},
 135       {:credo, "~> 1.1.0", only: [:dev, :test], runtime: false},
 136       {:mock, "~> 0.3.3", only: :test},
 137       {:crypt,
 138        git: "https://github.com/msantos/crypt", ref: "1f2b58927ab57e72910191a7ebaeff984382a1d3"},
 139       {:cors_plug, "~> 1.5"},
 140       {:ex_doc, "~> 0.21", only: :dev, runtime: false},
 141       {:web_push_encryption, "~> 0.2.1"},
 142       {:swoosh, "~> 0.23.2"},
 143       {:phoenix_swoosh, "~> 0.2"},
 144       {:gen_smtp, "~> 0.13"},
 145       {:websocket_client, git: "https://github.com/jeremyong/websocket_client.git", only: :test},
 146       {:floki, "~> 0.23.0"},
 147       {:ex_syslogger, "~> 1.4"},
 148       {:timex, "~> 3.5"},
 149       {:ueberauth, "~> 0.4"},
 150       {:auto_linker,
 151        git: "https://git.pleroma.social/pleroma/auto_linker.git",
 152        ref: "95e8188490e97505c56636c1379ffdf036c1fdde"},
 153       {:http_signatures,
 154        git: "https://git.pleroma.social/pleroma/http_signatures.git",
 155        ref: "293d77bb6f4a67ac8bde1428735c3b42f22cbb30"},
 156       {:telemetry, "~> 0.3"},
 157       {:poolboy, "~> 1.5"},
 158       {:prometheus_ex, "~> 3.0"},
 159       {:prometheus_plugs, "~> 1.1"},
 160       {:prometheus_phoenix, "~> 1.3"},
 161       {:prometheus_ecto, "~> 1.4"},
 162       {:recon, "~> 2.5"},
 163       {:quack, "~> 0.1.1"},
 164       {:joken, "~> 2.0"},
 165       {:benchee, "~> 1.0"},
 166       {:esshd, "~> 0.1.0", runtime: Application.get_env(:esshd, :enabled, false)},
 167       {:ex_const, "~> 0.2"},
 168       {:plug_static_index_html, "~> 1.0.0"},
 169       {:excoveralls, "~> 0.12.1", only: :test},
 170       {:flake_id, "~> 0.1.0"},
 171       {:remote_ip,
 172        git: "https://git.pleroma.social/pleroma/remote_ip.git",
 173        ref: "825dc00aaba5a1b7c4202a532b696b595dd3bcb3"},
 174       {:captcha,
 175        git: "https://git.pleroma.social/pleroma/elixir-libraries/elixir-captcha.git",
 176        ref: "e0f16822d578866e186a0974d65ad58cddc1e2ab"},
 177       {:mox, "~> 0.5", only: :test},
 178       {:restarter, path: "./restarter"}
 179     ] ++ oauth_deps()
 180   end
 181
 182   # Aliases are shortcuts or tasks specific to the current project.
 183   # For example, to create, migrate and run the seeds file at once:
 184   #
 185   #     $ mix ecto.setup
 186   #
 187   # See the documentation for `Mix` for more info on aliases.
 188   defp aliases do
 189     [
 190       "ecto.migrate": ["pleroma.ecto.migrate"],
 191       "ecto.rollback": ["pleroma.ecto.rollback"],
 192       "ecto.setup": ["ecto.create", "ecto.migrate", "run priv/repo/seeds.exs"],
 193       "ecto.reset": ["ecto.drop", "ecto.setup"],
 194       test: ["ecto.create --quiet", "ecto.migrate", "test"],
 195       docs: ["pleroma.docs", "docs"]
 196     ]
 197   end
 198
 199   # Builds a version string made of:
 200   # * the application version
 201   # * a pre-release if ahead of the tag: the describe string (-count-commithash)
 202   # * branch name
 203   # * build metadata:
 204   #   * a build name if `PLEROMA_BUILD_NAME` or `:pleroma, :build_name` is defined
 205   #   * the mix environment if different than prod
 206   defp version(version) do
 207     identifier_filter = ~r/[^0-9a-z\-]+/i
 208
 209     # Pre-release version, denoted from patch version with a hyphen
 210     git_pre_release =
 211       with {tag, 0} <-
 212              System.cmd("git", ["describe", "--tags", "--abbrev=0"], stderr_to_stdout: true),
 213            {describe, 0} <- System.cmd("git", ["describe", "--tags", "--abbrev=8"]) do
 214         describe
 215         |> String.trim()
 216         |> String.replace(String.trim(tag), "")
 217         |> String.trim_leading("-")
 218         |> String.trim()
 219       else
 220         _ ->
 221           {commit_hash, 0} = System.cmd("git", ["rev-parse", "--short", "HEAD"])
 222           "0-g" <> String.trim(commit_hash)
 223       end
 224
 225     # Branch name as pre-release version component, denoted with a dot
 226     branch_name =
 227       with {branch_name, 0} <- System.cmd("git", ["rev-parse", "--abbrev-ref", "HEAD"]),
 228            branch_name <- String.trim(branch_name),
 229            branch_name <- System.get_env("PLEROMA_BUILD_BRANCH") || branch_name,
 230            true <-
 231              !Enum.any?(["master", "HEAD", "release/", "stable"], fn name ->
 232                String.starts_with?(name, branch_name)
 233              end) do
 234         branch_name =
 235           branch_name
 236           |> String.trim()
 237           |> String.replace(identifier_filter, "-")
 238
 239         branch_name
 240       end
 241
 242     build_name =
 243       cond do
 244         name = Application.get_env(:pleroma, :build_name) -> name
 245         name = System.get_env("PLEROMA_BUILD_NAME") -> name
 246         true -> nil
 247       end
 248
 249     env_name = if Mix.env() != :prod, do: to_string(Mix.env())
 250     env_override = System.get_env("PLEROMA_BUILD_ENV")
 251
 252     env_name =
 253       case env_override do
 254         nil -> env_name
 255         env_override when env_override in ["", "prod"] -> nil
 256         env_override -> env_override
 257       end
 258
 259     # Pre-release version, denoted by appending a hyphen
 260     # and a series of dot separated identifiers
 261     pre_release =
 262       [git_pre_release, branch_name]
 263       |> Enum.filter(fn string -> string && string != "" end)
 264       |> Enum.join(".")
 265       |> (fn
 266             "" -> nil
 267             string -> "-" <> String.replace(string, identifier_filter, "-")
 268           end).()
 269
 270     # Build metadata, denoted with a plus sign
 271     build_metadata =
 272       [build_name, env_name]
 273       |> Enum.filter(fn string -> string && string != "" end)
 274       |> Enum.join(".")
 275       |> (fn
 276             "" -> nil
 277             string -> "+" <> String.replace(string, identifier_filter, "-")
 278           end).()
 279
 280     [version, pre_release, build_metadata]
 281     |> Enum.filter(fn string -> string && string != "" end)
 282     |> Enum.join()
 283   end
 284 end