git.squeep.com Git - akkoma/blob - mix.exs

   1 defmodule Pleroma.Mixfile do
   2   use Mix.Project
   3
   4   def project do
   5     [
   6       app: :pleroma,
   7       version: version("2.1.50"),
   8       elixir: "~> 1.9",
   9       elixirc_paths: elixirc_paths(Mix.env()),
  10       compilers: [:phoenix, :gettext] ++ Mix.compilers(),
  11       elixirc_options: [warnings_as_errors: warnings_as_errors(Mix.env())],
  12       xref: [exclude: [:eldap]],
  13       start_permanent: Mix.env() == :prod,
  14       aliases: aliases(),
  15       deps: deps(),
  16       test_coverage: [tool: ExCoveralls],
  17       preferred_cli_env: ["coveralls.html": :test],
  18       # Docs
  19       name: "Pleroma",
  20       homepage_url: "https://pleroma.social/",
  21       source_url: "https://git.pleroma.social/pleroma/pleroma",
  22       docs: [
  23         source_url_pattern:
  24           "https://git.pleroma.social/pleroma/pleroma/blob/develop/%{path}#L%{line}",
  25         logo: "priv/static/static/logo.png",
  26         extras: ["README.md", "CHANGELOG.md"] ++ Path.wildcard("docs/**/*.md"),
  27         groups_for_extras: [
  28           "Installation manuals": Path.wildcard("docs/installation/*.md"),
  29           Configuration: Path.wildcard("docs/config/*.md"),
  30           Administration: Path.wildcard("docs/admin/*.md"),
  31           "Pleroma's APIs and Mastodon API extensions": Path.wildcard("docs/api/*.md")
  32         ],
  33         main: "readme",
  34         output: "priv/static/doc"
  35       ],
  36       releases: [
  37         pleroma: [
  38           include_executables_for: [:unix],
  39           applications: [ex_syslogger: :load, syslog: :load, eldap: :transient],
  40           steps: [:assemble, &put_otp_version/1, &copy_files/1, &copy_nginx_config/1]
  41         ]
  42       ]
  43     ]
  44   end
  45
  46   def put_otp_version(%{path: target_path} = release) do
  47     File.write!(
  48       Path.join([target_path, "OTP_VERSION"]),
  49       Pleroma.OTPVersion.version()
  50     )
  51
  52     release
  53   end
  54
  55   def copy_files(%{path: target_path} = release) do
  56     File.cp_r!("./rel/files", target_path)
  57     release
  58   end
  59
  60   def copy_nginx_config(%{path: target_path} = release) do
  61     File.cp!(
  62       "./installation/pleroma.nginx",
  63       Path.join([target_path, "installation", "pleroma.nginx"])
  64     )
  65
  66     release
  67   end
  68
  69   # Configuration for the OTP application.
  70   #
  71   # Type `mix help compile.app` for more information.
  72   def application do
  73     [
  74       mod: {Pleroma.Application, []},
  75       extra_applications: [
  76         :logger,
  77         :runtime_tools,
  78         :comeonin,
  79         :quack,
  80         :fast_sanitize,
  81         :ssl
  82       ],
  83       included_applications: [:ex_syslogger]
  84     ]
  85   end
  86
  87   # Specifies which paths to compile per environment.
  88   defp elixirc_paths(:benchmark), do: ["lib", "benchmarks"]
  89   defp elixirc_paths(:test), do: ["lib", "test/support"]
  90   defp elixirc_paths(_), do: ["lib"]
  91
  92   defp warnings_as_errors(:prod), do: false
  93   defp warnings_as_errors(_), do: true
  94
  95   # Specifies OAuth dependencies.
  96   defp oauth_deps do
  97     oauth_strategy_packages =
  98       System.get_env("OAUTH_CONSUMER_STRATEGIES")
  99       |> to_string()
 100       |> String.split()
 101       |> Enum.map(fn strategy_entry ->
 102         with [_strategy, dependency] <- String.split(strategy_entry, ":") do
 103           dependency
 104         else
 105           [strategy] -> "ueberauth_#{strategy}"
 106         end
 107       end)
 108
 109     for s <- oauth_strategy_packages, do: {String.to_atom(s), ">= 0.0.0"}
 110   end
 111
 112   # Specifies your project dependencies.
 113   #
 114   # Type `mix help deps` for examples and options.
 115   defp deps do
 116     [
 117       {:phoenix, "~> 1.4.17"},
 118       {:tzdata, "~> 1.0.3"},
 119       {:plug_cowboy, "~> 2.3"},
 120       {:phoenix_pubsub, "~> 1.1"},
 121       {:phoenix_ecto, "~> 4.0"},
 122       {:ecto_enum, "~> 1.4"},
 123       {:ecto_sql, "~> 3.4.4"},
 124       {:postgrex, ">= 0.15.5"},
 125       {:oban, "~> 2.0.0"},
 126       {:gettext, "~> 0.18"},
 127       {:pbkdf2_elixir, "~> 1.2"},
 128       {:bcrypt_elixir, "~> 2.2"},
 129       {:trailing_format_plug, "~> 0.0.7"},
 130       {:fast_sanitize, "~> 0.2.0"},
 131       {:html_entities, "~> 0.5", override: true},
 132       {:phoenix_html, "~> 2.14"},
 133       {:calendar, "~> 1.0"},
 134       {:cachex, "~> 3.2"},
 135       {:poison, "~> 3.0", override: true},
 136       {:tesla,
 137        git: "https://github.com/teamon/tesla/",
 138        ref: "9f7261ca49f9f901ceb73b60219ad6f8a9f6aa30",
 139        override: true},
 140       {:castore, "~> 0.1"},
 141       {:cowlib, "~> 2.9", override: true},
 142       {:gun,
 143        github: "ninenines/gun", ref: "921c47146b2d9567eac7e9a4d2ccc60fffd4f327", override: true},
 144       {:jason, "~> 1.2"},
 145       {:mogrify, "~> 0.7.4"},
 146       {:ex_aws, "~> 2.1"},
 147       {:ex_aws_s3, "~> 2.0"},
 148       {:sweet_xml, "~> 0.6.6"},
 149       {:earmark, "1.4.3"},
 150       {:bbcode_pleroma, "~> 0.2.0"},
 151       {:crypt,
 152        git: "https://github.com/msantos/crypt.git",
 153        ref: "f63a705f92c26955977ee62a313012e309a4d77a"},
 154       {:cors_plug, "~> 2.0"},
 155       {:web_push_encryption, "~> 0.3"},
 156       {:swoosh, "~> 1.0"},
 157       {:phoenix_swoosh, "~> 0.3"},
 158       {:gen_smtp, "~> 0.13"},
 159       {:ex_syslogger, "~> 1.4"},
 160       {:floki, "~> 0.27"},
 161       {:timex, "~> 3.6"},
 162       {:ueberauth, "~> 0.4"},
 163       {:linkify, "~> 0.2.0"},
 164       {:http_signatures, "~> 0.1.0"},
 165       {:telemetry, "~> 0.3"},
 166       {:poolboy, "~> 1.5"},
 167       {:prometheus, "~> 4.6"},
 168       {:prometheus_ex, "~> 3.0"},
 169       {:prometheus_plugs, "~> 1.1"},
 170       {:prometheus_phoenix, "~> 1.3"},
 171       {:prometheus_ecto, "~> 1.4"},
 172       {:recon, "~> 2.5"},
 173       {:quack, "~> 0.1.1"},
 174       {:joken, "~> 2.0"},
 175       {:benchee, "~> 1.0"},
 176       {:pot, "~> 0.11"},
 177       {:esshd, "~> 0.1.0", runtime: Application.get_env(:esshd, :enabled, false)},
 178       {:ex_const, "~> 0.2"},
 179       {:plug_static_index_html, "~> 1.0.0"},
 180       {:flake_id, "~> 0.1.0"},
 181       {:concurrent_limiter,
 182        git: "https://git.pleroma.social/pleroma/elixir-libraries/concurrent_limiter.git",
 183        ref: "d81be41024569330f296fc472e24198d7499ba78"},
 184       {:remote_ip,
 185        git: "https://git.pleroma.social/pleroma/remote_ip.git",
 186        ref: "b647d0deecaa3acb140854fe4bda5b7e1dc6d1c8"},
 187       {:captcha,
 188        git: "https://git.pleroma.social/pleroma/elixir-libraries/elixir-captcha.git",
 189        ref: "e0f16822d578866e186a0974d65ad58cddc1e2ab"},
 190       {:restarter, path: "./restarter"},
 191       {:majic, git: "https://github.com/hrefhref/majic", branch: "develop"},
 192       {:open_api_spex,
 193        git: "https://git.pleroma.social/pleroma/elixir-libraries/open_api_spex.git",
 194        ref: "f296ac0924ba3cf79c7a588c4c252889df4c2edd"},
 195
 196       ## dev & test
 197       {:ex_doc, "~> 0.22", only: :dev, runtime: false},
 198       {:ex_machina, "~> 2.4", only: :test},
 199       {:credo, "~> 1.4", only: [:dev, :test], runtime: false},
 200       {:mock, "~> 0.3.5", only: :test},
 201       # temporary downgrade for excoveralls, hackney until hackney max_connections bug will be fixed
 202       {:excoveralls, "0.12.3", only: :test},
 203       {:hackney, "1.15.2", override: true},
 204       {:mox, "~> 0.5", only: :test},
 205       {:websocket_client, git: "https://github.com/jeremyong/websocket_client.git", only: :test}
 206     ] ++ oauth_deps()
 207   end
 208
 209   # Aliases are shortcuts or tasks specific to the current project.
 210   # For example, to create, migrate and run the seeds file at once:
 211   #
 212   #     $ mix ecto.setup
 213   #
 214   # See the documentation for `Mix` for more info on aliases.
 215   defp aliases do
 216     [
 217       "ecto.migrate": ["pleroma.ecto.migrate"],
 218       "ecto.rollback": ["pleroma.ecto.rollback"],
 219       "ecto.setup": ["ecto.create", "ecto.migrate", "run priv/repo/seeds.exs"],
 220       "ecto.reset": ["ecto.drop", "ecto.setup"],
 221       test: ["ecto.create --quiet", "ecto.migrate", "test"],
 222       docs: ["pleroma.docs", "docs"],
 223       analyze: ["credo --strict --only=warnings,todo,fixme,consistency,readability"]
 224     ]
 225   end
 226
 227   # Builds a version string made of:
 228   # * the application version
 229   # * a pre-release if ahead of the tag: the describe string (-count-commithash)
 230   # * branch name
 231   # * build metadata:
 232   #   * a build name if `PLEROMA_BUILD_NAME` or `:pleroma, :build_name` is defined
 233   #   * the mix environment if different than prod
 234   defp version(version) do
 235     identifier_filter = ~r/[^0-9a-z\-]+/i
 236
 237     git_available? = match?({_output, 0}, System.cmd("sh", ["-c", "command -v git"]))
 238
 239     git_pre_release =
 240       if git_available? do
 241         {tag, tag_err} =
 242           System.cmd("git", ["describe", "--tags", "--abbrev=0"], stderr_to_stdout: true)
 243
 244         {describe, describe_err} = System.cmd("git", ["describe", "--tags", "--abbrev=8"])
 245         {commit_hash, commit_hash_err} = System.cmd("git", ["rev-parse", "--short", "HEAD"])
 246
 247         # Pre-release version, denoted from patch version with a hyphen
 248         cond do
 249           tag_err == 0 and describe_err == 0 ->
 250             describe
 251             |> String.trim()
 252             |> String.replace(String.trim(tag), "")
 253             |> String.trim_leading("-")
 254             |> String.trim()
 255
 256           commit_hash_err == 0 ->
 257             "0-g" <> String.trim(commit_hash)
 258
 259           true ->
 260             nil
 261         end
 262       end
 263
 264     # Branch name as pre-release version component, denoted with a dot
 265     branch_name =
 266       with true <- git_available?,
 267            {branch_name, 0} <- System.cmd("git", ["rev-parse", "--abbrev-ref", "HEAD"]),
 268            branch_name <- String.trim(branch_name),
 269            branch_name <- System.get_env("PLEROMA_BUILD_BRANCH") || branch_name,
 270            true <-
 271              !Enum.any?(["master", "HEAD", "release/", "stable"], fn name ->
 272                String.starts_with?(name, branch_name)
 273              end) do
 274         branch_name =
 275           branch_name
 276           |> String.trim()
 277           |> String.replace(identifier_filter, "-")
 278
 279         branch_name
 280       else
 281         _ -> ""
 282       end
 283
 284     build_name =
 285       cond do
 286         name = Application.get_env(:pleroma, :build_name) -> name
 287         name = System.get_env("PLEROMA_BUILD_NAME") -> name
 288         true -> nil
 289       end
 290
 291     env_name = if Mix.env() != :prod, do: to_string(Mix.env())
 292     env_override = System.get_env("PLEROMA_BUILD_ENV")
 293
 294     env_name =
 295       case env_override do
 296         nil -> env_name
 297         env_override when env_override in ["", "prod"] -> nil
 298         env_override -> env_override
 299       end
 300
 301     # Pre-release version, denoted by appending a hyphen
 302     # and a series of dot separated identifiers
 303     pre_release =
 304       [git_pre_release, branch_name]
 305       |> Enum.filter(fn string -> string && string != "" end)
 306       |> Enum.join(".")
 307       |> (fn
 308             "" -> nil
 309             string -> "-" <> String.replace(string, identifier_filter, "-")
 310           end).()
 311
 312     # Build metadata, denoted with a plus sign
 313     build_metadata =
 314       [build_name, env_name]
 315       |> Enum.filter(fn string -> string && string != "" end)
 316       |> Enum.join(".")
 317       |> (fn
 318             "" -> nil
 319             string -> "+" <> String.replace(string, identifier_filter, "-")
 320           end).()
 321
 322     [version, pre_release, build_metadata]
 323     |> Enum.filter(fn string -> string && string != "" end)
 324     |> Enum.join()
 325   end
 326 end