git.squeep.com Git - akkoma/blob - mix.exs

   1 defmodule Pleroma.Mixfile do
   2   use Mix.Project
   3
   4   def project do
   5     [
   6       app: :pleroma,
   7       version: version("1.1.50"),
   8       elixir: "~> 1.8",
   9       elixirc_paths: elixirc_paths(Mix.env()),
  10       compilers: [:phoenix, :gettext] ++ Mix.compilers(),
  11       elixirc_options: [warnings_as_errors: true],
  12       xref: [exclude: [:eldap]],
  13       start_permanent: Mix.env() == :prod,
  14       aliases: aliases(),
  15       deps: deps(),
  16       test_coverage: [tool: ExCoveralls],
  17       preferred_cli_env: ["coveralls.html": :test],
  18       # Docs
  19       name: "Pleroma",
  20       homepage_url: "https://pleroma.social/",
  21       source_url: "https://git.pleroma.social/pleroma/pleroma",
  22       docs: [
  23         source_url_pattern:
  24           "https://git.pleroma.social/pleroma/pleroma/blob/develop/%{path}#L%{line}",
  25         logo: "priv/static/static/logo.png",
  26         extras: ["README.md", "CHANGELOG.md"] ++ Path.wildcard("docs/**/*.md"),
  27         groups_for_extras: [
  28           "Installation manuals": Path.wildcard("docs/installation/*.md"),
  29           Configuration: Path.wildcard("docs/config/*.md"),
  30           Administration: Path.wildcard("docs/admin/*.md"),
  31           "Pleroma's APIs and Mastodon API extensions": Path.wildcard("docs/api/*.md")
  32         ],
  33         main: "readme",
  34         output: "priv/static/doc"
  35       ],
  36       releases: [
  37         pleroma: [
  38           include_executables_for: [:unix],
  39           applications: [ex_syslogger: :load, syslog: :load],
  40           steps: [:assemble, &copy_files/1, &copy_nginx_config/1]
  41         ]
  42       ]
  43     ]
  44   end
  45
  46   def copy_files(%{path: target_path} = release) do
  47     File.cp_r!("./rel/files", target_path)
  48     release
  49   end
  50
  51   def copy_nginx_config(%{path: target_path} = release) do
  52     File.cp!(
  53       "./installation/pleroma.nginx",
  54       Path.join([target_path, "installation", "pleroma.nginx"])
  55     )
  56
  57     release
  58   end
  59
  60   # Configuration for the OTP application.
  61   #
  62   # Type `mix help compile.app` for more information.
  63   def application do
  64     [
  65       mod: {Pleroma.Application, []},
  66       extra_applications: [:logger, :runtime_tools, :comeonin, :quack, :fast_sanitize, :swarm],
  67       included_applications: [:ex_syslogger]
  68     ]
  69   end
  70
  71   # Specifies which paths to compile per environment.
  72   defp elixirc_paths(:benchmark), do: ["lib", "benchmarks"]
  73   defp elixirc_paths(:test), do: ["lib", "test/support"]
  74   defp elixirc_paths(_), do: ["lib"]
  75
  76   # Specifies OAuth dependencies.
  77   defp oauth_deps do
  78     oauth_strategy_packages =
  79       System.get_env("OAUTH_CONSUMER_STRATEGIES")
  80       |> to_string()
  81       |> String.split()
  82       |> Enum.map(fn strategy_entry ->
  83         with [_strategy, dependency] <- String.split(strategy_entry, ":") do
  84           dependency
  85         else
  86           [strategy] -> "ueberauth_#{strategy}"
  87         end
  88       end)
  89
  90     for s <- oauth_strategy_packages, do: {String.to_atom(s), ">= 0.0.0"}
  91   end
  92
  93   # Specifies your project dependencies.
  94   #
  95   # Type `mix help deps` for examples and options.
  96   defp deps do
  97     [
  98       {:phoenix, "~> 1.4.8"},
  99       {:tzdata, "~> 0.5.21"},
 100       {:plug_cowboy, "~> 2.0"},
 101       {:phoenix_pubsub, "~> 1.1"},
 102       {:phoenix_ecto, "~> 4.0"},
 103       {:ecto_enum, "~> 1.4"},
 104       {:ecto_sql, "~> 3.2"},
 105       {:postgrex, ">= 0.13.5"},
 106       {:oban, "~> 0.12.0"},
 107       {:quantum, "~> 2.3"},
 108       {:gettext, "~> 0.15"},
 109       {:comeonin, "~> 4.1.1"},
 110       {:pbkdf2_elixir, "~> 0.12.3"},
 111       {:trailing_format_plug, "~> 0.0.7"},
 112       {:fast_sanitize, "~> 0.1"},
 113       {:html_entities, "~> 0.5", override: true},
 114       {:phoenix_html, "~> 2.10"},
 115       {:calendar, "~> 0.17.4"},
 116       {:cachex, "~> 3.0.2"},
 117       {:poison, "~> 3.0", override: true},
 118       {:tesla, "~> 1.3", override: true},
 119       {:jason, "~> 1.0"},
 120       {:mogrify, "~> 0.6.1"},
 121       {:ex_aws, "~> 2.1"},
 122       {:ex_aws_s3, "~> 2.0"},
 123       {:sweet_xml, "~> 0.6.6"},
 124       {:earmark, "~> 1.3"},
 125       {:bbcode, "~> 0.1.1"},
 126       {:ex_machina, "~> 2.3", only: :test},
 127       {:credo, "~> 0.9.3", only: [:dev, :test]},
 128       {:mock, "~> 0.3.3", only: :test},
 129       {:crypt,
 130        git: "https://github.com/msantos/crypt", ref: "1f2b58927ab57e72910191a7ebaeff984382a1d3"},
 131       {:cors_plug, "~> 1.5"},
 132       {:ex_doc, "~> 0.21", only: :dev, runtime: false},
 133       {:web_push_encryption, "~> 0.2.1"},
 134       {:swoosh, "~> 0.23.2"},
 135       {:phoenix_swoosh, "~> 0.2"},
 136       {:gen_smtp, "~> 0.13"},
 137       {:websocket_client, git: "https://github.com/jeremyong/websocket_client.git", only: :test},
 138       {:floki, "~> 0.23.0"},
 139       {:ex_syslogger, github: "slashmili/ex_syslogger", tag: "1.4.0"},
 140       {:timex, "~> 3.5"},
 141       {:ueberauth, "~> 0.4"},
 142       {:auto_linker,
 143        git: "https://git.pleroma.social/pleroma/auto_linker.git",
 144        ref: "95e8188490e97505c56636c1379ffdf036c1fdde"},
 145       {:http_signatures,
 146        git: "https://git.pleroma.social/pleroma/http_signatures.git",
 147        ref: "293d77bb6f4a67ac8bde1428735c3b42f22cbb30"},
 148       {:telemetry, "~> 0.3"},
 149       {:poolboy, "~> 1.5"},
 150       {:prometheus_ex, "~> 3.0"},
 151       {:prometheus_plugs, "~> 1.1"},
 152       {:prometheus_phoenix, "~> 1.3"},
 153       {:prometheus_ecto, "~> 1.4"},
 154       {:recon, github: "ferd/recon", tag: "2.4.0"},
 155       {:quack, "~> 0.1.1"},
 156       {:joken, "~> 2.0"},
 157       {:benchee, "~> 1.0"},
 158       {:esshd, "~> 0.1.0", runtime: Application.get_env(:esshd, :enabled, false)},
 159       {:ex_const, "~> 0.2"},
 160       {:plug_static_index_html, "~> 1.0.0"},
 161       {:excoveralls, "~> 0.11.1", only: :test},
 162       {:flake_id, "~> 0.1.0"},
 163       {:remote_ip,
 164        git: "https://git.pleroma.social/pleroma/remote_ip.git",
 165        ref: "825dc00aaba5a1b7c4202a532b696b595dd3bcb3"},
 166       {:mox, "~> 0.5", only: :test}
 167     ] ++ oauth_deps()
 168   end
 169
 170   # Aliases are shortcuts or tasks specific to the current project.
 171   # For example, to create, migrate and run the seeds file at once:
 172   #
 173   #     $ mix ecto.setup
 174   #
 175   # See the documentation for `Mix` for more info on aliases.
 176   defp aliases do
 177     [
 178       "ecto.migrate": ["pleroma.ecto.migrate"],
 179       "ecto.rollback": ["pleroma.ecto.rollback"],
 180       "ecto.setup": ["ecto.create", "ecto.migrate", "run priv/repo/seeds.exs"],
 181       "ecto.reset": ["ecto.drop", "ecto.setup"],
 182       test: ["ecto.create --quiet", "ecto.migrate", "test"],
 183       docs: ["pleroma.docs", "docs"]
 184     ]
 185   end
 186
 187   # Builds a version string made of:
 188   # * the application version
 189   # * a pre-release if ahead of the tag: the describe string (-count-commithash)
 190   # * branch name
 191   # * build metadata:
 192   #   * a build name if `PLEROMA_BUILD_NAME` or `:pleroma, :build_name` is defined
 193   #   * the mix environment if different than prod
 194   defp version(version) do
 195     identifier_filter = ~r/[^0-9a-z\-]+/i
 196
 197     # Pre-release version, denoted from patch version with a hyphen
 198     git_pre_release =
 199       with {tag, 0} <-
 200              System.cmd("git", ["describe", "--tags", "--abbrev=0"], stderr_to_stdout: true),
 201            {describe, 0} <- System.cmd("git", ["describe", "--tags", "--abbrev=8"]) do
 202         describe
 203         |> String.trim()
 204         |> String.replace(String.trim(tag), "")
 205         |> String.trim_leading("-")
 206         |> String.trim()
 207       else
 208         _ ->
 209           {commit_hash, 0} = System.cmd("git", ["rev-parse", "--short", "HEAD"])
 210           "0-g" <> String.trim(commit_hash)
 211       end
 212
 213     # Branch name as pre-release version component, denoted with a dot
 214     branch_name =
 215       with {branch_name, 0} <- System.cmd("git", ["rev-parse", "--abbrev-ref", "HEAD"]),
 216            branch_name <- String.trim(branch_name),
 217            branch_name <- System.get_env("PLEROMA_BUILD_BRANCH") || branch_name,
 218            true <-
 219              !Enum.any?(["master", "HEAD", "release/", "stable"], fn name ->
 220                String.starts_with?(name, branch_name)
 221              end) do
 222         branch_name =
 223           branch_name
 224           |> String.trim()
 225           |> String.replace(identifier_filter, "-")
 226
 227         branch_name
 228       end
 229
 230     build_name =
 231       cond do
 232         name = Application.get_env(:pleroma, :build_name) -> name
 233         name = System.get_env("PLEROMA_BUILD_NAME") -> name
 234         true -> nil
 235       end
 236
 237     env_name = if Mix.env() != :prod, do: to_string(Mix.env())
 238     env_override = System.get_env("PLEROMA_BUILD_ENV")
 239
 240     env_name =
 241       case env_override do
 242         nil -> env_name
 243         env_override when env_override in ["", "prod"] -> nil
 244         env_override -> env_override
 245       end
 246
 247     # Pre-release version, denoted by appending a hyphen
 248     # and a series of dot separated identifiers
 249     pre_release =
 250       [git_pre_release, branch_name]
 251       |> Enum.filter(fn string -> string && string != "" end)
 252       |> Enum.join(".")
 253       |> (fn
 254             "" -> nil
 255             string -> "-" <> String.replace(string, identifier_filter, "-")
 256           end).()
 257
 258     # Build metadata, denoted with a plus sign
 259     build_metadata =
 260       [build_name, env_name]
 261       |> Enum.filter(fn string -> string && string != "" end)
 262       |> Enum.join(".")
 263       |> (fn
 264             "" -> nil
 265             string -> "+" <> String.replace(string, identifier_filter, "-")
 266           end).()
 267
 268     [version, pre_release, build_metadata]
 269     |> Enum.filter(fn string -> string && string != "" end)
 270     |> Enum.join()
 271   end
 272 end