git.squeep.com Git - akkoma/blob - mix.exs

   1 defmodule Pleroma.Mixfile do
   2   use Mix.Project
   3
   4   def project do
   5     [
   6       app: :pleroma,
   7       version: version("2.0.50"),
   8       elixir: "~> 1.9",
   9       elixirc_paths: elixirc_paths(Mix.env()),
  10       compilers: [:phoenix, :gettext] ++ Mix.compilers(),
  11       elixirc_options: [warnings_as_errors: warnings_as_errors(Mix.env())],
  12       xref: [exclude: [:eldap]],
  13       start_permanent: Mix.env() == :prod,
  14       aliases: aliases(),
  15       deps: deps(),
  16       test_coverage: [tool: ExCoveralls],
  17       preferred_cli_env: ["coveralls.html": :test],
  18       # Docs
  19       name: "Pleroma",
  20       homepage_url: "https://pleroma.social/",
  21       source_url: "https://git.pleroma.social/pleroma/pleroma",
  22       docs: [
  23         source_url_pattern:
  24           "https://git.pleroma.social/pleroma/pleroma/blob/develop/%{path}#L%{line}",
  25         logo: "priv/static/static/logo.png",
  26         extras: ["README.md", "CHANGELOG.md"] ++ Path.wildcard("docs/**/*.md"),
  27         groups_for_extras: [
  28           "Installation manuals": Path.wildcard("docs/installation/*.md"),
  29           Configuration: Path.wildcard("docs/config/*.md"),
  30           Administration: Path.wildcard("docs/admin/*.md"),
  31           "Pleroma's APIs and Mastodon API extensions": Path.wildcard("docs/api/*.md")
  32         ],
  33         main: "readme",
  34         output: "priv/static/doc"
  35       ],
  36       releases: [
  37         pleroma: [
  38           include_executables_for: [:unix],
  39           applications: [ex_syslogger: :load, syslog: :load, eldap: :transient],
  40           steps: [:assemble, &put_otp_version/1, &copy_files/1, &copy_nginx_config/1]
  41         ]
  42       ]
  43     ]
  44   end
  45
  46   def put_otp_version(%{path: target_path} = release) do
  47     File.write!(
  48       Path.join([target_path, "OTP_VERSION"]),
  49       Pleroma.OTPVersion.version()
  50     )
  51
  52     release
  53   end
  54
  55   def copy_files(%{path: target_path} = release) do
  56     File.cp_r!("./rel/files", target_path)
  57     release
  58   end
  59
  60   def copy_nginx_config(%{path: target_path} = release) do
  61     File.cp!(
  62       "./installation/pleroma.nginx",
  63       Path.join([target_path, "installation", "pleroma.nginx"])
  64     )
  65
  66     release
  67   end
  68
  69   # Configuration for the OTP application.
  70   #
  71   # Type `mix help compile.app` for more information.
  72   def application do
  73     [
  74       mod: {Pleroma.Application, []},
  75       extra_applications: [
  76         :logger,
  77         :runtime_tools,
  78         :comeonin,
  79         :quack,
  80         :fast_sanitize,
  81         :ssl
  82       ],
  83       included_applications: [:ex_syslogger]
  84     ]
  85   end
  86
  87   # Specifies which paths to compile per environment.
  88   defp elixirc_paths(:benchmark), do: ["lib", "benchmarks"]
  89   defp elixirc_paths(:test), do: ["lib", "test/support"]
  90   defp elixirc_paths(_), do: ["lib"]
  91
  92   defp warnings_as_errors(:prod), do: false
  93   defp warnings_as_errors(_), do: true
  94
  95   # Specifies OAuth dependencies.
  96   defp oauth_deps do
  97     oauth_strategy_packages =
  98       System.get_env("OAUTH_CONSUMER_STRATEGIES")
  99       |> to_string()
 100       |> String.split()
 101       |> Enum.map(fn strategy_entry ->
 102         with [_strategy, dependency] <- String.split(strategy_entry, ":") do
 103           dependency
 104         else
 105           [strategy] -> "ueberauth_#{strategy}"
 106         end
 107       end)
 108
 109     for s <- oauth_strategy_packages, do: {String.to_atom(s), ">= 0.0.0"}
 110   end
 111
 112   # Specifies your project dependencies.
 113   #
 114   # Type `mix help deps` for examples and options.
 115   defp deps do
 116     [
 117       {:phoenix, "~> 1.4.8"},
 118       {:tzdata, "~> 1.0.3"},
 119       {:plug_cowboy, "~> 2.0"},
 120       {:phoenix_pubsub, "~> 1.1"},
 121       {:phoenix_ecto, "~> 4.0"},
 122       {:ecto_enum, "~> 1.4"},
 123       {:ecto_sql, "~> 3.4.4"},
 124       {:postgrex, ">= 0.13.5"},
 125       {:oban, "~> 2.0.0"},
 126       {:gettext, "~> 0.15"},
 127       {:pbkdf2_elixir, "~> 1.0"},
 128       {:bcrypt_elixir, "~> 2.0"},
 129       {:trailing_format_plug, "~> 0.0.7"},
 130       {:fast_sanitize, "~> 0.1"},
 131       {:html_entities, "~> 0.5", override: true},
 132       {:phoenix_html, "~> 2.10"},
 133       {:calendar, "~> 0.17.4"},
 134       {:cachex, "~> 3.2"},
 135       {:poison, "~> 3.0", override: true},
 136       # {:tesla, "~> 1.3", override: true},
 137       {:tesla,
 138        git: "https://git.pleroma.social/pleroma/elixir-libraries/tesla.git",
 139        ref: "61b7503cef33f00834f78ddfafe0d5d9dec2270b",
 140        override: true},
 141       {:castore, "~> 0.1"},
 142       {:cowlib, "~> 2.8", override: true},
 143       {:gun,
 144        github: "ninenines/gun", ref: "e1a69b36b180a574c0ac314ced9613fdd52312cc", override: true},
 145       {:jason, "~> 1.0"},
 146       {:mogrify, "~> 0.6.1"},
 147       {:ex_aws, "~> 2.1"},
 148       {:ex_aws_s3, "~> 2.0"},
 149       {:sweet_xml, "~> 0.6.6"},
 150       {:earmark, "~> 1.3"},
 151       {:bbcode_pleroma, "~> 0.2.0"},
 152       {:ex_machina, "~> 2.3", only: :test},
 153       {:credo, "~> 1.1.0", only: [:dev, :test], runtime: false},
 154       {:mock, "~> 0.3.3", only: :test},
 155       {:crypt,
 156        git: "https://github.com/msantos/crypt", ref: "f63a705f92c26955977ee62a313012e309a4d77a"},
 157       {:cors_plug, "~> 1.5"},
 158       {:ex_doc, "~> 0.21", only: :dev, runtime: false},
 159       {:web_push_encryption, "~> 0.2.1"},
 160       {:swoosh,
 161        git: "https://github.com/swoosh/swoosh",
 162        ref: "c96e0ca8a00d8f211ec1f042a4626b09f249caa5",
 163        override: true},
 164       {:phoenix_swoosh, "~> 0.2"},
 165       {:gen_smtp, "~> 0.13"},
 166       {:websocket_client, git: "https://github.com/jeremyong/websocket_client.git", only: :test},
 167       {:ex_syslogger, "~> 1.4"},
 168       {:floki, "~> 0.25"},
 169       {:timex, "~> 3.5"},
 170       {:ueberauth, "~> 0.4"},
 171       {:auto_linker,
 172        git: "https://git.pleroma.social/pleroma/auto_linker.git",
 173        ref: "95e8188490e97505c56636c1379ffdf036c1fdde"},
 174       {:http_signatures,
 175        git: "https://git.pleroma.social/pleroma/http_signatures.git",
 176        ref: "293d77bb6f4a67ac8bde1428735c3b42f22cbb30"},
 177       {:telemetry, "~> 0.3"},
 178       {:poolboy, "~> 1.5"},
 179       {:prometheus, "~> 4.6"},
 180       {:prometheus_ex, "~> 3.0"},
 181       {:prometheus_plugs, "~> 1.1"},
 182       {:prometheus_phoenix, "~> 1.3"},
 183       {:prometheus_ecto, "~> 1.4"},
 184       {:recon, "~> 2.5"},
 185       {:quack, "~> 0.1.1"},
 186       {:joken, "~> 2.0"},
 187       {:benchee, "~> 1.0"},
 188       {:pot, "~> 0.10.2"},
 189       {:esshd, "~> 0.1.0", runtime: Application.get_env(:esshd, :enabled, false)},
 190       {:ex_const, "~> 0.2"},
 191       {:plug_static_index_html, "~> 1.0.0"},
 192       {:excoveralls, "~> 0.12.1", only: :test},
 193       {:flake_id, "~> 0.1.0"},
 194       {:concurrent_limiter,
 195        git: "https://git.pleroma.social/pleroma/elixir-libraries/concurrent_limiter",
 196        ref: "8eee96c6ba39b9286ec44c51c52d9f2758951365"},
 197       {:remote_ip,
 198        git: "https://git.pleroma.social/pleroma/remote_ip.git",
 199        ref: "b647d0deecaa3acb140854fe4bda5b7e1dc6d1c8"},
 200       {:captcha,
 201        git: "https://git.pleroma.social/pleroma/elixir-libraries/elixir-captcha.git",
 202        ref: "e0f16822d578866e186a0974d65ad58cddc1e2ab"},
 203       {:mox, "~> 0.5", only: :test},
 204       {:restarter, path: "./restarter"},
 205       {:open_api_spex,
 206        git: "https://git.pleroma.social/pleroma/elixir-libraries/open_api_spex.git",
 207        ref: "f296ac0924ba3cf79c7a588c4c252889df4c2edd"}
 208     ] ++ oauth_deps()
 209   end
 210
 211   # Aliases are shortcuts or tasks specific to the current project.
 212   # For example, to create, migrate and run the seeds file at once:
 213   #
 214   #     $ mix ecto.setup
 215   #
 216   # See the documentation for `Mix` for more info on aliases.
 217   defp aliases do
 218     [
 219       "ecto.migrate": ["pleroma.ecto.migrate"],
 220       "ecto.rollback": ["pleroma.ecto.rollback"],
 221       "ecto.setup": ["ecto.create", "ecto.migrate", "run priv/repo/seeds.exs"],
 222       "ecto.reset": ["ecto.drop", "ecto.setup"],
 223       test: ["ecto.create --quiet", "ecto.migrate", "test"],
 224       docs: ["pleroma.docs", "docs"]
 225     ]
 226   end
 227
 228   # Builds a version string made of:
 229   # * the application version
 230   # * a pre-release if ahead of the tag: the describe string (-count-commithash)
 231   # * branch name
 232   # * build metadata:
 233   #   * a build name if `PLEROMA_BUILD_NAME` or `:pleroma, :build_name` is defined
 234   #   * the mix environment if different than prod
 235   defp version(version) do
 236     identifier_filter = ~r/[^0-9a-z\-]+/i
 237
 238     {_cmdgit, cmdgit_err} = System.cmd("sh", ["-c", "command -v git"])
 239
 240     git_pre_release =
 241       if cmdgit_err == 0 do
 242         {tag, tag_err} =
 243           System.cmd("git", ["describe", "--tags", "--abbrev=0"], stderr_to_stdout: true)
 244
 245         {describe, describe_err} = System.cmd("git", ["describe", "--tags", "--abbrev=8"])
 246         {commit_hash, commit_hash_err} = System.cmd("git", ["rev-parse", "--short", "HEAD"])
 247
 248         # Pre-release version, denoted from patch version with a hyphen
 249         cond do
 250           tag_err == 0 and describe_err == 0 ->
 251             describe
 252             |> String.trim()
 253             |> String.replace(String.trim(tag), "")
 254             |> String.trim_leading("-")
 255             |> String.trim()
 256
 257           commit_hash_err == 0 ->
 258             "0-g" <> String.trim(commit_hash)
 259
 260           true ->
 261             nil
 262         end
 263       end
 264
 265     # Branch name as pre-release version component, denoted with a dot
 266     branch_name =
 267       with 0 <- cmdgit_err,
 268            {branch_name, 0} <- System.cmd("git", ["rev-parse", "--abbrev-ref", "HEAD"]),
 269            branch_name <- String.trim(branch_name),
 270            branch_name <- System.get_env("PLEROMA_BUILD_BRANCH") || branch_name,
 271            true <-
 272              !Enum.any?(["master", "HEAD", "release/", "stable"], fn name ->
 273                String.starts_with?(name, branch_name)
 274              end) do
 275         branch_name =
 276           branch_name
 277           |> String.trim()
 278           |> String.replace(identifier_filter, "-")
 279
 280         branch_name
 281       else
 282         _ -> ""
 283       end
 284
 285     build_name =
 286       cond do
 287         name = Application.get_env(:pleroma, :build_name) -> name
 288         name = System.get_env("PLEROMA_BUILD_NAME") -> name
 289         true -> nil
 290       end
 291
 292     env_name = if Mix.env() != :prod, do: to_string(Mix.env())
 293     env_override = System.get_env("PLEROMA_BUILD_ENV")
 294
 295     env_name =
 296       case env_override do
 297         nil -> env_name
 298         env_override when env_override in ["", "prod"] -> nil
 299         env_override -> env_override
 300       end
 301
 302     # Pre-release version, denoted by appending a hyphen
 303     # and a series of dot separated identifiers
 304     pre_release =
 305       [git_pre_release, branch_name]
 306       |> Enum.filter(fn string -> string && string != "" end)
 307       |> Enum.join(".")
 308       |> (fn
 309             "" -> nil
 310             string -> "-" <> String.replace(string, identifier_filter, "-")
 311           end).()
 312
 313     # Build metadata, denoted with a plus sign
 314     build_metadata =
 315       [build_name, env_name]
 316       |> Enum.filter(fn string -> string && string != "" end)
 317       |> Enum.join(".")
 318       |> (fn
 319             "" -> nil
 320             string -> "+" <> String.replace(string, identifier_filter, "-")
 321           end).()
 322
 323     [version, pre_release, build_metadata]
 324     |> Enum.filter(fn string -> string && string != "" end)
 325     |> Enum.join()
 326   end
 327 end