git.squeep.com Git - akkoma/blob - mix.exs

   1 defmodule Pleroma.Mixfile do
   2   use Mix.Project
   3
   4   def project do
   5     [
   6       app: :pleroma,
   7       version: version("0.9.0"),
   8       elixir: "~> 1.7",
   9       elixirc_paths: elixirc_paths(Mix.env()),
  10       compilers: [:phoenix, :gettext] ++ Mix.compilers(),
  11       elixirc_options: [warnings_as_errors: true],
  12       xref: [exclude: [:eldap]],
  13       start_permanent: Mix.env() == :prod,
  14       aliases: aliases(),
  15       deps: deps(),
  16       test_coverage: [tool: ExCoveralls],
  17
  18       # Docs
  19       name: "Pleroma",
  20       homepage_url: "https://pleroma.social/",
  21       source_url: "https://git.pleroma.social/pleroma/pleroma",
  22       docs: [
  23         source_url_pattern:
  24           "https://git.pleroma.social/pleroma/pleroma/blob/develop/%{path}#L%{line}",
  25         logo: "priv/static/static/logo.png",
  26         extras: ["README.md", "CHANGELOG.md"] ++ Path.wildcard("docs/**/*.md"),
  27         groups_for_extras: [
  28           "Installation manuals": Path.wildcard("docs/installation/*.md"),
  29           Configuration: Path.wildcard("docs/config/*.md"),
  30           Administration: Path.wildcard("docs/admin/*.md"),
  31           "Pleroma's APIs and Mastodon API extensions": Path.wildcard("docs/api/*.md")
  32         ],
  33         main: "readme",
  34         output: "priv/static/doc"
  35       ],
  36       releases: [
  37         pleroma: [
  38           include_executables_for: [:unix],
  39           applications: [ex_syslogger: :load, syslog: :load],
  40           steps: [:assemble, &copy_files/1, &copy_nginx_config/1]
  41         ]
  42       ]
  43     ]
  44   end
  45
  46   def copy_files(%{path: target_path} = release) do
  47     File.cp_r!("./rel/files", target_path)
  48     release
  49   end
  50
  51   def copy_nginx_config(%{path: target_path} = release) do
  52     File.cp!("./installation/pleroma.nginx", Path.join([target_path, "installation", "pleroma.nginx"]))
  53     release
  54   end
  55
  56   # Configuration for the OTP application.
  57   #
  58   # Type `mix help compile.app` for more information.
  59   def application do
  60     [
  61       mod: {Pleroma.Application, []},
  62       extra_applications: [:logger, :runtime_tools, :comeonin, :quack],
  63       included_applications: [:ex_syslogger]
  64     ]
  65   end
  66
  67   # Specifies which paths to compile per environment.
  68   defp elixirc_paths(:test), do: ["lib", "test/support"]
  69   defp elixirc_paths(_), do: ["lib"]
  70
  71   # Specifies OAuth dependencies.
  72   defp oauth_deps do
  73     oauth_strategy_packages =
  74       System.get_env("OAUTH_CONSUMER_STRATEGIES")
  75       |> to_string()
  76       |> String.split()
  77       |> Enum.map(fn strategy_entry ->
  78         with [_strategy, dependency] <- String.split(strategy_entry, ":") do
  79           dependency
  80         else
  81           [strategy] -> "ueberauth_#{strategy}"
  82         end
  83       end)
  84
  85     for s <- oauth_strategy_packages, do: {String.to_atom(s), ">= 0.0.0"}
  86   end
  87
  88   # Specifies your project dependencies.
  89   #
  90   # Type `mix help deps` for examples and options.
  91   defp deps do
  92     [
  93       {:phoenix, "~> 1.4.8"},
  94       {:plug_cowboy, "~> 2.0"},
  95       {:phoenix_pubsub, "~> 1.1"},
  96       {:phoenix_ecto, "~> 4.0"},
  97       {:ecto_sql, "~> 3.1"},
  98       {:postgrex, ">= 0.13.5"},
  99       {:gettext, "~> 0.15"},
 100       {:comeonin, "~> 4.1.1"},
 101       {:pbkdf2_elixir, "~> 0.12.3"},
 102       {:trailing_format_plug, "~> 0.0.7"},
 103       {:html_sanitize_ex, "~> 1.3.0"},
 104       {:html_entities, "~> 0.4"},
 105       {:phoenix_html, "~> 2.10"},
 106       {:calendar, "~> 0.17.4"},
 107       {:cachex, "~> 3.0.2"},
 108       {:httpoison, "~> 1.2.0"},
 109       {:poison, "~> 3.0", override: true},
 110       {:tesla, "~> 1.2"},
 111       {:jason, "~> 1.0"},
 112       {:mogrify, "~> 0.6.1"},
 113       {:ex_aws, "~> 2.0"},
 114       {:ex_aws_s3, "~> 2.0"},
 115       {:earmark, "~> 1.3"},
 116       {:bbcode, "~> 0.1"},
 117       {:ex_machina, "~> 2.3", only: :test},
 118       {:credo, "~> 0.9.3", only: [:dev, :test]},
 119       {:mock, "~> 0.3.3", only: :test},
 120       {:crypt,
 121        git: "https://github.com/msantos/crypt", ref: "1f2b58927ab57e72910191a7ebaeff984382a1d3"},
 122       {:cors_plug, "~> 1.5"},
 123       {:ex_doc, "~> 0.20.2", only: :dev, runtime: false},
 124       {:web_push_encryption, "~> 0.2.1"},
 125       {:swoosh, "~> 0.20"},
 126       {:gen_smtp, "~> 0.13"},
 127       {:websocket_client, git: "https://github.com/jeremyong/websocket_client.git", only: :test},
 128       {:floki, "~> 0.20.0"},
 129       {:ex_syslogger, github: "slashmili/ex_syslogger", tag: "1.4.0"},
 130       {:timex, "~> 3.5"},
 131       {:ueberauth, "~> 0.4"},
 132       {:auto_linker,
 133        git: "https://git.pleroma.social/pleroma/auto_linker.git",
 134        ref: "95e8188490e97505c56636c1379ffdf036c1fdde"},
 135       {:http_signatures,
 136        git: "https://git.pleroma.social/pleroma/http_signatures.git",
 137        ref: "9789401987096ead65646b52b5a2ca6bf52fc531"},
 138       {:pleroma_job_queue, "~> 0.2.0"},
 139       {:telemetry, "~> 0.3"},
 140       {:prometheus_ex, "~> 3.0"},
 141       {:prometheus_plugs, "~> 1.1"},
 142       {:prometheus_phoenix, "~> 1.2"},
 143       {:prometheus_ecto, "~> 1.4"},
 144       {:recon, github: "ferd/recon", tag: "2.4.0"},
 145       {:quack, "~> 0.1.1"},
 146       {:benchee, "~> 1.0"},
 147       {:esshd, "~> 0.1.0", runtime: Application.get_env(:esshd, :enabled, false)},
 148       {:ex_rated, "~> 1.3"},
 149       {:plug_static_index_html, "~> 1.0.0"},
 150       {:excoveralls, "~> 0.11.1", only: :test}
 151     ] ++ oauth_deps()
 152   end
 153
 154   # Aliases are shortcuts or tasks specific to the current project.
 155   # For example, to create, migrate and run the seeds file at once:
 156   #
 157   #     $ mix ecto.setup
 158   #
 159   # See the documentation for `Mix` for more info on aliases.
 160   defp aliases do
 161     [
 162       "ecto.migrate": ["pleroma.ecto.migrate"],
 163       "ecto.rollback": ["pleroma.ecto.rollback"],
 164       "ecto.setup": ["ecto.create", "ecto.migrate", "run priv/repo/seeds.exs"],
 165       "ecto.reset": ["ecto.drop", "ecto.setup"],
 166       test: ["ecto.create --quiet", "ecto.migrate", "test"]
 167     ]
 168   end
 169
 170   # Builds a version string made of:
 171   # * the application version
 172   # * a pre-release if ahead of the tag: the describe string (-count-commithash)
 173   # * build info:
 174   #   * a build name if `PLEROMA_BUILD_NAME` or `:pleroma, :build_name` is defined
 175   #   * the mix environment if different than prod
 176   defp version(version) do
 177     {git_tag, git_pre_release} =
 178       with {tag, 0} <-
 179              System.cmd("git", ["describe", "--tags", "--abbrev=0"], stderr_to_stdout: true),
 180            tag = String.trim(tag),
 181            {describe, 0} <- System.cmd("git", ["describe", "--tags", "--abbrev=8"]),
 182            describe = String.trim(describe),
 183            ahead <- String.replace(describe, tag, "") do
 184         {String.replace_prefix(tag, "v", ""), if(ahead != "", do: String.trim(ahead))}
 185       else
 186         _ ->
 187           {commit_hash, 0} = System.cmd("git", ["rev-parse", "--short", "HEAD"])
 188           {nil, "-0-g" <> String.trim(commit_hash)}
 189       end
 190
 191     if git_tag && version != git_tag do
 192       Mix.shell().error(
 193         "Application version #{inspect(version)} does not match git tag #{inspect(git_tag)}"
 194       )
 195     end
 196
 197     build_name =
 198       cond do
 199         name = Application.get_env(:pleroma, :build_name) -> name
 200         name = System.get_env("PLEROMA_BUILD_NAME") -> name
 201         true -> nil
 202       end
 203
 204     env_name = if Mix.env() != :prod, do: to_string(Mix.env())
 205
 206     build =
 207       [build_name, env_name]
 208       |> Enum.filter(fn string -> string && string != "" end)
 209       |> Enum.join("-")
 210       |> (fn
 211             "" -> nil
 212             string -> "+" <> string
 213           end).()
 214
 215     branch_name =
 216       with {branch_name, 0} <- System.cmd("git", ["rev-parse", "--abbrev-ref", "HEAD"]),
 217            branch_name <- System.get_env("PLEROMA_BUILD_BRANCH") || branch_name,
 218            true <- branch_name != "master" do
 219         branch_name =
 220           String.trim(branch_name)
 221           |> String.replace(~r/\W+/, "-")
 222
 223         "-" <> branch_name
 224       end
 225
 226     [version, git_pre_release, branch_name, build]
 227     |> Enum.filter(fn string -> string && string != "" end)
 228     |> Enum.join()
 229   end
 230 end