git.squeep.com Git - akkoma/blob - mix.exs

   1 defmodule Pleroma.Mixfile do
   2   use Mix.Project
   3
   4   def project do
   5     [
   6       app: :pleroma,
   7       version: version("2.1.50"),
   8       elixir: "~> 1.9",
   9       elixirc_paths: elixirc_paths(Mix.env()),
  10       compilers: [:phoenix, :gettext] ++ Mix.compilers(),
  11       elixirc_options: [warnings_as_errors: warnings_as_errors(Mix.env())],
  12       xref: [exclude: [:eldap]],
  13       start_permanent: Mix.env() == :prod,
  14       aliases: aliases(),
  15       deps: deps(),
  16       test_coverage: [tool: ExCoveralls],
  17       preferred_cli_env: ["coveralls.html": :test],
  18       # Docs
  19       name: "Pleroma",
  20       homepage_url: "https://pleroma.social/",
  21       source_url: "https://git.pleroma.social/pleroma/pleroma",
  22       docs: [
  23         source_url_pattern:
  24           "https://git.pleroma.social/pleroma/pleroma/blob/develop/%{path}#L%{line}",
  25         logo: "priv/static/static/logo.png",
  26         extras: ["README.md", "CHANGELOG.md"] ++ Path.wildcard("docs/**/*.md"),
  27         groups_for_extras: [
  28           "Installation manuals": Path.wildcard("docs/installation/*.md"),
  29           Configuration: Path.wildcard("docs/config/*.md"),
  30           Administration: Path.wildcard("docs/admin/*.md"),
  31           "Pleroma's APIs and Mastodon API extensions": Path.wildcard("docs/api/*.md")
  32         ],
  33         main: "readme",
  34         output: "priv/static/doc"
  35       ],
  36       releases: [
  37         pleroma: [
  38           include_executables_for: [:unix],
  39           applications: [ex_syslogger: :load, syslog: :load, eldap: :transient],
  40           steps: [:assemble, &put_otp_version/1, &copy_files/1, &copy_nginx_config/1]
  41         ]
  42       ]
  43     ]
  44   end
  45
  46   def put_otp_version(%{path: target_path} = release) do
  47     File.write!(
  48       Path.join([target_path, "OTP_VERSION"]),
  49       Pleroma.OTPVersion.version()
  50     )
  51
  52     release
  53   end
  54
  55   def copy_files(%{path: target_path} = release) do
  56     File.cp_r!("./rel/files", target_path)
  57     release
  58   end
  59
  60   def copy_nginx_config(%{path: target_path} = release) do
  61     File.cp!(
  62       "./installation/pleroma.nginx",
  63       Path.join([target_path, "installation", "pleroma.nginx"])
  64     )
  65
  66     release
  67   end
  68
  69   # Configuration for the OTP application.
  70   #
  71   # Type `mix help compile.app` for more information.
  72   def application do
  73     [
  74       mod: {Pleroma.Application, []},
  75       extra_applications: [
  76         :logger,
  77         :runtime_tools,
  78         :comeonin,
  79         :quack,
  80         :fast_sanitize,
  81         :ssl
  82       ],
  83       included_applications: [:ex_syslogger]
  84     ]
  85   end
  86
  87   # Specifies which paths to compile per environment.
  88   defp elixirc_paths(:benchmark), do: ["lib", "benchmarks"]
  89   defp elixirc_paths(:test), do: ["lib", "test/support"]
  90   defp elixirc_paths(_), do: ["lib"]
  91
  92   defp warnings_as_errors(:prod), do: false
  93   defp warnings_as_errors(_), do: true
  94
  95   # Specifies OAuth dependencies.
  96   defp oauth_deps do
  97     oauth_strategy_packages =
  98       System.get_env("OAUTH_CONSUMER_STRATEGIES")
  99       |> to_string()
 100       |> String.split()
 101       |> Enum.map(fn strategy_entry ->
 102         with [_strategy, dependency] <- String.split(strategy_entry, ":") do
 103           dependency
 104         else
 105           [strategy] -> "ueberauth_#{strategy}"
 106         end
 107       end)
 108
 109     for s <- oauth_strategy_packages, do: {String.to_atom(s), ">= 0.0.0"}
 110   end
 111
 112   # Specifies your project dependencies.
 113   #
 114   # Type `mix help deps` for examples and options.
 115   defp deps do
 116     [
 117       {:phoenix, "~> 1.4.17"},
 118       {:tzdata, "~> 1.0.3"},
 119       {:plug_cowboy, "~> 2.3"},
 120       {:phoenix_pubsub, "~> 1.1"},
 121       {:phoenix_ecto, "~> 4.0"},
 122       {:ecto_enum, "~> 1.4"},
 123       {:ecto_sql, "~> 3.4.4"},
 124       {:postgrex, ">= 0.15.5"},
 125       {:oban, "~> 2.0.0"},
 126       {:gettext, "~> 0.18"},
 127       {:pbkdf2_elixir, "~> 1.2"},
 128       {:bcrypt_elixir, "~> 2.2"},
 129       {:trailing_format_plug, "~> 0.0.7"},
 130       {:fast_sanitize, "~> 0.2.0"},
 131       {:html_entities, "~> 0.5", override: true},
 132       {:phoenix_html, "~> 2.14"},
 133       {:calendar, "~> 1.0"},
 134       {:cachex, "~> 3.2"},
 135       {:poison, "~> 3.0", override: true},
 136       {:tesla,
 137        github: "teamon/tesla", ref: "af3707078b10793f6a534938e56b963aff82fe3c", override: true},
 138       {:castore, "~> 0.1"},
 139       {:cowlib, "~> 2.9", override: true},
 140       {:gun,
 141        github: "ninenines/gun", ref: "921c47146b2d9567eac7e9a4d2ccc60fffd4f327", override: true},
 142       {:jason, "~> 1.2"},
 143       {:mogrify, "~> 0.7.4"},
 144       {:ex_aws, "~> 2.1"},
 145       {:ex_aws_s3, "~> 2.0"},
 146       {:sweet_xml, "~> 0.6.6"},
 147       {:earmark, "1.4.3"},
 148       {:bbcode_pleroma, "~> 0.2.0"},
 149       {:crypt,
 150        git: "https://github.com/msantos/crypt.git",
 151        ref: "f63a705f92c26955977ee62a313012e309a4d77a"},
 152       {:cors_plug, "~> 2.0"},
 153       {:web_push_encryption, "~> 0.3"},
 154       {:swoosh, "~> 1.0"},
 155       {:phoenix_swoosh, "~> 0.3"},
 156       {:gen_smtp, "~> 0.13"},
 157       {:ex_syslogger, "~> 1.4"},
 158       {:floki, "~> 0.27"},
 159       {:timex, "~> 3.6"},
 160       {:ueberauth, "~> 0.4"},
 161       {:linkify, "~> 0.2.0"},
 162       {:http_signatures, "~> 0.1.0"},
 163       {:telemetry, "~> 0.3"},
 164       {:poolboy, "~> 1.5"},
 165       {:prometheus, "~> 4.6"},
 166       {:prometheus_ex, "~> 3.0"},
 167       {:prometheus_plugs, "~> 1.1"},
 168       {:prometheus_phoenix, "~> 1.3"},
 169       {:prometheus_ecto, "~> 1.4"},
 170       {:recon, "~> 2.5"},
 171       {:quack, "~> 0.1.1"},
 172       {:joken, "~> 2.0"},
 173       {:benchee, "~> 1.0"},
 174       {:pot, "~> 0.11"},
 175       {:esshd, "~> 0.1.0", runtime: Application.get_env(:esshd, :enabled, false)},
 176       {:ex_const, "~> 0.2"},
 177       {:plug_static_index_html, "~> 1.0.0"},
 178       {:flake_id, "~> 0.1.0"},
 179       {:concurrent_limiter,
 180        git: "https://git.pleroma.social/pleroma/elixir-libraries/concurrent_limiter.git",
 181        ref: "55e92f84b4ed531bd487952a71040a9c69dc2807"},
 182       {:remote_ip,
 183        git: "https://git.pleroma.social/pleroma/remote_ip.git",
 184        ref: "b647d0deecaa3acb140854fe4bda5b7e1dc6d1c8"},
 185       {:captcha,
 186        git: "https://git.pleroma.social/pleroma/elixir-libraries/elixir-captcha.git",
 187        ref: "e0f16822d578866e186a0974d65ad58cddc1e2ab"},
 188       {:restarter, path: "./restarter"},
 189       {:open_api_spex,
 190        git: "https://git.pleroma.social/pleroma/elixir-libraries/open_api_spex.git",
 191        ref: "f296ac0924ba3cf79c7a588c4c252889df4c2edd"},
 192
 193       ## dev & test
 194       {:ex_doc, "~> 0.22", only: :dev, runtime: false},
 195       {:ex_machina, "~> 2.4", only: :test},
 196       {:credo, "~> 1.4", only: [:dev, :test], runtime: false},
 197       {:mock, "~> 0.3.5", only: :test},
 198       {:excoveralls, "~> 0.13.1", only: :test},
 199       {:mox, "~> 0.5", only: :test},
 200       {:websocket_client, git: "https://github.com/jeremyong/websocket_client.git", only: :test}
 201     ] ++ oauth_deps()
 202   end
 203
 204   # Aliases are shortcuts or tasks specific to the current project.
 205   # For example, to create, migrate and run the seeds file at once:
 206   #
 207   #     $ mix ecto.setup
 208   #
 209   # See the documentation for `Mix` for more info on aliases.
 210   defp aliases do
 211     [
 212       "ecto.migrate": ["pleroma.ecto.migrate"],
 213       "ecto.rollback": ["pleroma.ecto.rollback"],
 214       "ecto.setup": ["ecto.create", "ecto.migrate", "run priv/repo/seeds.exs"],
 215       "ecto.reset": ["ecto.drop", "ecto.setup"],
 216       test: ["ecto.create --quiet", "ecto.migrate", "test"],
 217       docs: ["pleroma.docs", "docs"],
 218       analyze: ["credo --strict --only=warnings,todo,fixme,consistency,readability"]
 219     ]
 220   end
 221
 222   # Builds a version string made of:
 223   # * the application version
 224   # * a pre-release if ahead of the tag: the describe string (-count-commithash)
 225   # * branch name
 226   # * build metadata:
 227   #   * a build name if `PLEROMA_BUILD_NAME` or `:pleroma, :build_name` is defined
 228   #   * the mix environment if different than prod
 229   defp version(version) do
 230     identifier_filter = ~r/[^0-9a-z\-]+/i
 231
 232     git_available? = match?({_output, 0}, System.cmd("sh", ["-c", "command -v git"]))
 233
 234     git_pre_release =
 235       if git_available? do
 236         {tag, tag_err} =
 237           System.cmd("git", ["describe", "--tags", "--abbrev=0"], stderr_to_stdout: true)
 238
 239         {describe, describe_err} = System.cmd("git", ["describe", "--tags", "--abbrev=8"])
 240         {commit_hash, commit_hash_err} = System.cmd("git", ["rev-parse", "--short", "HEAD"])
 241
 242         # Pre-release version, denoted from patch version with a hyphen
 243         cond do
 244           tag_err == 0 and describe_err == 0 ->
 245             describe
 246             |> String.trim()
 247             |> String.replace(String.trim(tag), "")
 248             |> String.trim_leading("-")
 249             |> String.trim()
 250
 251           commit_hash_err == 0 ->
 252             "0-g" <> String.trim(commit_hash)
 253
 254           true ->
 255             nil
 256         end
 257       end
 258
 259     # Branch name as pre-release version component, denoted with a dot
 260     branch_name =
 261       with true <- git_available?,
 262            {branch_name, 0} <- System.cmd("git", ["rev-parse", "--abbrev-ref", "HEAD"]),
 263            branch_name <- String.trim(branch_name),
 264            branch_name <- System.get_env("PLEROMA_BUILD_BRANCH") || branch_name,
 265            true <-
 266              !Enum.any?(["master", "HEAD", "release/", "stable"], fn name ->
 267                String.starts_with?(name, branch_name)
 268              end) do
 269         branch_name =
 270           branch_name
 271           |> String.trim()
 272           |> String.replace(identifier_filter, "-")
 273
 274         branch_name
 275       else
 276         _ -> ""
 277       end
 278
 279     build_name =
 280       cond do
 281         name = Application.get_env(:pleroma, :build_name) -> name
 282         name = System.get_env("PLEROMA_BUILD_NAME") -> name
 283         true -> nil
 284       end
 285
 286     env_name = if Mix.env() != :prod, do: to_string(Mix.env())
 287     env_override = System.get_env("PLEROMA_BUILD_ENV")
 288
 289     env_name =
 290       case env_override do
 291         nil -> env_name
 292         env_override when env_override in ["", "prod"] -> nil
 293         env_override -> env_override
 294       end
 295
 296     # Pre-release version, denoted by appending a hyphen
 297     # and a series of dot separated identifiers
 298     pre_release =
 299       [git_pre_release, branch_name]
 300       |> Enum.filter(fn string -> string && string != "" end)
 301       |> Enum.join(".")
 302       |> (fn
 303             "" -> nil
 304             string -> "-" <> String.replace(string, identifier_filter, "-")
 305           end).()
 306
 307     # Build metadata, denoted with a plus sign
 308     build_metadata =
 309       [build_name, env_name]
 310       |> Enum.filter(fn string -> string && string != "" end)
 311       |> Enum.join(".")
 312       |> (fn
 313             "" -> nil
 314             string -> "+" <> String.replace(string, identifier_filter, "-")
 315           end).()
 316
 317     [version, pre_release, build_metadata]
 318     |> Enum.filter(fn string -> string && string != "" end)
 319     |> Enum.join()
 320   end
 321 end