git.squeep.com Git - akkoma/blob - mix.exs

   1 defmodule Pleroma.Mixfile do
   2   use Mix.Project
   3
   4   def project do
   5     [
   6       app: :pleroma,
   7       version: version("0.9.0"),
   8       elixir: "~> 1.7",
   9       elixirc_paths: elixirc_paths(Mix.env()),
  10       compilers: [:phoenix, :gettext] ++ Mix.compilers(),
  11       elixirc_options: [warnings_as_errors: true],
  12       start_permanent: Mix.env() == :prod,
  13       aliases: aliases(),
  14       deps: deps(),
  15
  16       # Docs
  17       name: "Pleroma",
  18       source_url: "https://git.pleroma.social/pleroma/pleroma",
  19       source_url_pattern:
  20         "https://git.pleroma.social/pleroma/pleroma/blob/develop/%{path}#L%{line}",
  21       homepage_url: "https://pleroma.social/",
  22       docs: [
  23         logo: "priv/static/static/logo.png",
  24         extras: [
  25           "README.md",
  26           "docs/Admin-API.md",
  27           "docs/Clients.md",
  28           "docs/config.md",
  29           "docs/Custom-Emoji.md",
  30           "docs/Differences-in-MastodonAPI-Responses.md",
  31           "docs/Message-Rewrite-Facility-configuration.md",
  32           "docs/Pleroma-API.md",
  33           "docs/static_dir.md"
  34         ],
  35         main: "readme",
  36         output: "priv/static/doc"
  37       ]
  38     ]
  39   end
  40
  41   # Configuration for the OTP application.
  42   #
  43   # Type `mix help compile.app` for more information.
  44   def application do
  45     [
  46       mod: {Pleroma.Application, []},
  47       extra_applications: [:logger, :runtime_tools, :comeonin],
  48       included_applications: [:ex_syslogger]
  49     ]
  50   end
  51
  52   # Specifies which paths to compile per environment.
  53   defp elixirc_paths(:test), do: ["lib", "test/support"]
  54   defp elixirc_paths(_), do: ["lib"]
  55
  56   # Specifies your project dependencies.
  57   #
  58   # Type `mix help deps` for examples and options.
  59   defp deps do
  60     [
  61       {:phoenix, "~> 1.4.1"},
  62       {:plug_cowboy, "~> 2.0"},
  63       {:phoenix_pubsub, "~> 1.1"},
  64       {:phoenix_ecto, "~> 4.0"},
  65       {:ecto_sql, "~>3.0.5"},
  66       {:postgrex, ">= 0.13.5"},
  67       {:gettext, "~> 0.15"},
  68       {:comeonin, "~> 4.1.1"},
  69       {:pbkdf2_elixir, "~> 0.12.3"},
  70       {:trailing_format_plug, "~> 0.0.7"},
  71       {:html_sanitize_ex, "~> 1.3.0"},
  72       {:html_entities, "~> 0.4"},
  73       {:phoenix_html, "~> 2.10"},
  74       {:calendar, "~> 0.17.4"},
  75       {:cachex, "~> 3.0.2"},
  76       {:httpoison, "~> 1.2.0"},
  77       {:tesla, "~> 1.2"},
  78       {:jason, "~> 1.0"},
  79       {:mogrify, "~> 0.6.1"},
  80       {:ex_aws, "~> 2.0"},
  81       {:ex_aws_s3, "~> 2.0"},
  82       {:earmark, "~> 1.3"},
  83       {:ex_machina, "~> 2.3", only: :test},
  84       {:credo, "~> 0.9.3", only: [:dev, :test]},
  85       {:mock, "~> 0.3.1", only: :test},
  86       {:crypt,
  87        git: "https://github.com/msantos/crypt", ref: "1f2b58927ab57e72910191a7ebaeff984382a1d3"},
  88       {:cors_plug, "~> 1.5"},
  89       {:ex_doc, "~> 0.19", only: :dev, runtime: false},
  90       {:web_push_encryption, "~> 0.2.1"},
  91       {:swoosh, "~> 0.20"},
  92       {:gen_smtp, "~> 0.13"},
  93       {:websocket_client, git: "https://github.com/jeremyong/websocket_client.git", only: :test},
  94       {:floki, "~> 0.20.0"},
  95       {:ex_syslogger, github: "slashmili/ex_syslogger", tag: "1.4.0"},
  96       {:timex, "~> 3.5"},
  97       {:auto_linker,
  98        git: "https://git.pleroma.social/pleroma/auto_linker.git",
  99        ref: "94193ca5f97c1f9fdf3d1469653e2d46fac34bcd"}
 100     ]
 101   end
 102
 103   # Aliases are shortcuts or tasks specific to the current project.
 104   # For example, to create, migrate and run the seeds file at once:
 105   #
 106   #     $ mix ecto.setup
 107   #
 108   # See the documentation for `Mix` for more info on aliases.
 109   defp aliases do
 110     [
 111       "ecto.setup": ["ecto.create", "ecto.migrate", "run priv/repo/seeds.exs"],
 112       "ecto.reset": ["ecto.drop", "ecto.setup"],
 113       test: ["ecto.create --quiet", "ecto.migrate", "test"]
 114     ]
 115   end
 116
 117   # Builds a version string made of:
 118   # * the application version
 119   # * a pre-release if ahead of the tag: the describe string (-count-commithash)
 120   # * build info:
 121   #   * a build name if `PLEROMA_BUILD_NAME` or `:pleroma, :build_name` is defined
 122   #   * the mix environment if different than prod
 123   defp version(version) do
 124     {git_tag, git_pre_release} =
 125       with {tag, 0} <- System.cmd("git", ["describe", "--tags", "--abbrev=0"]),
 126            tag = String.trim(tag),
 127            {describe, 0} <- System.cmd("git", ["describe", "--tags", "--abbrev=8"]),
 128            describe = String.trim(describe),
 129            ahead <- String.replace(describe, tag, "") do
 130         {String.replace_prefix(tag, "v", ""), if(ahead != "", do: String.trim(ahead))}
 131       else
 132         _ -> {nil, nil}
 133       end
 134
 135     if git_tag && version != git_tag do
 136       Mix.shell().error(
 137         "Application version #{inspect(version)} does not match git tag #{inspect(git_tag)}"
 138       )
 139     end
 140
 141     build_name =
 142       cond do
 143         name = Application.get_env(:pleroma, :build_name) -> name
 144         name = System.get_env("PLEROMA_BUILD_NAME") -> name
 145         true -> nil
 146       end
 147
 148     env_name = if Mix.env() != :prod, do: to_string(Mix.env())
 149
 150     build =
 151       [build_name, env_name]
 152       |> Enum.filter(fn string -> string && string != "" end)
 153       |> Enum.join("-")
 154       |> (fn
 155             "" -> nil
 156             string -> "+" <> string
 157           end).()
 158
 159     [version, git_pre_release, build]
 160     |> Enum.filter(fn string -> string && string != "" end)
 161     |> Enum.join()
 162   end
 163 end