git.squeep.com Git - akkoma/blob - mix.exs

   1 defmodule Pleroma.Mixfile do
   2   use Mix.Project
   3
   4   def project do
   5     [
   6       app: :pleroma,
   7       version: version("1.1.50"),
   8       elixir: "~> 1.8",
   9       elixirc_paths: elixirc_paths(Mix.env()),
  10       compilers: [:phoenix, :gettext] ++ Mix.compilers(),
  11       elixirc_options: [warnings_as_errors: true],
  12       xref: [exclude: [:eldap]],
  13       start_permanent: Mix.env() == :prod,
  14       aliases: aliases(),
  15       deps: deps(),
  16       test_coverage: [tool: ExCoveralls],
  17       preferred_cli_env: ["coveralls.html": :test],
  18       # Docs
  19       name: "Pleroma",
  20       homepage_url: "https://pleroma.social/",
  21       source_url: "https://git.pleroma.social/pleroma/pleroma",
  22       docs: [
  23         source_url_pattern:
  24           "https://git.pleroma.social/pleroma/pleroma/blob/develop/%{path}#L%{line}",
  25         logo: "priv/static/static/logo.png",
  26         extras: ["README.md", "CHANGELOG.md"] ++ Path.wildcard("docs/**/*.md"),
  27         groups_for_extras: [
  28           "Installation manuals": Path.wildcard("docs/installation/*.md"),
  29           Configuration: Path.wildcard("docs/config/*.md"),
  30           Administration: Path.wildcard("docs/admin/*.md"),
  31           "Pleroma's APIs and Mastodon API extensions": Path.wildcard("docs/api/*.md")
  32         ],
  33         main: "readme",
  34         output: "priv/static/doc"
  35       ],
  36       releases: [
  37         pleroma: [
  38           include_executables_for: [:unix],
  39           applications: [ex_syslogger: :load, syslog: :load],
  40           steps: [:assemble, &copy_files/1, &copy_nginx_config/1]
  41         ]
  42       ]
  43     ]
  44   end
  45
  46   def copy_files(%{path: target_path} = release) do
  47     File.cp_r!("./rel/files", target_path)
  48     release
  49   end
  50
  51   def copy_nginx_config(%{path: target_path} = release) do
  52     File.cp!(
  53       "./installation/pleroma.nginx",
  54       Path.join([target_path, "installation", "pleroma.nginx"])
  55     )
  56
  57     release
  58   end
  59
  60   # Configuration for the OTP application.
  61   #
  62   # Type `mix help compile.app` for more information.
  63   def application do
  64     [
  65       mod: {Pleroma.Application, []},
  66       extra_applications: [:logger, :runtime_tools, :comeonin, :quack, :fast_sanitize],
  67       included_applications: [:ex_syslogger]
  68     ]
  69   end
  70
  71   # Specifies which paths to compile per environment.
  72   defp elixirc_paths(:benchmark), do: ["lib", "benchmarks"]
  73   defp elixirc_paths(:test), do: ["lib", "test/support"]
  74   defp elixirc_paths(_), do: ["lib"]
  75
  76   # Specifies OAuth dependencies.
  77   defp oauth_deps do
  78     oauth_strategy_packages =
  79       System.get_env("OAUTH_CONSUMER_STRATEGIES")
  80       |> to_string()
  81       |> String.split()
  82       |> Enum.map(fn strategy_entry ->
  83         with [_strategy, dependency] <- String.split(strategy_entry, ":") do
  84           dependency
  85         else
  86           [strategy] -> "ueberauth_#{strategy}"
  87         end
  88       end)
  89
  90     for s <- oauth_strategy_packages, do: {String.to_atom(s), ">= 0.0.0"}
  91   end
  92
  93   # Specifies your project dependencies.
  94   #
  95   # Type `mix help deps` for examples and options.
  96   defp deps do
  97     [
  98       {:phoenix, "~> 1.4.8"},
  99       {:tzdata, "~> 0.5.21"},
 100       {:plug_cowboy, "~> 2.0"},
 101       {:phoenix_pubsub, "~> 1.1"},
 102       {:phoenix_ecto, "~> 4.0"},
 103       {:ecto_sql, "~> 3.2"},
 104       {:oban, "~> 0.11.1"},
 105       {:gettext, "~> 0.15"},
 106       {:comeonin, "~> 4.1.1"},
 107       {:pbkdf2_elixir, "~> 0.12.3"},
 108       {:trailing_format_plug, "~> 0.0.7"},
 109       {:fast_sanitize, "~> 0.1"},
 110       {:html_entities, "~> 0.5", override: true},
 111       {:phoenix_html, "~> 2.10"},
 112       {:calendar, "~> 0.17.4"},
 113       {:cachex, "~> 3.0.2"},
 114       {:poison, "~> 3.0", override: true},
 115       {:tesla, "~> 1.3", override: true},
 116       {:jason, "~> 1.0"},
 117       {:mogrify, "~> 0.6.1"},
 118       {:ex_aws, "~> 2.1"},
 119       {:ex_aws_s3, "~> 2.0"},
 120       {:sweet_xml, "~> 0.6.6"},
 121       {:earmark, "~> 1.3"},
 122       {:bbcode, "~> 0.1.1"},
 123       {:ex_machina, "~> 2.3", only: :test},
 124       {:credo, "~> 0.9.3", only: [:dev, :test]},
 125       {:mock, "~> 0.3.3", only: :test},
 126       {:crypt,
 127        git: "https://github.com/msantos/crypt", ref: "1f2b58927ab57e72910191a7ebaeff984382a1d3"},
 128       {:cors_plug, "~> 1.5"},
 129       {:ex_doc, "~> 0.21", only: :dev, runtime: false},
 130       {:web_push_encryption, "~> 0.2.1"},
 131       {:swoosh, "~> 0.23.2"},
 132       {:phoenix_swoosh, "~> 0.2"},
 133       {:gen_smtp, "~> 0.13"},
 134       {:websocket_client, git: "https://github.com/jeremyong/websocket_client.git", only: :test},
 135       {:floki, "~> 0.23.0"},
 136       {:ex_syslogger, github: "slashmili/ex_syslogger", tag: "1.4.0"},
 137       {:timex, "~> 3.5"},
 138       {:ueberauth, "~> 0.4"},
 139       {:auto_linker,
 140        git: "https://git.pleroma.social/pleroma/auto_linker.git",
 141        ref: "95e8188490e97505c56636c1379ffdf036c1fdde"},
 142       {:http_signatures,
 143        git: "https://git.pleroma.social/pleroma/http_signatures.git",
 144        ref: "293d77bb6f4a67ac8bde1428735c3b42f22cbb30"},
 145       {:telemetry, "~> 0.3"},
 146       {:poolboy, "~> 1.5"},
 147       {:prometheus_ex, "~> 3.0"},
 148       {:prometheus_plugs, "~> 1.1"},
 149       {:prometheus_phoenix, "~> 1.3"},
 150       {:prometheus_ecto, "~> 1.4"},
 151       {:recon, github: "ferd/recon", tag: "2.4.0"},
 152       {:quack, "~> 0.1.1"},
 153       {:joken, "~> 2.0"},
 154       {:benchee, "~> 1.0"},
 155       {:esshd, "~> 0.1.0", runtime: Application.get_env(:esshd, :enabled, false)},
 156       {:ex_const, "~> 0.2"},
 157       {:plug_static_index_html, "~> 1.0.0"},
 158       {:excoveralls, "~> 0.11.1", only: :test},
 159       {:flake_id, "~> 0.1.0"},
 160       {:remote_ip,
 161        git: "https://git.pleroma.social/pleroma/remote_ip.git",
 162        ref: "825dc00aaba5a1b7c4202a532b696b595dd3bcb3"},
 163       {:mox, "~> 0.5", only: :test}
 164     ] ++ oauth_deps()
 165   end
 166
 167   # Aliases are shortcuts or tasks specific to the current project.
 168   # For example, to create, migrate and run the seeds file at once:
 169   #
 170   #     $ mix ecto.setup
 171   #
 172   # See the documentation for `Mix` for more info on aliases.
 173   defp aliases do
 174     [
 175       "ecto.migrate": ["pleroma.ecto.migrate"],
 176       "ecto.rollback": ["pleroma.ecto.rollback"],
 177       "ecto.setup": ["ecto.create", "ecto.migrate", "run priv/repo/seeds.exs"],
 178       "ecto.reset": ["ecto.drop", "ecto.setup"],
 179       test: ["ecto.create --quiet", "ecto.migrate", "test"],
 180       docs: ["pleroma.docs", "docs"]
 181     ]
 182   end
 183
 184   # Builds a version string made of:
 185   # * the application version
 186   # * a pre-release if ahead of the tag: the describe string (-count-commithash)
 187   # * branch name
 188   # * build metadata:
 189   #   * a build name if `PLEROMA_BUILD_NAME` or `:pleroma, :build_name` is defined
 190   #   * the mix environment if different than prod
 191   defp version(version) do
 192     identifier_filter = ~r/[^0-9a-z\-]+/i
 193
 194     # Pre-release version, denoted from patch version with a hyphen
 195     git_pre_release =
 196       with {tag, 0} <-
 197              System.cmd("git", ["describe", "--tags", "--abbrev=0"], stderr_to_stdout: true),
 198            {describe, 0} <- System.cmd("git", ["describe", "--tags", "--abbrev=8"]) do
 199         describe
 200         |> String.trim()
 201         |> String.replace(String.trim(tag), "")
 202         |> String.trim_leading("-")
 203         |> String.trim()
 204       else
 205         _ ->
 206           {commit_hash, 0} = System.cmd("git", ["rev-parse", "--short", "HEAD"])
 207           "0-g" <> String.trim(commit_hash)
 208       end
 209
 210     # Branch name as pre-release version component, denoted with a dot
 211     branch_name =
 212       with {branch_name, 0} <- System.cmd("git", ["rev-parse", "--abbrev-ref", "HEAD"]),
 213            branch_name <- String.trim(branch_name),
 214            branch_name <- System.get_env("PLEROMA_BUILD_BRANCH") || branch_name,
 215            true <-
 216              !Enum.any?(["master", "HEAD", "release/", "stable"], fn name ->
 217                String.starts_with?(name, branch_name)
 218              end) do
 219         branch_name =
 220           branch_name
 221           |> String.trim()
 222           |> String.replace(identifier_filter, "-")
 223
 224         branch_name
 225       end
 226
 227     build_name =
 228       cond do
 229         name = Application.get_env(:pleroma, :build_name) -> name
 230         name = System.get_env("PLEROMA_BUILD_NAME") -> name
 231         true -> nil
 232       end
 233
 234     env_name = if Mix.env() != :prod, do: to_string(Mix.env())
 235     env_override = System.get_env("PLEROMA_BUILD_ENV")
 236
 237     env_name =
 238       case env_override do
 239         nil -> env_name
 240         env_override when env_override in ["", "prod"] -> nil
 241         env_override -> env_override
 242       end
 243
 244     # Pre-release version, denoted by appending a hyphen
 245     # and a series of dot separated identifiers
 246     pre_release =
 247       [git_pre_release, branch_name]
 248       |> Enum.filter(fn string -> string && string != "" end)
 249       |> Enum.join(".")
 250       |> (fn
 251             "" -> nil
 252             string -> "-" <> String.replace(string, identifier_filter, "-")
 253           end).()
 254
 255     # Build metadata, denoted with a plus sign
 256     build_metadata =
 257       [build_name, env_name]
 258       |> Enum.filter(fn string -> string && string != "" end)
 259       |> Enum.join(".")
 260       |> (fn
 261             "" -> nil
 262             string -> "+" <> String.replace(string, identifier_filter, "-")
 263           end).()
 264
 265     [version, pre_release, build_metadata]
 266     |> Enum.filter(fn string -> string && string != "" end)
 267     |> Enum.join()
 268   end
 269 end