git.squeep.com Git - akkoma/blob - mix.exs

   1 defmodule Pleroma.Mixfile do
   2   use Mix.Project
   3
   4   def project do
   5     [
   6       app: :pleroma,
   7       version: version("2.0.50"),
   8       elixir: "~> 1.8",
   9       elixirc_paths: elixirc_paths(Mix.env()),
  10       compilers: [:phoenix, :gettext] ++ Mix.compilers(),
  11       elixirc_options: [warnings_as_errors: warnings_as_errors(Mix.env())],
  12       xref: [exclude: [:eldap]],
  13       start_permanent: Mix.env() == :prod,
  14       aliases: aliases(),
  15       deps: deps(),
  16       test_coverage: [tool: ExCoveralls],
  17       preferred_cli_env: ["coveralls.html": :test],
  18       # Docs
  19       name: "Pleroma",
  20       homepage_url: "https://pleroma.social/",
  21       source_url: "https://git.pleroma.social/pleroma/pleroma",
  22       docs: [
  23         source_url_pattern:
  24           "https://git.pleroma.social/pleroma/pleroma/blob/develop/%{path}#L%{line}",
  25         logo: "priv/static/static/logo.png",
  26         extras: ["README.md", "CHANGELOG.md"] ++ Path.wildcard("docs/**/*.md"),
  27         groups_for_extras: [
  28           "Installation manuals": Path.wildcard("docs/installation/*.md"),
  29           Configuration: Path.wildcard("docs/config/*.md"),
  30           Administration: Path.wildcard("docs/admin/*.md"),
  31           "Pleroma's APIs and Mastodon API extensions": Path.wildcard("docs/api/*.md")
  32         ],
  33         main: "readme",
  34         output: "priv/static/doc"
  35       ],
  36       releases: [
  37         pleroma: [
  38           include_executables_for: [:unix],
  39           applications: [ex_syslogger: :load, syslog: :load],
  40           steps: [:assemble, &put_otp_version/1, &copy_files/1, &copy_nginx_config/1]
  41         ]
  42       ]
  43     ]
  44   end
  45
  46   def put_otp_version(%{path: target_path} = release) do
  47     File.write!(
  48       Path.join([target_path, "OTP_VERSION"]),
  49       Pleroma.OTPVersion.version()
  50     )
  51
  52     release
  53   end
  54
  55   def copy_files(%{path: target_path} = release) do
  56     File.cp_r!("./rel/files", target_path)
  57     release
  58   end
  59
  60   def copy_nginx_config(%{path: target_path} = release) do
  61     File.cp!(
  62       "./installation/pleroma.nginx",
  63       Path.join([target_path, "installation", "pleroma.nginx"])
  64     )
  65
  66     release
  67   end
  68
  69   # Configuration for the OTP application.
  70   #
  71   # Type `mix help compile.app` for more information.
  72   def application do
  73     [
  74       mod: {Pleroma.Application, []},
  75       extra_applications: [:logger, :runtime_tools, :comeonin, :quack, :fast_sanitize, :ssl],
  76       included_applications: [:ex_syslogger]
  77     ]
  78   end
  79
  80   # Specifies which paths to compile per environment.
  81   defp elixirc_paths(:benchmark), do: ["lib", "benchmarks"]
  82   defp elixirc_paths(:test), do: ["lib", "test/support"]
  83   defp elixirc_paths(_), do: ["lib"]
  84
  85   defp warnings_as_errors(:prod), do: false
  86   # Uncomment this if you need testing configurable_from_database logic
  87   # defp warnings_as_errors(:dev), do: false
  88   defp warnings_as_errors(_), do: true
  89
  90   # Specifies OAuth dependencies.
  91   defp oauth_deps do
  92     oauth_strategy_packages =
  93       System.get_env("OAUTH_CONSUMER_STRATEGIES")
  94       |> to_string()
  95       |> String.split()
  96       |> Enum.map(fn strategy_entry ->
  97         with [_strategy, dependency] <- String.split(strategy_entry, ":") do
  98           dependency
  99         else
 100           [strategy] -> "ueberauth_#{strategy}"
 101         end
 102       end)
 103
 104     for s <- oauth_strategy_packages, do: {String.to_atom(s), ">= 0.0.0"}
 105   end
 106
 107   # Specifies your project dependencies.
 108   #
 109   # Type `mix help deps` for examples and options.
 110   defp deps do
 111     [
 112       {:phoenix, "~> 1.4.8"},
 113       {:tzdata, "~> 0.5.21"},
 114       {:plug_cowboy, "~> 2.0"},
 115       {:phoenix_pubsub, "~> 1.1"},
 116       {:phoenix_ecto, "~> 4.0"},
 117       {:ecto_enum, "~> 1.4"},
 118       {:ecto_sql, "~> 3.3.2"},
 119       {:postgrex, ">= 0.13.5"},
 120       {:oban, "~> 1.2"},
 121       {:gettext, "~> 0.15"},
 122       {:comeonin, "~> 4.1.1"},
 123       {:pbkdf2_elixir, "~> 0.12.3"},
 124       {:trailing_format_plug, "~> 0.0.7"},
 125       {:fast_sanitize, "~> 0.1"},
 126       {:html_entities, "~> 0.5", override: true},
 127       {:phoenix_html, "~> 2.10"},
 128       {:calendar, "~> 0.17.4"},
 129       {:cachex, "~> 3.2"},
 130       {:poison, "~> 3.0", override: true},
 131       # {:tesla, "~> 1.3", override: true},
 132       {:tesla,
 133        git: "https://git.pleroma.social/pleroma/elixir-libraries/tesla.git",
 134        ref: "61b7503cef33f00834f78ddfafe0d5d9dec2270b",
 135        override: true},
 136       {:castore, "~> 0.1"},
 137       {:cowlib, "~> 2.8", override: true},
 138       {:gun,
 139        github: "ninenines/gun", ref: "e1a69b36b180a574c0ac314ced9613fdd52312cc", override: true},
 140       {:jason, "~> 1.0"},
 141       {:mogrify, "~> 0.6.1"},
 142       {:ex_aws, "~> 2.1"},
 143       {:ex_aws_s3, "~> 2.0"},
 144       {:sweet_xml, "~> 0.6.6"},
 145       {:earmark, "~> 1.3"},
 146       {:bbcode_pleroma, "~> 0.2.0"},
 147       {:ex_machina, "~> 2.3", only: :test},
 148       {:credo, "~> 1.1.0", only: [:dev, :test], runtime: false},
 149       {:mock, "~> 0.3.3", only: :test},
 150       {:crypt,
 151        git: "https://github.com/msantos/crypt", ref: "1f2b58927ab57e72910191a7ebaeff984382a1d3"},
 152       {:cors_plug, "~> 1.5"},
 153       {:ex_doc, "~> 0.21", only: :dev, runtime: false},
 154       {:web_push_encryption, "~> 0.2.1"},
 155       {:swoosh, "~> 0.23.2"},
 156       {:phoenix_swoosh, "~> 0.2"},
 157       {:gen_smtp, "~> 0.13"},
 158       {:websocket_client, git: "https://github.com/jeremyong/websocket_client.git", only: :test},
 159       {:ex_syslogger, "~> 1.4"},
 160       {:floki, "~> 0.25"},
 161       {:timex, "~> 3.5"},
 162       {:ueberauth, "~> 0.4"},
 163       {:auto_linker,
 164        git: "https://git.pleroma.social/pleroma/auto_linker.git",
 165        ref: "95e8188490e97505c56636c1379ffdf036c1fdde"},
 166       {:http_signatures,
 167        git: "https://git.pleroma.social/pleroma/http_signatures.git",
 168        ref: "293d77bb6f4a67ac8bde1428735c3b42f22cbb30"},
 169       {:telemetry, "~> 0.3"},
 170       {:poolboy, "~> 1.5"},
 171       {:prometheus_ex, "~> 3.0"},
 172       {:prometheus_plugs, "~> 1.1"},
 173       {:prometheus_phoenix, "~> 1.3"},
 174       {:prometheus_ecto, "~> 1.4"},
 175       {:recon, "~> 2.5"},
 176       {:quack, "~> 0.1.1"},
 177       {:joken, "~> 2.0"},
 178       {:benchee, "~> 1.0"},
 179       {:esshd, "~> 0.1.0", runtime: Application.get_env(:esshd, :enabled, false)},
 180       {:ex_const, "~> 0.2"},
 181       {:plug_static_index_html, "~> 1.0.0"},
 182       {:excoveralls, "~> 0.12.1", only: :test},
 183       {:flake_id, "~> 0.1.0"},
 184       {:remote_ip,
 185        git: "https://git.pleroma.social/pleroma/remote_ip.git",
 186        ref: "b647d0deecaa3acb140854fe4bda5b7e1dc6d1c8"},
 187       {:captcha,
 188        git: "https://git.pleroma.social/pleroma/elixir-libraries/elixir-captcha.git",
 189        ref: "e0f16822d578866e186a0974d65ad58cddc1e2ab"},
 190       {:mox, "~> 0.5", only: :test},
 191       {:restarter, path: "./restarter"},
 192       {:open_api_spex, "~> 3.6"}
 193     ] ++ oauth_deps()
 194   end
 195
 196   # Aliases are shortcuts or tasks specific to the current project.
 197   # For example, to create, migrate and run the seeds file at once:
 198   #
 199   #     $ mix ecto.setup
 200   #
 201   # See the documentation for `Mix` for more info on aliases.
 202   defp aliases do
 203     [
 204       "ecto.migrate": ["pleroma.ecto.migrate"],
 205       "ecto.rollback": ["pleroma.ecto.rollback"],
 206       "ecto.setup": ["ecto.create", "ecto.migrate", "run priv/repo/seeds.exs"],
 207       "ecto.reset": ["ecto.drop", "ecto.setup"],
 208       test: ["ecto.create --quiet", "ecto.migrate", "test"],
 209       docs: ["pleroma.docs", "docs"]
 210     ]
 211   end
 212
 213   # Builds a version string made of:
 214   # * the application version
 215   # * a pre-release if ahead of the tag: the describe string (-count-commithash)
 216   # * branch name
 217   # * build metadata:
 218   #   * a build name if `PLEROMA_BUILD_NAME` or `:pleroma, :build_name` is defined
 219   #   * the mix environment if different than prod
 220   defp version(version) do
 221     identifier_filter = ~r/[^0-9a-z\-]+/i
 222
 223     # Pre-release version, denoted from patch version with a hyphen
 224     git_pre_release =
 225       with {tag, 0} <-
 226              System.cmd("git", ["describe", "--tags", "--abbrev=0"], stderr_to_stdout: true),
 227            {describe, 0} <- System.cmd("git", ["describe", "--tags", "--abbrev=8"]) do
 228         describe
 229         |> String.trim()
 230         |> String.replace(String.trim(tag), "")
 231         |> String.trim_leading("-")
 232         |> String.trim()
 233       else
 234         _ ->
 235           {commit_hash, 0} = System.cmd("git", ["rev-parse", "--short", "HEAD"])
 236           "0-g" <> String.trim(commit_hash)
 237       end
 238
 239     # Branch name as pre-release version component, denoted with a dot
 240     branch_name =
 241       with {branch_name, 0} <- System.cmd("git", ["rev-parse", "--abbrev-ref", "HEAD"]),
 242            branch_name <- String.trim(branch_name),
 243            branch_name <- System.get_env("PLEROMA_BUILD_BRANCH") || branch_name,
 244            true <-
 245              !Enum.any?(["master", "HEAD", "release/", "stable"], fn name ->
 246                String.starts_with?(name, branch_name)
 247              end) do
 248         branch_name =
 249           branch_name
 250           |> String.trim()
 251           |> String.replace(identifier_filter, "-")
 252
 253         branch_name
 254       end
 255
 256     build_name =
 257       cond do
 258         name = Application.get_env(:pleroma, :build_name) -> name
 259         name = System.get_env("PLEROMA_BUILD_NAME") -> name
 260         true -> nil
 261       end
 262
 263     env_name = if Mix.env() != :prod, do: to_string(Mix.env())
 264     env_override = System.get_env("PLEROMA_BUILD_ENV")
 265
 266     env_name =
 267       case env_override do
 268         nil -> env_name
 269         env_override when env_override in ["", "prod"] -> nil
 270         env_override -> env_override
 271       end
 272
 273     # Pre-release version, denoted by appending a hyphen
 274     # and a series of dot separated identifiers
 275     pre_release =
 276       [git_pre_release, branch_name]
 277       |> Enum.filter(fn string -> string && string != "" end)
 278       |> Enum.join(".")
 279       |> (fn
 280             "" -> nil
 281             string -> "-" <> String.replace(string, identifier_filter, "-")
 282           end).()
 283
 284     # Build metadata, denoted with a plus sign
 285     build_metadata =
 286       [build_name, env_name]
 287       |> Enum.filter(fn string -> string && string != "" end)
 288       |> Enum.join(".")
 289       |> (fn
 290             "" -> nil
 291             string -> "+" <> String.replace(string, identifier_filter, "-")
 292           end).()
 293
 294     [version, pre_release, build_metadata]
 295     |> Enum.filter(fn string -> string && string != "" end)
 296     |> Enum.join()
 297   end
 298 end