git.squeep.com Git - akkoma/blob - mix.exs

   1 defmodule Pleroma.Mixfile do
   2   use Mix.Project
   3
   4   def project do
   5     [
   6       app: :pleroma,
   7       version: version("3.0.0"),
   8       elixir: "~> 1.9",
   9       elixirc_paths: elixirc_paths(Mix.env()),
  10       compilers: [:phoenix, :gettext] ++ Mix.compilers(),
  11       elixirc_options: [warnings_as_errors: warnings_as_errors()],
  12       start_permanent: Mix.env() == :prod,
  13       aliases: aliases(),
  14       deps: deps(),
  15       test_coverage: [tool: ExCoveralls],
  16       preferred_cli_env: ["coveralls.html": :test],
  17       # Docs
  18       name: "Akkoma",
  19       homepage_url: "https://akkoma.dev/",
  20       source_url: "https://akkoma.dev/AkkomaGang/akkoma",
  21       docs: [
  22         source_url_pattern: "https://akkoma.dev/AkkomaGang/akkoma/blob/develop/%{path}#L%{line}",
  23         logo: "priv/static/images/logo.png",
  24         extras: ["README.md", "CHANGELOG.md"] ++ Path.wildcard("docs/**/*.md"),
  25         groups_for_extras: [
  26           "Installation manuals": Path.wildcard("docs/installation/*.md"),
  27           Configuration: Path.wildcard("docs/config/*.md"),
  28           Administration: Path.wildcard("docs/admin/*.md"),
  29           "Pleroma's APIs and Mastodon API extensions": Path.wildcard("docs/api/*.md")
  30         ],
  31         main: "readme",
  32         output: "priv/static/doc"
  33       ],
  34       releases: [
  35         pleroma: [
  36           include_executables_for: [:unix],
  37           applications: [ex_syslogger: :load, syslog: :load],
  38           steps: [:assemble, &put_otp_version/1, &copy_files/1, &copy_nginx_config/1],
  39           config_providers: [{Pleroma.Config.ReleaseRuntimeProvider, []}]
  40         ]
  41       ]
  42     ]
  43   end
  44
  45   def put_otp_version(%{path: target_path} = release) do
  46     File.write!(
  47       Path.join([target_path, "OTP_VERSION"]),
  48       Pleroma.OTPVersion.version()
  49     )
  50
  51     release
  52   end
  53
  54   def copy_files(%{path: target_path} = release) do
  55     File.cp_r!("./rel/files", target_path)
  56     release
  57   end
  58
  59   def copy_nginx_config(%{path: target_path} = release) do
  60     File.cp!(
  61       "./installation/nginx/akkoma.nginx",
  62       Path.join([target_path, "installation", "akkoma.nginx"])
  63     )
  64
  65     release
  66   end
  67
  68   # Configuration for the OTP application.
  69   #
  70   # Type `mix help compile.app` for more information.
  71   def application do
  72     [
  73       mod: {Pleroma.Application, []},
  74       extra_applications: [
  75         :logger,
  76         :runtime_tools,
  77         :comeonin,
  78         :quack,
  79         :fast_sanitize,
  80         :os_mon,
  81         :ssl
  82       ],
  83       included_applications: [:ex_syslogger]
  84     ]
  85   end
  86
  87   # Specifies which paths to compile per environment.
  88   defp elixirc_paths(:benchmark), do: ["lib", "benchmarks", "priv/scrubbers"]
  89   defp elixirc_paths(:test), do: ["lib", "test/support"]
  90   defp elixirc_paths(_), do: ["lib"]
  91
  92   defp warnings_as_errors, do: System.get_env("CI") == "true"
  93
  94   # Specifies OAuth dependencies.
  95   defp oauth_deps do
  96     oauth_strategy_packages =
  97       System.get_env("OAUTH_CONSUMER_STRATEGIES")
  98       |> to_string()
  99       |> String.split()
 100       |> Enum.map(fn strategy_entry ->
 101         with [_strategy, dependency] <- String.split(strategy_entry, ":") do
 102           dependency
 103         else
 104           [strategy] -> "ueberauth_#{strategy}"
 105         end
 106       end)
 107
 108     for s <- oauth_strategy_packages, do: {String.to_atom(s), ">= 0.0.0"}
 109   end
 110
 111   # Specifies your project dependencies.
 112   #
 113   # Type `mix help deps` for examples and options.
 114   defp deps do
 115     [
 116       {:phoenix, "~> 1.6.11"},
 117       {:tzdata, "~> 1.1.1"},
 118       {:plug_cowboy, "~> 2.5"},
 119       {:phoenix_pubsub, "~> 2.1"},
 120       {:phoenix_ecto, "~> 4.4"},
 121       {:ecto_enum, "~> 1.4"},
 122       {:ecto_sql, "~> 3.8.3"},
 123       {:postgrex, ">= 0.16.3"},
 124       {:oban, "~> 2.12.1"},
 125       {:gettext,
 126        git: "https://github.com/tusooa/gettext.git",
 127        ref: "72fb2496b6c5280ed911bdc3756890e7f38a4808",
 128        override: true},
 129       {:bcrypt_elixir, "~> 2.2"},
 130       {:trailing_format_plug, "~> 0.0.7"},
 131       {:fast_sanitize, "~> 0.2.0"},
 132       {:html_entities, "~> 0.5", override: true},
 133       {:phoenix_html, "~> 3.1", override: true},
 134       {:calendar, "~> 1.0"},
 135       {:cachex, "~> 3.4"},
 136       {:poison, "~> 3.0", override: true},
 137       {:tesla, "~> 1.4.4", override: true},
 138       {:castore, "~> 0.1"},
 139       {:cowlib, "~> 2.9", override: true},
 140       {:gun, "~> 2.0.0-rc.1", override: true},
 141       {:finch, "~> 0.10.0"},
 142       {:jason, "~> 1.2"},
 143       {:mogrify, "~> 0.9.1"},
 144       {:ex_aws, "~> 2.1.6"},
 145       {:ex_aws_s3, "~> 2.0"},
 146       {:sweet_xml, "~> 0.7.2"},
 147       {:earmark, "~> 1.4.15"},
 148       {:bbcode_pleroma, "~> 0.2.0"},
 149       {:crypt,
 150        git: "https://github.com/msantos/crypt.git",
 151        ref: "f75cd55325e33cbea198fb41fe41871392f8fb76"},
 152       {:cors_plug, "~> 2.0"},
 153       {:web_push_encryption, "~> 0.3.1"},
 154       {:swoosh, "~> 1.0"},
 155       {:phoenix_swoosh, "~> 0.3"},
 156       {:gen_smtp, "~> 0.13"},
 157       {:ex_syslogger, "~> 1.4"},
 158       {:floki, "~> 0.27"},
 159       {:timex, "~> 3.6"},
 160       {:ueberauth, "~> 0.4"},
 161       {:linkify,
 162        git: "https://akkoma.dev/AkkomaGang/linkify.git", branch: "bugfix/line-ending-buffer"},
 163       {:http_signatures, "~> 0.1.1"},
 164       {:telemetry, "~> 0.3"},
 165       {:poolboy, "~> 1.5"},
 166       {:recon, "~> 2.5"},
 167       {:quack, "~> 0.1.1"},
 168       {:joken, "~> 2.0"},
 169       {:benchee, "~> 1.0"},
 170       {:pot, "~> 1.0"},
 171       {:ex_const, "~> 0.2"},
 172       {:plug_static_index_html, "~> 1.0.0"},
 173       {:flake_id, "~> 0.1.0"},
 174       {:concurrent_limiter, "~> 0.1.1"},
 175       {:remote_ip,
 176        git: "https://git.pleroma.social/pleroma/remote_ip.git",
 177        ref: "b647d0deecaa3acb140854fe4bda5b7e1dc6d1c8"},
 178       {:captcha,
 179        git: "https://git.pleroma.social/pleroma/elixir-libraries/elixir-captcha.git",
 180        ref: "e0f16822d578866e186a0974d65ad58cddc1e2ab"},
 181       {:restarter, path: "./restarter"},
 182       {:majic, "~> 1.0"},
 183       {:eblurhash, "~> 1.2.2"},
 184       {:open_api_spex, "3.10.0"},
 185       {:search_parser,
 186        git: "https://github.com/FloatingGhost/pleroma-contrib-search-parser.git",
 187        ref: "08971a81e68686f9ac465cfb6661d51c5e4e1e7f"},
 188       {:nimble_parsec, "~> 1.0", override: true},
 189       {:phoenix_live_dashboard, "~> 0.6.2"},
 190       {:ecto_psql_extras, "~> 0.6"},
 191       {:elasticsearch,
 192        git: "https://akkoma.dev/AkkomaGang/elasticsearch-elixir.git", ref: "main"},
 193
 194       # indirect dependency version override
 195       {:plug, "~> 1.10.4", override: true},
 196
 197       ## dev & test
 198       {:ex_doc, "~> 0.22", only: :dev, runtime: false},
 199       {:ex_machina, "~> 2.4", only: :test},
 200       {:credo, "~> 1.6", only: [:dev, :test], runtime: false},
 201       {:mock, "~> 0.3.5", only: :test},
 202       # temporary downgrade for excoveralls, hackney until hackney max_connections bug will be fixed
 203       {:excoveralls, "0.12.3", only: :test},
 204       {:mox, "~> 1.0", only: :test},
 205       {:websocket_client, git: "https://github.com/jeremyong/websocket_client.git", only: :test}
 206     ] ++ oauth_deps()
 207   end
 208
 209   # Aliases are shortcuts or tasks specific to the current project.
 210   # For example, to create, migrate and run the seeds file at once:
 211   #
 212   #     $ mix ecto.setup
 213   #
 214   # See the documentation for `Mix` for more info on aliases.
 215   defp aliases do
 216     [
 217       "ecto.migrate": ["pleroma.ecto.migrate"],
 218       "ecto.rollback": ["pleroma.ecto.rollback"],
 219       "ecto.setup": ["ecto.create", "ecto.migrate", "run priv/repo/seeds.exs"],
 220       "ecto.reset": ["ecto.drop", "ecto.setup"],
 221       test: ["ecto.create --quiet", "ecto.migrate", "test"],
 222       docs: ["pleroma.docs", "docs"],
 223       analyze: ["credo --strict --only=warnings,todo,fixme,consistency,readability"],
 224       copyright: &add_copyright/1,
 225       "copyright.bump": &bump_copyright/1
 226     ]
 227   end
 228
 229   # Builds a version string made of:
 230   # * the application version
 231   # * a pre-release if ahead of the tag: the describe string (-count-commithash)
 232   # * branch name
 233   # * build metadata:
 234   #   * a build name if `PLEROMA_BUILD_NAME` or `:pleroma, :build_name` is defined
 235   #   * the mix environment if different than prod
 236   defp version(version) do
 237     identifier_filter = ~r/[^0-9a-z\-]+/i
 238
 239     git_available? = match?({_output, 0}, System.cmd("sh", ["-c", "command -v git"]))
 240     dotgit_present? = File.exists?(".git")
 241
 242     git_pre_release =
 243       if git_available? and dotgit_present? do
 244         {tag, tag_err} =
 245           System.cmd("git", ["describe", "--tags", "--abbrev=0"], stderr_to_stdout: true)
 246
 247         {describe, describe_err} = System.cmd("git", ["describe", "--tags", "--abbrev=8"])
 248         {commit_hash, commit_hash_err} = System.cmd("git", ["rev-parse", "--short", "HEAD"])
 249
 250         # Pre-release version, denoted from patch version with a hyphen
 251         cond do
 252           tag_err == 0 and describe_err == 0 ->
 253             describe
 254             |> String.trim()
 255             |> String.replace(String.trim(tag), "")
 256             |> String.trim_leading("-")
 257             |> String.trim()
 258
 259           commit_hash_err == 0 ->
 260             "0-g" <> String.trim(commit_hash)
 261
 262           true ->
 263             nil
 264         end
 265       end
 266
 267     # Branch name as pre-release version component, denoted with a dot
 268     branch_name =
 269       with true <- git_available?,
 270            true <- dotgit_present?,
 271            {branch_name, 0} <- System.cmd("git", ["rev-parse", "--abbrev-ref", "HEAD"]),
 272            branch_name <- String.trim(branch_name),
 273            branch_name <- System.get_env("PLEROMA_BUILD_BRANCH") || branch_name,
 274            true <-
 275              !Enum.any?(["master", "HEAD", "release/", "stable"], fn name ->
 276                String.starts_with?(name, branch_name)
 277              end) do
 278         branch_name =
 279           branch_name
 280           |> String.trim()
 281           |> String.replace(identifier_filter, "-")
 282
 283         branch_name
 284       else
 285         _ -> ""
 286       end
 287
 288     build_name =
 289       cond do
 290         name = Application.get_env(:pleroma, :build_name) -> name
 291         name = System.get_env("PLEROMA_BUILD_NAME") -> name
 292         true -> nil
 293       end
 294
 295     env_name = if Mix.env() != :prod, do: to_string(Mix.env())
 296     env_override = System.get_env("PLEROMA_BUILD_ENV")
 297
 298     env_name =
 299       case env_override do
 300         nil -> env_name
 301         env_override when env_override in ["", "prod"] -> nil
 302         env_override -> env_override
 303       end
 304
 305     # Pre-release version, denoted by appending a hyphen
 306     # and a series of dot separated identifiers
 307     pre_release =
 308       [git_pre_release, branch_name]
 309       |> Enum.filter(fn string -> string && string != "" end)
 310       |> Enum.join(".")
 311       |> (fn
 312             "" -> nil
 313             string -> "-" <> String.replace(string, identifier_filter, "-")
 314           end).()
 315
 316     # Build metadata, denoted with a plus sign
 317     build_metadata =
 318       [build_name, env_name]
 319       |> Enum.filter(fn string -> string && string != "" end)
 320       |> Enum.join(".")
 321       |> (fn
 322             "" -> nil
 323             string -> "+" <> String.replace(string, identifier_filter, "-")
 324           end).()
 325
 326     [version, pre_release, build_metadata]
 327     |> Enum.filter(fn string -> string && string != "" end)
 328     |> Enum.join()
 329   end
 330
 331   defp add_copyright(_) do
 332     year = NaiveDateTime.utc_now().year
 333     template = ~s[\
 334 # Pleroma: A lightweight social networking server
 335 # Copyright © 2017-#{year} Pleroma Authors <https://pleroma.social/>
 336 # SPDX-License-Identifier: AGPL-3.0-only
 337 # Akkoma: The cooler pleroma
 338 # Copyright © 2022-#{year} Akkoma Authors <https://akkoma.dev/>
 339 # SPDX-License-Identifier: AGPL-3.0-only
 340
 341 ] |> String.replace("\n", "\\n")
 342
 343     find = "find lib test priv -type f \\( -name '*.ex' -or -name '*.exs' \\) -exec "
 344     grep = "grep -L '# Copyright © [0-9\-]* Pleroma' {} \\;"
 345     xargs = "xargs -n1 sed -i'' '1s;^;#{template};'"
 346
 347     :os.cmd(String.to_charlist("#{find}#{grep} | #{xargs}"))
 348   end
 349
 350   defp bump_copyright(_) do
 351     year = NaiveDateTime.utc_now().year
 352     find = "find lib test priv -type f \\( -name '*.ex' -or -name '*.exs' \\)"
 353
 354     xargs =
 355       "xargs sed -i'' 's;# Copyright © [0-9\-]* Pleroma.*$;# Copyright © 2017-#{year} Pleroma Authors <https://pleroma.social/>;'"
 356
 357     :os.cmd(String.to_charlist("#{find} | #{xargs}"))
 358   end
 359 end