git.squeep.com Git - akkoma/blob - mix.exs

   1 defmodule Pleroma.Mixfile do
   2   use Mix.Project
   3
   4   def project do
   5     [
   6       app: :pleroma,
   7       version: version("1.1.50"),
   8       elixir: "~> 1.8",
   9       elixirc_paths: elixirc_paths(Mix.env()),
  10       compilers: [:phoenix, :gettext] ++ Mix.compilers(),
  11       elixirc_options: [warnings_as_errors: warnings_as_errors(Mix.env())],
  12       xref: [exclude: [:eldap]],
  13       start_permanent: Mix.env() == :prod,
  14       aliases: aliases(),
  15       deps: deps(),
  16       test_coverage: [tool: ExCoveralls],
  17       preferred_cli_env: ["coveralls.html": :test],
  18       # Docs
  19       name: "Pleroma",
  20       homepage_url: "https://pleroma.social/",
  21       source_url: "https://git.pleroma.social/pleroma/pleroma",
  22       docs: [
  23         source_url_pattern:
  24           "https://git.pleroma.social/pleroma/pleroma/blob/develop/%{path}#L%{line}",
  25         logo: "priv/static/static/logo.png",
  26         extras: ["README.md", "CHANGELOG.md"] ++ Path.wildcard("docs/**/*.md"),
  27         groups_for_extras: [
  28           "Installation manuals": Path.wildcard("docs/installation/*.md"),
  29           Configuration: Path.wildcard("docs/config/*.md"),
  30           Administration: Path.wildcard("docs/admin/*.md"),
  31           "Pleroma's APIs and Mastodon API extensions": Path.wildcard("docs/api/*.md")
  32         ],
  33         main: "readme",
  34         output: "priv/static/doc"
  35       ],
  36       releases: [
  37         pleroma: [
  38           include_executables_for: [:unix],
  39           applications: [ex_syslogger: :load, syslog: :load],
  40           steps: [:assemble, &copy_files/1, &copy_nginx_config/1]
  41         ]
  42       ]
  43     ]
  44   end
  45
  46   def copy_files(%{path: target_path} = release) do
  47     File.cp_r!("./rel/files", target_path)
  48     release
  49   end
  50
  51   def copy_nginx_config(%{path: target_path} = release) do
  52     File.cp!(
  53       "./installation/pleroma.nginx",
  54       Path.join([target_path, "installation", "pleroma.nginx"])
  55     )
  56
  57     release
  58   end
  59
  60   # Configuration for the OTP application.
  61   #
  62   # Type `mix help compile.app` for more information.
  63   def application do
  64     [
  65       mod: {Pleroma.Application, []},
  66       extra_applications: [:logger, :runtime_tools, :comeonin, :quack, :fast_sanitize, :swarm],
  67       included_applications: [:ex_syslogger]
  68     ]
  69   end
  70
  71   # Specifies which paths to compile per environment.
  72   defp elixirc_paths(:benchmark), do: ["lib", "benchmarks"]
  73   defp elixirc_paths(:test), do: ["lib", "test/support"]
  74   defp elixirc_paths(_), do: ["lib"]
  75
  76   defp warnings_as_errors(:prod), do: false
  77   # Uncomment this if you need testing configurable_from_database logic
  78   # defp warnings_as_errors(:dev), do: false
  79   defp warnings_as_errors(_), do: true
  80
  81   # Specifies OAuth dependencies.
  82   defp oauth_deps do
  83     oauth_strategy_packages =
  84       System.get_env("OAUTH_CONSUMER_STRATEGIES")
  85       |> to_string()
  86       |> String.split()
  87       |> Enum.map(fn strategy_entry ->
  88         with [_strategy, dependency] <- String.split(strategy_entry, ":") do
  89           dependency
  90         else
  91           [strategy] -> "ueberauth_#{strategy}"
  92         end
  93       end)
  94
  95     for s <- oauth_strategy_packages, do: {String.to_atom(s), ">= 0.0.0"}
  96   end
  97
  98   # Specifies your project dependencies.
  99   #
 100   # Type `mix help deps` for examples and options.
 101   defp deps do
 102     [
 103       {:phoenix, "~> 1.4.8"},
 104       {:tzdata, "~> 0.5.21"},
 105       {:plug_cowboy, "~> 2.0"},
 106       {:phoenix_pubsub, "~> 1.1"},
 107       {:phoenix_ecto, "~> 4.0"},
 108       {:ecto_enum, "~> 1.4"},
 109       {:ecto_sql, "~> 3.2"},
 110       {:postgrex, ">= 0.13.5"},
 111       {:oban, "~> 0.12.0"},
 112       {:quantum, "~> 2.3"},
 113       {:gettext, "~> 0.15"},
 114       {:comeonin, "~> 4.1.1"},
 115       {:pbkdf2_elixir, "~> 0.12.3"},
 116       {:trailing_format_plug, "~> 0.0.7"},
 117       {:fast_sanitize, "~> 0.1"},
 118       {:html_entities, "~> 0.5", override: true},
 119       {:phoenix_html, "~> 2.10"},
 120       {:calendar, "~> 0.17.4"},
 121       {:cachex, "~> 3.0.2"},
 122       {:poison, "~> 3.0", override: true},
 123       {:tesla, "~> 1.3", override: true},
 124       {:jason, "~> 1.0"},
 125       {:mogrify, "~> 0.6.1"},
 126       {:ex_aws, "~> 2.1"},
 127       {:ex_aws_s3, "~> 2.0"},
 128       {:sweet_xml, "~> 0.6.6"},
 129       {:earmark, "~> 1.3"},
 130       {:bbcode, "~> 0.1.1"},
 131       {:ex_machina, "~> 2.3", only: :test},
 132       {:credo, "~> 1.1.0", only: [:dev, :test], runtime: false},
 133       {:mock, "~> 0.3.3", only: :test},
 134       {:crypt,
 135        git: "https://github.com/msantos/crypt", ref: "1f2b58927ab57e72910191a7ebaeff984382a1d3"},
 136       {:cors_plug, "~> 1.5"},
 137       {:ex_doc, "~> 0.21", only: :dev, runtime: false},
 138       {:web_push_encryption, "~> 0.2.1"},
 139       {:swoosh, "~> 0.23.2"},
 140       {:phoenix_swoosh, "~> 0.2"},
 141       {:gen_smtp, "~> 0.13"},
 142       {:websocket_client, git: "https://github.com/jeremyong/websocket_client.git", only: :test},
 143       {:floki, "~> 0.23.0"},
 144       {:ex_syslogger, github: "slashmili/ex_syslogger", tag: "1.4.0"},
 145       {:timex, "~> 3.5"},
 146       {:ueberauth, "~> 0.4"},
 147       {:auto_linker,
 148        git: "https://git.pleroma.social/pleroma/auto_linker.git",
 149        ref: "95e8188490e97505c56636c1379ffdf036c1fdde"},
 150       {:http_signatures,
 151        git: "https://git.pleroma.social/pleroma/http_signatures.git",
 152        ref: "293d77bb6f4a67ac8bde1428735c3b42f22cbb30"},
 153       {:telemetry, "~> 0.3"},
 154       {:poolboy, "~> 1.5"},
 155       {:prometheus_ex, "~> 3.0"},
 156       {:prometheus_plugs, "~> 1.1"},
 157       {:prometheus_phoenix, "~> 1.3"},
 158       {:prometheus_ecto, "~> 1.4"},
 159       {:recon, github: "ferd/recon", tag: "2.4.0"},
 160       {:quack, "~> 0.1.1"},
 161       {:joken, "~> 2.0"},
 162       {:benchee, "~> 1.0"},
 163       {:esshd, "~> 0.1.0", runtime: Application.get_env(:esshd, :enabled, false)},
 164       {:ex_const, "~> 0.2"},
 165       {:plug_static_index_html, "~> 1.0.0"},
 166       {:excoveralls, "~> 0.11.1", only: :test},
 167       {:flake_id, "~> 0.1.0"},
 168       {:remote_ip,
 169        git: "https://git.pleroma.social/pleroma/remote_ip.git",
 170        ref: "825dc00aaba5a1b7c4202a532b696b595dd3bcb3"},
 171       {:captcha,
 172        git: "https://git.pleroma.social/pleroma/elixir-libraries/elixir-captcha.git",
 173        ref: "e0f16822d578866e186a0974d65ad58cddc1e2ab"},
 174       {:mox, "~> 0.5", only: :test},
 175       {:restarter, path: "../restarter"}
 176     ] ++ oauth_deps()
 177   end
 178
 179   # Aliases are shortcuts or tasks specific to the current project.
 180   # For example, to create, migrate and run the seeds file at once:
 181   #
 182   #     $ mix ecto.setup
 183   #
 184   # See the documentation for `Mix` for more info on aliases.
 185   defp aliases do
 186     [
 187       "ecto.migrate": ["pleroma.ecto.migrate"],
 188       "ecto.rollback": ["pleroma.ecto.rollback"],
 189       "ecto.setup": ["ecto.create", "ecto.migrate", "run priv/repo/seeds.exs"],
 190       "ecto.reset": ["ecto.drop", "ecto.setup"],
 191       test: ["ecto.create --quiet", "ecto.migrate", "test"],
 192       docs: ["pleroma.docs", "docs"]
 193     ]
 194   end
 195
 196   # Builds a version string made of:
 197   # * the application version
 198   # * a pre-release if ahead of the tag: the describe string (-count-commithash)
 199   # * branch name
 200   # * build metadata:
 201   #   * a build name if `PLEROMA_BUILD_NAME` or `:pleroma, :build_name` is defined
 202   #   * the mix environment if different than prod
 203   defp version(version) do
 204     identifier_filter = ~r/[^0-9a-z\-]+/i
 205
 206     # Pre-release version, denoted from patch version with a hyphen
 207     git_pre_release =
 208       with {tag, 0} <-
 209              System.cmd("git", ["describe", "--tags", "--abbrev=0"], stderr_to_stdout: true),
 210            {describe, 0} <- System.cmd("git", ["describe", "--tags", "--abbrev=8"]) do
 211         describe
 212         |> String.trim()
 213         |> String.replace(String.trim(tag), "")
 214         |> String.trim_leading("-")
 215         |> String.trim()
 216       else
 217         _ ->
 218           {commit_hash, 0} = System.cmd("git", ["rev-parse", "--short", "HEAD"])
 219           "0-g" <> String.trim(commit_hash)
 220       end
 221
 222     # Branch name as pre-release version component, denoted with a dot
 223     branch_name =
 224       with {branch_name, 0} <- System.cmd("git", ["rev-parse", "--abbrev-ref", "HEAD"]),
 225            branch_name <- String.trim(branch_name),
 226            branch_name <- System.get_env("PLEROMA_BUILD_BRANCH") || branch_name,
 227            true <-
 228              !Enum.any?(["master", "HEAD", "release/", "stable"], fn name ->
 229                String.starts_with?(name, branch_name)
 230              end) do
 231         branch_name =
 232           branch_name
 233           |> String.trim()
 234           |> String.replace(identifier_filter, "-")
 235
 236         branch_name
 237       end
 238
 239     build_name =
 240       cond do
 241         name = Application.get_env(:pleroma, :build_name) -> name
 242         name = System.get_env("PLEROMA_BUILD_NAME") -> name
 243         true -> nil
 244       end
 245
 246     env_name = if Mix.env() != :prod, do: to_string(Mix.env())
 247     env_override = System.get_env("PLEROMA_BUILD_ENV")
 248
 249     env_name =
 250       case env_override do
 251         nil -> env_name
 252         env_override when env_override in ["", "prod"] -> nil
 253         env_override -> env_override
 254       end
 255
 256     # Pre-release version, denoted by appending a hyphen
 257     # and a series of dot separated identifiers
 258     pre_release =
 259       [git_pre_release, branch_name]
 260       |> Enum.filter(fn string -> string && string != "" end)
 261       |> Enum.join(".")
 262       |> (fn
 263             "" -> nil
 264             string -> "-" <> String.replace(string, identifier_filter, "-")
 265           end).()
 266
 267     # Build metadata, denoted with a plus sign
 268     build_metadata =
 269       [build_name, env_name]
 270       |> Enum.filter(fn string -> string && string != "" end)
 271       |> Enum.join(".")
 272       |> (fn
 273             "" -> nil
 274             string -> "+" <> String.replace(string, identifier_filter, "-")
 275           end).()
 276
 277     [version, pre_release, build_metadata]
 278     |> Enum.filter(fn string -> string && string != "" end)
 279     |> Enum.join()
 280   end
 281 end