git.squeep.com Git - akkoma/blob - mix.exs

   1 defmodule Pleroma.Mixfile do
   2   use Mix.Project
   3
   4   def project do
   5     [
   6       app: :pleroma,
   7       version: version("2.0.50"),
   8       elixir: "~> 1.9",
   9       elixirc_paths: elixirc_paths(Mix.env()),
  10       compilers: [:phoenix, :gettext] ++ Mix.compilers(),
  11       elixirc_options: [warnings_as_errors: warnings_as_errors(Mix.env())],
  12       xref: [exclude: [:eldap]],
  13       start_permanent: Mix.env() == :prod,
  14       aliases: aliases(),
  15       deps: deps(),
  16       test_coverage: [tool: ExCoveralls],
  17       preferred_cli_env: ["coveralls.html": :test],
  18       # Docs
  19       name: "Pleroma",
  20       homepage_url: "https://pleroma.social/",
  21       source_url: "https://git.pleroma.social/pleroma/pleroma",
  22       docs: [
  23         source_url_pattern:
  24           "https://git.pleroma.social/pleroma/pleroma/blob/develop/%{path}#L%{line}",
  25         logo: "priv/static/static/logo.png",
  26         extras: ["README.md", "CHANGELOG.md"] ++ Path.wildcard("docs/**/*.md"),
  27         groups_for_extras: [
  28           "Installation manuals": Path.wildcard("docs/installation/*.md"),
  29           Configuration: Path.wildcard("docs/config/*.md"),
  30           Administration: Path.wildcard("docs/admin/*.md"),
  31           "Pleroma's APIs and Mastodon API extensions": Path.wildcard("docs/api/*.md")
  32         ],
  33         main: "readme",
  34         output: "priv/static/doc"
  35       ],
  36       releases: [
  37         pleroma: [
  38           include_executables_for: [:unix],
  39           applications: [ex_syslogger: :load, syslog: :load, eldap: :transient],
  40           steps: [:assemble, &put_otp_version/1, &copy_files/1, &copy_nginx_config/1]
  41         ]
  42       ]
  43     ]
  44   end
  45
  46   def put_otp_version(%{path: target_path} = release) do
  47     File.write!(
  48       Path.join([target_path, "OTP_VERSION"]),
  49       Pleroma.OTPVersion.version()
  50     )
  51
  52     release
  53   end
  54
  55   def copy_files(%{path: target_path} = release) do
  56     File.cp_r!("./rel/files", target_path)
  57     release
  58   end
  59
  60   def copy_nginx_config(%{path: target_path} = release) do
  61     File.cp!(
  62       "./installation/pleroma.nginx",
  63       Path.join([target_path, "installation", "pleroma.nginx"])
  64     )
  65
  66     release
  67   end
  68
  69   # Configuration for the OTP application.
  70   #
  71   # Type `mix help compile.app` for more information.
  72   def application do
  73     [
  74       mod: {Pleroma.Application, []},
  75       extra_applications: [
  76         :logger,
  77         :runtime_tools,
  78         :comeonin,
  79         :quack,
  80         :fast_sanitize,
  81         :ssl
  82       ],
  83       included_applications: [:ex_syslogger]
  84     ]
  85   end
  86
  87   # Specifies which paths to compile per environment.
  88   defp elixirc_paths(:benchmark), do: ["lib", "benchmarks"]
  89   defp elixirc_paths(:test), do: ["lib", "test/support"]
  90   defp elixirc_paths(_), do: ["lib"]
  91
  92   defp warnings_as_errors(:prod), do: false
  93   defp warnings_as_errors(_), do: true
  94
  95   # Specifies OAuth dependencies.
  96   defp oauth_deps do
  97     oauth_strategy_packages =
  98       System.get_env("OAUTH_CONSUMER_STRATEGIES")
  99       |> to_string()
 100       |> String.split()
 101       |> Enum.map(fn strategy_entry ->
 102         with [_strategy, dependency] <- String.split(strategy_entry, ":") do
 103           dependency
 104         else
 105           [strategy] -> "ueberauth_#{strategy}"
 106         end
 107       end)
 108
 109     for s <- oauth_strategy_packages, do: {String.to_atom(s), ">= 0.0.0"}
 110   end
 111
 112   # Specifies your project dependencies.
 113   #
 114   # Type `mix help deps` for examples and options.
 115   defp deps do
 116     [
 117       {:phoenix, "~> 1.4.8"},
 118       {:tzdata, "~> 1.0.3"},
 119       {:plug_cowboy, "~> 2.0"},
 120       {:phoenix_pubsub, "~> 1.1"},
 121       {:phoenix_ecto, "~> 4.0"},
 122       {:ecto_enum, "~> 1.4"},
 123       {:ecto_sql, "~> 3.4.4"},
 124       {:postgrex, ">= 0.13.5"},
 125       {:oban, "~> 2.0.0"},
 126       {:gettext, "~> 0.15"},
 127       {:pbkdf2_elixir, "~> 1.0"},
 128       {:bcrypt_elixir, "~> 2.0"},
 129       {:trailing_format_plug, "~> 0.0.7"},
 130       {:fast_sanitize, "~> 0.1"},
 131       {:html_entities, "~> 0.5", override: true},
 132       {:phoenix_html, "~> 2.10"},
 133       {:calendar, "~> 0.17.4"},
 134       {:cachex, "~> 3.2"},
 135       {:poison, "~> 3.0", override: true},
 136       # {:tesla, "~> 1.3", override: true},
 137       {:tesla,
 138        github: "teamon/tesla", ref: "af3707078b10793f6a534938e56b963aff82fe3c", override: true},
 139       {:castore, "~> 0.1"},
 140       {:cowlib, "~> 2.8", override: true},
 141       {:gun,
 142        github: "ninenines/gun", ref: "921c47146b2d9567eac7e9a4d2ccc60fffd4f327", override: true},
 143       {:jason, "~> 1.0"},
 144       {:mogrify, "~> 0.6.1"},
 145       {:ex_aws, "~> 2.1"},
 146       {:ex_aws_s3, "~> 2.0"},
 147       {:sweet_xml, "~> 0.6.6"},
 148       {:earmark, "~> 1.3"},
 149       {:bbcode_pleroma, "~> 0.2.0"},
 150       {:ex_machina, "~> 2.3", only: :test},
 151       {:credo, "~> 1.1.0", only: [:dev, :test], runtime: false},
 152       {:mock, "~> 0.3.3", only: :test},
 153       {:crypt,
 154        git: "https://github.com/msantos/crypt.git",
 155        ref: "f63a705f92c26955977ee62a313012e309a4d77a"},
 156       {:cors_plug, "~> 1.5"},
 157       {:ex_doc, "~> 0.21", only: :dev, runtime: false},
 158       {:web_push_encryption, "~> 0.2.1"},
 159       {:swoosh,
 160        git: "https://github.com/swoosh/swoosh.git",
 161        ref: "c96e0ca8a00d8f211ec1f042a4626b09f249caa5",
 162        override: true},
 163       {:phoenix_swoosh, "~> 0.2"},
 164       {:gen_smtp, "~> 0.13"},
 165       {:websocket_client, git: "https://github.com/jeremyong/websocket_client.git", only: :test},
 166       {:ex_syslogger, "~> 1.4"},
 167       {:floki, "~> 0.25"},
 168       {:timex, "~> 3.5"},
 169       {:ueberauth, "~> 0.4"},
 170       {:auto_linker,
 171        git: "https://git.pleroma.social/pleroma/auto_linker.git",
 172        ref: "95e8188490e97505c56636c1379ffdf036c1fdde"},
 173       {:http_signatures,
 174        git: "https://git.pleroma.social/pleroma/http_signatures.git",
 175        ref: "293d77bb6f4a67ac8bde1428735c3b42f22cbb30"},
 176       {:telemetry, "~> 0.3"},
 177       {:poolboy, "~> 1.5"},
 178       {:prometheus, "~> 4.6"},
 179       {:prometheus_ex, "~> 3.0"},
 180       {:prometheus_plugs, "~> 1.1"},
 181       {:prometheus_phoenix, "~> 1.3"},
 182       {:prometheus_ecto, "~> 1.4"},
 183       {:recon, "~> 2.5"},
 184       {:quack, "~> 0.1.1"},
 185       {:joken, "~> 2.0"},
 186       {:benchee, "~> 1.0"},
 187       {:pot, "~> 0.10.2"},
 188       {:esshd, "~> 0.1.0", runtime: Application.get_env(:esshd, :enabled, false)},
 189       {:ex_const, "~> 0.2"},
 190       {:plug_static_index_html, "~> 1.0.0"},
 191       {:excoveralls, "~> 0.12.1", only: :test},
 192       {:flake_id, "~> 0.1.0"},
 193       {:concurrent_limiter,
 194        git: "https://git.pleroma.social/pleroma/elixir-libraries/concurrent_limiter.git",
 195        ref: "8eee96c6ba39b9286ec44c51c52d9f2758951365"},
 196       {:remote_ip,
 197        git: "https://git.pleroma.social/pleroma/remote_ip.git",
 198        ref: "b647d0deecaa3acb140854fe4bda5b7e1dc6d1c8"},
 199       {:captcha,
 200        git: "https://git.pleroma.social/pleroma/elixir-libraries/elixir-captcha.git",
 201        ref: "e0f16822d578866e186a0974d65ad58cddc1e2ab"},
 202       {:mox, "~> 0.5", only: :test},
 203       {:restarter, path: "./restarter"},
 204       {:open_api_spex,
 205        git: "https://git.pleroma.social/pleroma/elixir-libraries/open_api_spex.git",
 206        ref: "f296ac0924ba3cf79c7a588c4c252889df4c2edd"}
 207     ] ++ oauth_deps()
 208   end
 209
 210   # Aliases are shortcuts or tasks specific to the current project.
 211   # For example, to create, migrate and run the seeds file at once:
 212   #
 213   #     $ mix ecto.setup
 214   #
 215   # See the documentation for `Mix` for more info on aliases.
 216   defp aliases do
 217     [
 218       "ecto.migrate": ["pleroma.ecto.migrate"],
 219       "ecto.rollback": ["pleroma.ecto.rollback"],
 220       "ecto.setup": ["ecto.create", "ecto.migrate", "run priv/repo/seeds.exs"],
 221       "ecto.reset": ["ecto.drop", "ecto.setup"],
 222       test: ["ecto.create --quiet", "ecto.migrate", "test"],
 223       docs: ["pleroma.docs", "docs"]
 224     ]
 225   end
 226
 227   # Builds a version string made of:
 228   # * the application version
 229   # * a pre-release if ahead of the tag: the describe string (-count-commithash)
 230   # * branch name
 231   # * build metadata:
 232   #   * a build name if `PLEROMA_BUILD_NAME` or `:pleroma, :build_name` is defined
 233   #   * the mix environment if different than prod
 234   defp version(version) do
 235     identifier_filter = ~r/[^0-9a-z\-]+/i
 236
 237     {_cmdgit, cmdgit_err} = System.cmd("sh", ["-c", "command -v git"])
 238
 239     git_pre_release =
 240       if cmdgit_err == 0 do
 241         {tag, tag_err} =
 242           System.cmd("git", ["describe", "--tags", "--abbrev=0"], stderr_to_stdout: true)
 243
 244         {describe, describe_err} = System.cmd("git", ["describe", "--tags", "--abbrev=8"])
 245         {commit_hash, commit_hash_err} = System.cmd("git", ["rev-parse", "--short", "HEAD"])
 246
 247         # Pre-release version, denoted from patch version with a hyphen
 248         cond do
 249           tag_err == 0 and describe_err == 0 ->
 250             describe
 251             |> String.trim()
 252             |> String.replace(String.trim(tag), "")
 253             |> String.trim_leading("-")
 254             |> String.trim()
 255
 256           commit_hash_err == 0 ->
 257             "0-g" <> String.trim(commit_hash)
 258
 259           true ->
 260             nil
 261         end
 262       end
 263
 264     # Branch name as pre-release version component, denoted with a dot
 265     branch_name =
 266       with 0 <- cmdgit_err,
 267            {branch_name, 0} <- System.cmd("git", ["rev-parse", "--abbrev-ref", "HEAD"]),
 268            branch_name <- String.trim(branch_name),
 269            branch_name <- System.get_env("PLEROMA_BUILD_BRANCH") || branch_name,
 270            true <-
 271              !Enum.any?(["master", "HEAD", "release/", "stable"], fn name ->
 272                String.starts_with?(name, branch_name)
 273              end) do
 274         branch_name =
 275           branch_name
 276           |> String.trim()
 277           |> String.replace(identifier_filter, "-")
 278
 279         branch_name
 280       else
 281         _ -> ""
 282       end
 283
 284     build_name =
 285       cond do
 286         name = Application.get_env(:pleroma, :build_name) -> name
 287         name = System.get_env("PLEROMA_BUILD_NAME") -> name
 288         true -> nil
 289       end
 290
 291     env_name = if Mix.env() != :prod, do: to_string(Mix.env())
 292     env_override = System.get_env("PLEROMA_BUILD_ENV")
 293
 294     env_name =
 295       case env_override do
 296         nil -> env_name
 297         env_override when env_override in ["", "prod"] -> nil
 298         env_override -> env_override
 299       end
 300
 301     # Pre-release version, denoted by appending a hyphen
 302     # and a series of dot separated identifiers
 303     pre_release =
 304       [git_pre_release, branch_name]
 305       |> Enum.filter(fn string -> string && string != "" end)
 306       |> Enum.join(".")
 307       |> (fn
 308             "" -> nil
 309             string -> "-" <> String.replace(string, identifier_filter, "-")
 310           end).()
 311
 312     # Build metadata, denoted with a plus sign
 313     build_metadata =
 314       [build_name, env_name]
 315       |> Enum.filter(fn string -> string && string != "" end)
 316       |> Enum.join(".")
 317       |> (fn
 318             "" -> nil
 319             string -> "+" <> String.replace(string, identifier_filter, "-")
 320           end).()
 321
 322     [version, pre_release, build_metadata]
 323     |> Enum.filter(fn string -> string && string != "" end)
 324     |> Enum.join()
 325   end
 326 end