git.squeep.com Git - akkoma/blob - mix.exs

   1 defmodule Pleroma.Mixfile do
   2   use Mix.Project
   3
   4   def project do
   5     [
   6       app: :pleroma,
   7       version: version("0.9.0"),
   8       elixir: "~> 1.7",
   9       elixirc_paths: elixirc_paths(Mix.env()),
  10       compilers: [:phoenix, :gettext] ++ Mix.compilers(),
  11       elixirc_options: [warnings_as_errors: true],
  12       xref: [exclude: [:eldap]],
  13       start_permanent: Mix.env() == :prod,
  14       aliases: aliases(),
  15       deps: deps(),
  16       test_coverage: [tool: ExCoveralls],
  17
  18       # Docs
  19       name: "Pleroma",
  20       homepage_url: "https://pleroma.social/",
  21       source_url: "https://git.pleroma.social/pleroma/pleroma",
  22       docs: [
  23         source_url_pattern:
  24           "https://git.pleroma.social/pleroma/pleroma/blob/develop/%{path}#L%{line}",
  25         logo: "priv/static/static/logo.png",
  26         extras: ["README.md", "CHANGELOG.md"] ++ Path.wildcard("docs/**/*.md"),
  27         groups_for_extras: [
  28           "Installation manuals": Path.wildcard("docs/installation/*.md"),
  29           Configuration: Path.wildcard("docs/config/*.md"),
  30           Administration: Path.wildcard("docs/admin/*.md"),
  31           "Pleroma's APIs and Mastodon API extensions": Path.wildcard("docs/api/*.md")
  32         ],
  33         main: "readme",
  34         output: "priv/static/doc"
  35       ],
  36       releases: [
  37         pleroma: [
  38           include_executables_for: [:unix],
  39           applications: [ex_syslogger: :load, syslog: :load],
  40           steps: [:assemble, &copy_pleroma_ctl/1]
  41         ]
  42       ]
  43     ]
  44   end
  45
  46   def copy_pleroma_ctl(%{path: target_path} = release) do
  47     File.cp!("./rel/pleroma_ctl", Path.join([target_path, "bin", "pleroma_ctl"]))
  48     release
  49   end
  50
  51   # Configuration for the OTP application.
  52   #
  53   # Type `mix help compile.app` for more information.
  54   def application do
  55     [
  56       mod: {Pleroma.Application, []},
  57       extra_applications: [:logger, :runtime_tools, :comeonin, :quack],
  58       included_applications: [:ex_syslogger]
  59     ]
  60   end
  61
  62   # Specifies which paths to compile per environment.
  63   defp elixirc_paths(:test), do: ["lib", "test/support"]
  64   defp elixirc_paths(_), do: ["lib"]
  65
  66   # Specifies OAuth dependencies.
  67   defp oauth_deps do
  68     oauth_strategy_packages =
  69       System.get_env("OAUTH_CONSUMER_STRATEGIES")
  70       |> to_string()
  71       |> String.split()
  72       |> Enum.map(fn strategy_entry ->
  73         with [_strategy, dependency] <- String.split(strategy_entry, ":") do
  74           dependency
  75         else
  76           [strategy] -> "ueberauth_#{strategy}"
  77         end
  78       end)
  79
  80     for s <- oauth_strategy_packages, do: {String.to_atom(s), ">= 0.0.0"}
  81   end
  82
  83   # Specifies your project dependencies.
  84   #
  85   # Type `mix help deps` for examples and options.
  86   defp deps do
  87     [
  88       {:phoenix, "~> 1.4.1"},
  89       {:plug_cowboy, "~> 2.0"},
  90       {:phoenix_pubsub, "~> 1.1"},
  91       {:phoenix_ecto, "~> 4.0"},
  92       {:ecto_sql, "~> 3.1"},
  93       {:postgrex, ">= 0.13.5"},
  94       {:gettext, "~> 0.15"},
  95       {:comeonin, "~> 4.1.1"},
  96       {:pbkdf2_elixir, "~> 0.12.3"},
  97       {:trailing_format_plug, "~> 0.0.7"},
  98       {:html_sanitize_ex, "~> 1.3.0"},
  99       {:html_entities, "~> 0.4"},
 100       {:phoenix_html, "~> 2.10"},
 101       {:calendar, "~> 0.17.4"},
 102       {:cachex, "~> 3.0.2"},
 103       {:httpoison, "~> 1.2.0"},
 104       {:poison, "~> 3.0", override: true},
 105       {:tesla, "~> 1.2"},
 106       {:jason, "~> 1.0"},
 107       {:mogrify, "~> 0.6.1"},
 108       {:ex_aws, "~> 2.0"},
 109       {:ex_aws_s3, "~> 2.0"},
 110       {:earmark, "~> 1.3"},
 111       {:bbcode, "~> 0.1"},
 112       {:ex_machina, "~> 2.3", only: :test},
 113       {:credo, "~> 0.9.3", only: [:dev, :test]},
 114       {:mock, "~> 0.3.3", only: :test},
 115       {:crypt,
 116        git: "https://github.com/msantos/crypt", ref: "1f2b58927ab57e72910191a7ebaeff984382a1d3"},
 117       {:cors_plug, "~> 1.5"},
 118       {:ex_doc, "~> 0.20.2", only: :dev, runtime: false},
 119       {:web_push_encryption, "~> 0.2.1"},
 120       {:swoosh, "~> 0.20"},
 121       {:gen_smtp, "~> 0.13"},
 122       {:websocket_client, git: "https://github.com/jeremyong/websocket_client.git", only: :test},
 123       {:floki, "~> 0.20.0"},
 124       {:ex_syslogger, github: "slashmili/ex_syslogger", tag: "1.4.0"},
 125       {:timex, "~> 3.5"},
 126       {:ueberauth, "~> 0.4"},
 127       {:auto_linker,
 128        git: "https://git.pleroma.social/pleroma/auto_linker.git",
 129        ref: "c00c4e75b35367fa42c95ffd9b8c455bf9995829"},
 130       {:http_signatures,
 131        git: "https://git.pleroma.social/pleroma/http_signatures.git",
 132        ref: "9789401987096ead65646b52b5a2ca6bf52fc531"},
 133       {:pleroma_job_queue, "~> 0.2.0"},
 134       {:telemetry, "~> 0.3"},
 135       {:prometheus_ex, "~> 3.0"},
 136       {:prometheus_plugs, "~> 1.1"},
 137       {:prometheus_phoenix, "~> 1.2"},
 138       {:prometheus_ecto, "~> 1.4"},
 139       {:prometheus_process_collector, "~> 1.4"},
 140       {:recon, github: "ferd/recon", tag: "2.4.0"},
 141       {:quack, "~> 0.1.1"},
 142       {:benchee, "~> 1.0"},
 143       {:esshd, "~> 0.1.0", runtime: Application.get_env(:esshd, :enabled, false)},
 144       {:ex_rated, "~> 1.3"},
 145       {:plug_static_index_html, "~> 1.0.0"},
 146       {:excoveralls, "~> 0.11.1", only: :test}
 147     ] ++ oauth_deps()
 148   end
 149
 150   # Aliases are shortcuts or tasks specific to the current project.
 151   # For example, to create, migrate and run the seeds file at once:
 152   #
 153   #     $ mix ecto.setup
 154   #
 155   # See the documentation for `Mix` for more info on aliases.
 156   defp aliases do
 157     [
 158       "ecto.setup": ["ecto.create", "ecto.migrate", "run priv/repo/seeds.exs"],
 159       "ecto.reset": ["ecto.drop", "ecto.setup"],
 160       test: ["ecto.create --quiet", "ecto.migrate", "test"]
 161     ]
 162   end
 163
 164   # Builds a version string made of:
 165   # * the application version
 166   # * a pre-release if ahead of the tag: the describe string (-count-commithash)
 167   # * build info:
 168   #   * a build name if `PLEROMA_BUILD_NAME` or `:pleroma, :build_name` is defined
 169   #   * the mix environment if different than prod
 170   defp version(version) do
 171     {git_tag, git_pre_release} =
 172       with {tag, 0} <-
 173              System.cmd("git", ["describe", "--tags", "--abbrev=0"], stderr_to_stdout: true),
 174            tag = String.trim(tag),
 175            {describe, 0} <- System.cmd("git", ["describe", "--tags", "--abbrev=8"]),
 176            describe = String.trim(describe),
 177            ahead <- String.replace(describe, tag, "") do
 178         {String.replace_prefix(tag, "v", ""), if(ahead != "", do: String.trim(ahead))}
 179       else
 180         _ -> {nil, nil}
 181       end
 182
 183     if git_tag && version != git_tag do
 184       Mix.shell().error(
 185         "Application version #{inspect(version)} does not match git tag #{inspect(git_tag)}"
 186       )
 187     end
 188
 189     build_name =
 190       cond do
 191         name = Application.get_env(:pleroma, :build_name) -> name
 192         name = System.get_env("PLEROMA_BUILD_NAME") -> name
 193         true -> nil
 194       end
 195
 196     env_name = if Mix.env() != :prod, do: to_string(Mix.env())
 197
 198     build =
 199       [build_name, env_name]
 200       |> Enum.filter(fn string -> string && string != "" end)
 201       |> Enum.join("-")
 202       |> (fn
 203             "" -> nil
 204             string -> "+" <> string
 205           end).()
 206
 207     [version, git_pre_release, build]
 208     |> Enum.filter(fn string -> string && string != "" end)
 209     |> Enum.join()
 210   end
 211 end