git.squeep.com Git - akkoma/blob - mix.exs

   1 defmodule Pleroma.Mixfile do
   2   use Mix.Project
   3
   4   def project do
   5     [
   6       app: :pleroma,
   7       version: version("2.0.50"),
   8       elixir: "~> 1.8",
   9       elixirc_paths: elixirc_paths(Mix.env()),
  10       compilers: [:phoenix, :gettext] ++ Mix.compilers(),
  11       elixirc_options: [warnings_as_errors: warnings_as_errors(Mix.env())],
  12       xref: [exclude: [:eldap]],
  13       start_permanent: Mix.env() == :prod,
  14       aliases: aliases(),
  15       deps: deps(),
  16       test_coverage: [tool: ExCoveralls],
  17       preferred_cli_env: ["coveralls.html": :test],
  18       # Docs
  19       name: "Pleroma",
  20       homepage_url: "https://pleroma.social/",
  21       source_url: "https://git.pleroma.social/pleroma/pleroma",
  22       docs: [
  23         source_url_pattern:
  24           "https://git.pleroma.social/pleroma/pleroma/blob/develop/%{path}#L%{line}",
  25         logo: "priv/static/static/logo.png",
  26         extras: ["README.md", "CHANGELOG.md"] ++ Path.wildcard("docs/**/*.md"),
  27         groups_for_extras: [
  28           "Installation manuals": Path.wildcard("docs/installation/*.md"),
  29           Configuration: Path.wildcard("docs/config/*.md"),
  30           Administration: Path.wildcard("docs/admin/*.md"),
  31           "Pleroma's APIs and Mastodon API extensions": Path.wildcard("docs/api/*.md")
  32         ],
  33         main: "readme",
  34         output: "priv/static/doc"
  35       ],
  36       releases: [
  37         pleroma: [
  38           include_executables_for: [:unix],
  39           applications: [ex_syslogger: :load, syslog: :load],
  40           steps: [:assemble, &put_otp_version/1, &copy_files/1, &copy_nginx_config/1]
  41         ]
  42       ]
  43     ]
  44   end
  45
  46   def put_otp_version(%{path: target_path} = release) do
  47     File.write!(
  48       Path.join([target_path, "OTP_VERSION"]),
  49       Pleroma.OTPVersion.version()
  50     )
  51
  52     release
  53   end
  54
  55   def copy_files(%{path: target_path} = release) do
  56     File.cp_r!("./rel/files", target_path)
  57     release
  58   end
  59
  60   def copy_nginx_config(%{path: target_path} = release) do
  61     File.cp!(
  62       "./installation/pleroma.nginx",
  63       Path.join([target_path, "installation", "pleroma.nginx"])
  64     )
  65
  66     release
  67   end
  68
  69   # Configuration for the OTP application.
  70   #
  71   # Type `mix help compile.app` for more information.
  72   def application do
  73     [
  74       mod: {Pleroma.Application, []},
  75       extra_applications: [
  76         :logger,
  77         :runtime_tools,
  78         :comeonin,
  79         :quack,
  80         :fast_sanitize,
  81         :ssl,
  82         :eldap
  83       ],
  84       included_applications: [:ex_syslogger]
  85     ]
  86   end
  87
  88   # Specifies which paths to compile per environment.
  89   defp elixirc_paths(:benchmark), do: ["lib", "benchmarks"]
  90   defp elixirc_paths(:test), do: ["lib", "test/support"]
  91   defp elixirc_paths(_), do: ["lib"]
  92
  93   defp warnings_as_errors(:prod), do: false
  94   # Uncomment this if you need testing configurable_from_database logic
  95   # defp warnings_as_errors(:dev), do: false
  96   defp warnings_as_errors(_), do: true
  97
  98   # Specifies OAuth dependencies.
  99   defp oauth_deps do
 100     oauth_strategy_packages =
 101       System.get_env("OAUTH_CONSUMER_STRATEGIES")
 102       |> to_string()
 103       |> String.split()
 104       |> Enum.map(fn strategy_entry ->
 105         with [_strategy, dependency] <- String.split(strategy_entry, ":") do
 106           dependency
 107         else
 108           [strategy] -> "ueberauth_#{strategy}"
 109         end
 110       end)
 111
 112     for s <- oauth_strategy_packages, do: {String.to_atom(s), ">= 0.0.0"}
 113   end
 114
 115   # Specifies your project dependencies.
 116   #
 117   # Type `mix help deps` for examples and options.
 118   defp deps do
 119     [
 120       {:phoenix, "~> 1.4.8"},
 121       {:tzdata, "~> 0.5.21"},
 122       {:plug_cowboy, "~> 2.0"},
 123       {:phoenix_pubsub, "~> 1.1"},
 124       {:phoenix_ecto, "~> 4.0"},
 125       {:ecto_enum, "~> 1.4"},
 126       {:ecto_sql, "~> 3.3.2"},
 127       {:postgrex, ">= 0.13.5"},
 128       {:oban, "~> 1.2"},
 129       {:gettext, "~> 0.15"},
 130       {:comeonin, "~> 4.1.1"},
 131       {:pbkdf2_elixir, "~> 0.12.3"},
 132       {:trailing_format_plug, "~> 0.0.7"},
 133       {:fast_sanitize, "~> 0.1"},
 134       {:html_entities, "~> 0.5", override: true},
 135       {:phoenix_html, "~> 2.10"},
 136       {:calendar, "~> 0.17.4"},
 137       {:cachex, "~> 3.2"},
 138       {:poison, "~> 3.0", override: true},
 139       # {:tesla, "~> 1.3", override: true},
 140       {:tesla,
 141        git: "https://git.pleroma.social/pleroma/elixir-libraries/tesla.git",
 142        ref: "61b7503cef33f00834f78ddfafe0d5d9dec2270b",
 143        override: true},
 144       {:castore, "~> 0.1"},
 145       {:cowlib, "~> 2.8", override: true},
 146       {:gun,
 147        github: "ninenines/gun", ref: "e1a69b36b180a574c0ac314ced9613fdd52312cc", override: true},
 148       {:jason, "~> 1.0"},
 149       {:mogrify, "~> 0.6.1"},
 150       {:ex_aws, "~> 2.1"},
 151       {:ex_aws_s3, "~> 2.0"},
 152       {:sweet_xml, "~> 0.6.6"},
 153       {:earmark, "~> 1.3"},
 154       {:bbcode_pleroma, "~> 0.2.0"},
 155       {:ex_machina, "~> 2.3", only: :test},
 156       {:credo, "~> 1.1.0", only: [:dev, :test], runtime: false},
 157       {:mock, "~> 0.3.3", only: :test},
 158       {:crypt,
 159        git: "https://github.com/msantos/crypt", ref: "1f2b58927ab57e72910191a7ebaeff984382a1d3"},
 160       {:cors_plug, "~> 1.5"},
 161       {:ex_doc, "~> 0.21", only: :dev, runtime: false},
 162       {:web_push_encryption, "~> 0.2.1"},
 163       {:swoosh, "~> 0.23.2"},
 164       {:phoenix_swoosh, "~> 0.2"},
 165       {:gen_smtp, "~> 0.13"},
 166       {:websocket_client, git: "https://github.com/jeremyong/websocket_client.git", only: :test},
 167       {:ex_syslogger, "~> 1.4"},
 168       {:floki, "~> 0.25"},
 169       {:timex, "~> 3.5"},
 170       {:ueberauth, "~> 0.4"},
 171       {:auto_linker,
 172        git: "https://git.pleroma.social/pleroma/auto_linker.git",
 173        ref: "95e8188490e97505c56636c1379ffdf036c1fdde"},
 174       {:http_signatures,
 175        git: "https://git.pleroma.social/pleroma/http_signatures.git",
 176        ref: "293d77bb6f4a67ac8bde1428735c3b42f22cbb30"},
 177       {:telemetry, "~> 0.3"},
 178       {:poolboy, "~> 1.5"},
 179       {:prometheus_ex, "~> 3.0"},
 180       {:prometheus_plugs, "~> 1.1"},
 181       {:prometheus_phoenix, "~> 1.3"},
 182       {:prometheus_ecto, "~> 1.4"},
 183       {:recon, "~> 2.5"},
 184       {:quack, "~> 0.1.1"},
 185       {:joken, "~> 2.0"},
 186       {:benchee, "~> 1.0"},
 187       {:pot, "~> 0.10.2"},
 188       {:esshd, "~> 0.1.0", runtime: Application.get_env(:esshd, :enabled, false)},
 189       {:ex_const, "~> 0.2"},
 190       {:plug_static_index_html, "~> 1.0.0"},
 191       {:excoveralls, "~> 0.12.1", only: :test},
 192       {:flake_id, "~> 0.1.0"},
 193       {:remote_ip,
 194        git: "https://git.pleroma.social/pleroma/remote_ip.git",
 195        ref: "b647d0deecaa3acb140854fe4bda5b7e1dc6d1c8"},
 196       {:captcha,
 197        git: "https://git.pleroma.social/pleroma/elixir-libraries/elixir-captcha.git",
 198        ref: "e0f16822d578866e186a0974d65ad58cddc1e2ab"},
 199       {:mox, "~> 0.5", only: :test},
 200       {:restarter, path: "./restarter"},
 201       {:open_api_spex,
 202        git: "https://git.pleroma.social/pleroma/elixir-libraries/open_api_spex.git",
 203        ref: "b862ebd78de0df95875cf46feb6e9607130dc2a8"}
 204     ] ++ oauth_deps()
 205   end
 206
 207   # Aliases are shortcuts or tasks specific to the current project.
 208   # For example, to create, migrate and run the seeds file at once:
 209   #
 210   #     $ mix ecto.setup
 211   #
 212   # See the documentation for `Mix` for more info on aliases.
 213   defp aliases do
 214     [
 215       "ecto.migrate": ["pleroma.ecto.migrate"],
 216       "ecto.rollback": ["pleroma.ecto.rollback"],
 217       "ecto.setup": ["ecto.create", "ecto.migrate", "run priv/repo/seeds.exs"],
 218       "ecto.reset": ["ecto.drop", "ecto.setup"],
 219       test: ["ecto.create --quiet", "ecto.migrate", "test"],
 220       docs: ["pleroma.docs", "docs"]
 221     ]
 222   end
 223
 224   # Builds a version string made of:
 225   # * the application version
 226   # * a pre-release if ahead of the tag: the describe string (-count-commithash)
 227   # * branch name
 228   # * build metadata:
 229   #   * a build name if `PLEROMA_BUILD_NAME` or `:pleroma, :build_name` is defined
 230   #   * the mix environment if different than prod
 231   defp version(version) do
 232     identifier_filter = ~r/[^0-9a-z\-]+/i
 233
 234     # Pre-release version, denoted from patch version with a hyphen
 235     {tag, tag_err} =
 236       System.cmd("git", ["describe", "--tags", "--abbrev=0"], stderr_to_stdout: true)
 237
 238     {describe, describe_err} = System.cmd("git", ["describe", "--tags", "--abbrev=8"])
 239     {commit_hash, commit_hash_err} = System.cmd("git", ["rev-parse", "--short", "HEAD"])
 240
 241     git_pre_release =
 242       cond do
 243         tag_err == 0 and describe_err == 0 ->
 244           describe
 245           |> String.trim()
 246           |> String.replace(String.trim(tag), "")
 247           |> String.trim_leading("-")
 248           |> String.trim()
 249
 250         commit_hash_err == 0 ->
 251           "0-g" <> String.trim(commit_hash)
 252
 253         true ->
 254           ""
 255       end
 256
 257     # Branch name as pre-release version component, denoted with a dot
 258     branch_name =
 259       with {branch_name, 0} <- System.cmd("git", ["rev-parse", "--abbrev-ref", "HEAD"]),
 260            branch_name <- String.trim(branch_name),
 261            branch_name <- System.get_env("PLEROMA_BUILD_BRANCH") || branch_name,
 262            true <-
 263              !Enum.any?(["master", "HEAD", "release/", "stable"], fn name ->
 264                String.starts_with?(name, branch_name)
 265              end) do
 266         branch_name =
 267           branch_name
 268           |> String.trim()
 269           |> String.replace(identifier_filter, "-")
 270
 271         branch_name
 272       else
 273         _ -> "stable"
 274       end
 275
 276     build_name =
 277       cond do
 278         name = Application.get_env(:pleroma, :build_name) -> name
 279         name = System.get_env("PLEROMA_BUILD_NAME") -> name
 280         true -> nil
 281       end
 282
 283     env_name = if Mix.env() != :prod, do: to_string(Mix.env())
 284     env_override = System.get_env("PLEROMA_BUILD_ENV")
 285
 286     env_name =
 287       case env_override do
 288         nil -> env_name
 289         env_override when env_override in ["", "prod"] -> nil
 290         env_override -> env_override
 291       end
 292
 293     # Pre-release version, denoted by appending a hyphen
 294     # and a series of dot separated identifiers
 295     pre_release =
 296       [git_pre_release, branch_name]
 297       |> Enum.filter(fn string -> string && string != "" end)
 298       |> Enum.join(".")
 299       |> (fn
 300             "" -> nil
 301             string -> "-" <> String.replace(string, identifier_filter, "-")
 302           end).()
 303
 304     # Build metadata, denoted with a plus sign
 305     build_metadata =
 306       [build_name, env_name]
 307       |> Enum.filter(fn string -> string && string != "" end)
 308       |> Enum.join(".")
 309       |> (fn
 310             "" -> nil
 311             string -> "+" <> String.replace(string, identifier_filter, "-")
 312           end).()
 313
 314     [version, pre_release, build_metadata]
 315     |> Enum.filter(fn string -> string && string != "" end)
 316     |> Enum.join()
 317   end
 318 end