git.squeep.com Git - akkoma/blob - mix.exs

   1 defmodule Pleroma.Mixfile do
   2   use Mix.Project
   3
   4   def project do
   5     [
   6       app: :pleroma,
   7       version: version("1.1.50"),
   8       elixir: "~> 1.8",
   9       elixirc_paths: elixirc_paths(Mix.env()),
  10       compilers: [:phoenix, :gettext] ++ Mix.compilers(),
  11       elixirc_options: [warnings_as_errors: true],
  12       xref: [exclude: [:eldap]],
  13       start_permanent: Mix.env() == :prod,
  14       aliases: aliases(),
  15       deps: deps(),
  16       test_coverage: [tool: ExCoveralls],
  17       preferred_cli_env: ["coveralls.html": :test],
  18       # Docs
  19       name: "Pleroma",
  20       homepage_url: "https://pleroma.social/",
  21       source_url: "https://git.pleroma.social/pleroma/pleroma",
  22       docs: [
  23         source_url_pattern:
  24           "https://git.pleroma.social/pleroma/pleroma/blob/develop/%{path}#L%{line}",
  25         logo: "priv/static/static/logo.png",
  26         extras: ["README.md", "CHANGELOG.md"] ++ Path.wildcard("docs/**/*.md"),
  27         groups_for_extras: [
  28           "Installation manuals": Path.wildcard("docs/installation/*.md"),
  29           Configuration: Path.wildcard("docs/config/*.md"),
  30           Administration: Path.wildcard("docs/admin/*.md"),
  31           "Pleroma's APIs and Mastodon API extensions": Path.wildcard("docs/api/*.md")
  32         ],
  33         main: "readme",
  34         output: "priv/static/doc"
  35       ],
  36       releases: [
  37         pleroma: [
  38           include_executables_for: [:unix],
  39           applications: [ex_syslogger: :load, syslog: :load],
  40           steps: [:assemble, &copy_files/1, &copy_nginx_config/1]
  41         ]
  42       ]
  43     ]
  44   end
  45
  46   def copy_files(%{path: target_path} = release) do
  47     File.cp_r!("./rel/files", target_path)
  48     release
  49   end
  50
  51   def copy_nginx_config(%{path: target_path} = release) do
  52     File.cp!(
  53       "./installation/pleroma.nginx",
  54       Path.join([target_path, "installation", "pleroma.nginx"])
  55     )
  56
  57     release
  58   end
  59
  60   # Configuration for the OTP application.
  61   #
  62   # Type `mix help compile.app` for more information.
  63   def application do
  64     [
  65       mod: {Pleroma.Application, []},
  66       extra_applications: [:logger, :runtime_tools, :comeonin, :quack, :fast_sanitize, :swarm],
  67       included_applications: [:ex_syslogger]
  68     ]
  69   end
  70
  71   # Specifies which paths to compile per environment.
  72   defp elixirc_paths(:benchmark), do: ["lib", "benchmarks"]
  73   defp elixirc_paths(:test), do: ["lib", "test/support"]
  74   defp elixirc_paths(_), do: ["lib"]
  75
  76   # Specifies OAuth dependencies.
  77   defp oauth_deps do
  78     oauth_strategy_packages =
  79       System.get_env("OAUTH_CONSUMER_STRATEGIES")
  80       |> to_string()
  81       |> String.split()
  82       |> Enum.map(fn strategy_entry ->
  83         with [_strategy, dependency] <- String.split(strategy_entry, ":") do
  84           dependency
  85         else
  86           [strategy] -> "ueberauth_#{strategy}"
  87         end
  88       end)
  89
  90     for s <- oauth_strategy_packages, do: {String.to_atom(s), ">= 0.0.0"}
  91   end
  92
  93   # Specifies your project dependencies.
  94   #
  95   # Type `mix help deps` for examples and options.
  96   defp deps do
  97     [
  98       {:phoenix, "~> 1.4.8"},
  99       {:tzdata, "~> 0.5.21"},
 100       {:plug_cowboy, "~> 2.0"},
 101       {:phoenix_pubsub, "~> 1.1"},
 102       {:phoenix_ecto, "~> 4.0"},
 103       {:ecto_sql, "~> 3.2"},
 104       {:postgrex, ">= 0.13.5"},
 105       {:oban, "~> 0.8.1"},
 106       {:quantum, "~> 2.3"},
 107       {:gettext, "~> 0.15"},
 108       {:comeonin, "~> 4.1.1"},
 109       {:pbkdf2_elixir, "~> 0.12.3"},
 110       {:trailing_format_plug, "~> 0.0.7"},
 111       {:fast_sanitize, "~> 0.1"},
 112       {:html_entities, "~> 0.5", override: true},
 113       {:phoenix_html, "~> 2.10"},
 114       {:calendar, "~> 0.17.4"},
 115       {:cachex, "~> 3.0.2"},
 116       {:poison, "~> 3.0", override: true},
 117       {:tesla, "~> 1.3", override: true},
 118       {:jason, "~> 1.0"},
 119       {:mogrify, "~> 0.6.1"},
 120       {:ex_aws, "~> 2.1"},
 121       {:ex_aws_s3, "~> 2.0"},
 122       {:sweet_xml, "~> 0.6.6"},
 123       {:earmark, "~> 1.3"},
 124       {:bbcode, "~> 0.1.1"},
 125       {:ex_machina, "~> 2.3", only: :test},
 126       {:credo, "~> 0.9.3", only: [:dev, :test]},
 127       {:mock, "~> 0.3.3", only: :test},
 128       {:crypt,
 129        git: "https://github.com/msantos/crypt", ref: "1f2b58927ab57e72910191a7ebaeff984382a1d3"},
 130       {:cors_plug, "~> 1.5"},
 131       {:ex_doc, "~> 0.21", only: :dev, runtime: false},
 132       {:web_push_encryption, "~> 0.2.1"},
 133       {:swoosh, "~> 0.23.2"},
 134       {:phoenix_swoosh, "~> 0.2"},
 135       {:gen_smtp, "~> 0.13"},
 136       {:websocket_client, git: "https://github.com/jeremyong/websocket_client.git", only: :test},
 137       {:floki, "~> 0.23.0"},
 138       {:ex_syslogger, github: "slashmili/ex_syslogger", tag: "1.4.0"},
 139       {:timex, "~> 3.5"},
 140       {:ueberauth, "~> 0.4"},
 141       {:auto_linker,
 142        git: "https://git.pleroma.social/pleroma/auto_linker.git",
 143        ref: "95e8188490e97505c56636c1379ffdf036c1fdde"},
 144       {:http_signatures,
 145        git: "https://git.pleroma.social/pleroma/http_signatures.git",
 146        ref: "293d77bb6f4a67ac8bde1428735c3b42f22cbb30"},
 147       {:telemetry, "~> 0.3"},
 148       {:poolboy, "~> 1.5"},
 149       {:prometheus_ex, "~> 3.0"},
 150       {:prometheus_plugs, "~> 1.1"},
 151       {:prometheus_phoenix, "~> 1.3"},
 152       {:prometheus_ecto, "~> 1.4"},
 153       {:recon, github: "ferd/recon", tag: "2.4.0"},
 154       {:quack, "~> 0.1.1"},
 155       {:joken, "~> 2.0"},
 156       {:benchee, "~> 1.0"},
 157       {:esshd, "~> 0.1.0", runtime: Application.get_env(:esshd, :enabled, false)},
 158       {:ex_const, "~> 0.2"},
 159       {:plug_static_index_html, "~> 1.0.0"},
 160       {:excoveralls, "~> 0.11.1", only: :test},
 161       {:flake_id, "~> 0.1.0"},
 162       {:remote_ip,
 163        git: "https://git.pleroma.social/pleroma/remote_ip.git",
 164        ref: "825dc00aaba5a1b7c4202a532b696b595dd3bcb3"},
 165       {:mox, "~> 0.5", only: :test}
 166     ] ++ oauth_deps()
 167   end
 168
 169   # Aliases are shortcuts or tasks specific to the current project.
 170   # For example, to create, migrate and run the seeds file at once:
 171   #
 172   #     $ mix ecto.setup
 173   #
 174   # See the documentation for `Mix` for more info on aliases.
 175   defp aliases do
 176     [
 177       "ecto.migrate": ["pleroma.ecto.migrate"],
 178       "ecto.rollback": ["pleroma.ecto.rollback"],
 179       "ecto.setup": ["ecto.create", "ecto.migrate", "run priv/repo/seeds.exs"],
 180       "ecto.reset": ["ecto.drop", "ecto.setup"],
 181       test: ["ecto.create --quiet", "ecto.migrate", "test"],
 182       docs: ["pleroma.docs", "docs"]
 183     ]
 184   end
 185
 186   # Builds a version string made of:
 187   # * the application version
 188   # * a pre-release if ahead of the tag: the describe string (-count-commithash)
 189   # * branch name
 190   # * build metadata:
 191   #   * a build name if `PLEROMA_BUILD_NAME` or `:pleroma, :build_name` is defined
 192   #   * the mix environment if different than prod
 193   defp version(version) do
 194     identifier_filter = ~r/[^0-9a-z\-]+/i
 195
 196     # Pre-release version, denoted from patch version with a hyphen
 197     {git_tag, git_pre_release} =
 198       with {tag, 0} <-
 199              System.cmd("git", ["describe", "--tags", "--abbrev=0"], stderr_to_stdout: true),
 200            tag = String.trim(tag),
 201            {describe, 0} <- System.cmd("git", ["describe", "--tags", "--abbrev=8"]),
 202            describe = String.trim(describe),
 203            ahead <- String.replace(describe, tag, ""),
 204            ahead <- String.trim_leading(ahead, "-") do
 205         {String.replace_prefix(tag, "v", ""), if(ahead != "", do: String.trim(ahead))}
 206       else
 207         _ ->
 208           {commit_hash, 0} = System.cmd("git", ["rev-parse", "--short", "HEAD"])
 209           {nil, "0-g" <> String.trim(commit_hash)}
 210       end
 211
 212     if git_tag && version != git_tag do
 213       Mix.shell().error(
 214         "Application version #{inspect(version)} does not match git tag #{inspect(git_tag)}"
 215       )
 216     end
 217
 218     # Branch name as pre-release version component, denoted with a dot
 219     branch_name =
 220       with {branch_name, 0} <- System.cmd("git", ["rev-parse", "--abbrev-ref", "HEAD"]),
 221            branch_name <- String.trim(branch_name),
 222            branch_name <- System.get_env("PLEROMA_BUILD_BRANCH") || branch_name,
 223            true <-
 224              !Enum.any?(["master", "HEAD", "release/", "stable"], fn name ->
 225                String.starts_with?(name, branch_name)
 226              end) do
 227         branch_name =
 228           branch_name
 229           |> String.trim()
 230           |> String.replace(identifier_filter, "-")
 231
 232         branch_name
 233       end
 234
 235     build_name =
 236       cond do
 237         name = Application.get_env(:pleroma, :build_name) -> name
 238         name = System.get_env("PLEROMA_BUILD_NAME") -> name
 239         true -> nil
 240       end
 241
 242     env_name = if Mix.env() != :prod, do: to_string(Mix.env())
 243     env_override = System.get_env("PLEROMA_BUILD_ENV")
 244
 245     env_name =
 246       case env_override do
 247         nil -> env_name
 248         env_override when env_override in ["", "prod"] -> nil
 249         env_override -> env_override
 250       end
 251
 252     # Pre-release version, denoted by appending a hyphen
 253     # and a series of dot separated identifiers
 254     pre_release =
 255       [git_pre_release, branch_name]
 256       |> Enum.filter(fn string -> string && string != "" end)
 257       |> Enum.join(".")
 258       |> (fn
 259             "" -> nil
 260             string -> "-" <> String.replace(string, identifier_filter, "-")
 261           end).()
 262
 263     # Build metadata, denoted with a plus sign
 264     build_metadata =
 265       [build_name, env_name]
 266       |> Enum.filter(fn string -> string && string != "" end)
 267       |> Enum.join(".")
 268       |> (fn
 269             "" -> nil
 270             string -> "+" <> String.replace(string, identifier_filter, "-")
 271           end).()
 272
 273     [version, pre_release, build_metadata]
 274     |> Enum.filter(fn string -> string && string != "" end)
 275     |> Enum.join()
 276   end
 277 end