git.squeep.com Git - akkoma/blob - mix.exs

   1 defmodule Pleroma.Mixfile do
   2   use Mix.Project
   3
   4   def project do
   5     [
   6       app: :pleroma,
   7       version: version("0.9.0"),
   8       elixir: "~> 1.4",
   9       elixirc_paths: elixirc_paths(Mix.env()),
  10       compilers: [:phoenix, :gettext] ++ Mix.compilers(),
  11       elixirc_options: [warnings_as_errors: true],
  12       start_permanent: Mix.env() == :prod,
  13       aliases: aliases(),
  14       deps: deps(),
  15
  16       # Docs
  17       name: "Pleroma",
  18       source_url: "https://git.pleroma.social/pleroma/pleroma",
  19       source_url_pattern:
  20         "https://git.pleroma.social/pleroma/pleroma/blob/develop/%{path}#L%{line}",
  21       homepage_url: "https://pleroma.social/",
  22       docs: [
  23         logo: "priv/static/static/logo.png",
  24         extras: ["README.md", "config/config.md"],
  25         main: "readme"
  26       ]
  27     ]
  28   end
  29
  30   # Configuration for the OTP application.
  31   #
  32   # Type `mix help compile.app` for more information.
  33   def application do
  34     [mod: {Pleroma.Application, []}, extra_applications: [:logger, :runtime_tools, :comeonin]]
  35   end
  36
  37   # Specifies which paths to compile per environment.
  38   defp elixirc_paths(:test), do: ["lib", "test/support"]
  39   defp elixirc_paths(_), do: ["lib"]
  40
  41   # Specifies your project dependencies.
  42   #
  43   # Type `mix help deps` for examples and options.
  44   defp deps do
  45     [
  46       {:phoenix, "~> 1.3.3"},
  47       {:phoenix_pubsub, "~> 1.0.2"},
  48       {:phoenix_ecto, "~> 3.3"},
  49       {:postgrex, ">= 0.13.5"},
  50       {:gettext, "~> 0.15"},
  51       {:cowboy, "~> 1.1.2", override: true},
  52       {:comeonin, "~> 4.1.1"},
  53       {:pbkdf2_elixir, "~> 0.12.3"},
  54       {:trailing_format_plug, "~> 0.0.7"},
  55       {:html_sanitize_ex, "~> 1.3.0"},
  56       {:phoenix_html, "~> 2.10"},
  57       {:calendar, "~> 0.17.4"},
  58       {:cachex, "~> 3.0.2"},
  59       {:httpoison, "~> 1.2.0"},
  60       {:tesla, "~> 1.2"},
  61       {:jason, "~> 1.0"},
  62       {:mogrify, "~> 0.6.1"},
  63       {:ex_aws, "~> 2.0"},
  64       {:ex_aws_s3, "~> 2.0"},
  65       {:earmark, "~> 1.3"},
  66       {:ex_machina, "~> 2.2", only: :test},
  67       {:credo, "~> 0.9.3", only: [:dev, :test]},
  68       {:mock, "~> 0.3.1", only: :test},
  69       {:crypt,
  70        git: "https://github.com/msantos/crypt", ref: "1f2b58927ab57e72910191a7ebaeff984382a1d3"},
  71       {:cors_plug, "~> 1.5"},
  72       {:ex_doc, "> 0.18.3 and < 0.20.0", only: :dev, runtime: false},
  73       {:web_push_encryption, "~> 0.2.1"},
  74       {:swoosh, "~> 0.20"},
  75       {:gen_smtp, "~> 0.13"}
  76     ]
  77   end
  78
  79   # Aliases are shortcuts or tasks specific to the current project.
  80   # For example, to create, migrate and run the seeds file at once:
  81   #
  82   #     $ mix ecto.setup
  83   #
  84   # See the documentation for `Mix` for more info on aliases.
  85   defp aliases do
  86     [
  87       "ecto.setup": ["ecto.create", "ecto.migrate", "run priv/repo/seeds.exs"],
  88       "ecto.reset": ["ecto.drop", "ecto.setup"],
  89       test: ["ecto.create --quiet", "ecto.migrate", "test"]
  90     ]
  91   end
  92
  93   # Builds a version string made of:
  94   # * the application version
  95   # * a pre-release if ahead of the tag: the describe string (-count-commithash)
  96   # * build info:
  97   #   * a build name if `PLEROMA_BUILD_NAME` or `:pleroma, :build_name` is defined
  98   #   * the mix environment if different than prod
  99   defp version(version) do
 100     {git_tag, git_pre_release} =
 101       with {tag, 0} <- System.cmd("git", ["describe", "--tags", "--abbrev=0"]),
 102            tag = String.trim(tag),
 103            {describe, 0} <- System.cmd("git", ["describe", "--tags", "--abbrev=8"]),
 104            describe = String.trim(describe),
 105            ahead <- String.replace(describe, tag, "") do
 106         {String.replace_prefix(tag, "v", ""), if(ahead != "", do: String.trim(ahead))}
 107       else
 108         _ -> {nil, nil}
 109       end
 110
 111     if git_tag && version != git_tag do
 112       Mix.shell().error(
 113         "Application version #{inspect(version)} does not match git tag #{inspect(git_tag)}"
 114       )
 115     end
 116
 117     build_name =
 118       cond do
 119         name = Application.get_env(:pleroma, :build_name) -> name
 120         name = System.get_env("PLEROMA_BUILD_NAME") -> name
 121         true -> nil
 122       end
 123
 124     env_name = if Mix.env() != :prod, do: to_string(Mix.env())
 125
 126     build =
 127       [build_name, env_name]
 128       |> Enum.filter(fn string -> string && string != "" end)
 129       |> Enum.join("-")
 130       |> (fn
 131             "" -> nil
 132             string -> "+" <> string
 133           end).()
 134
 135     [version, git_pre_release, build]
 136     |> Enum.filter(fn string -> string && string != "" end)
 137     |> Enum.join()
 138   end
 139 end