git.squeep.com Git - akkoma/blob - mix.exs

   1 defmodule Pleroma.Mixfile do
   2   use Mix.Project
   3
   4   def project do
   5     [
   6       app: :pleroma,
   7       version: version("1.0.0"),
   8       elixir: "~> 1.8",
   9       elixirc_paths: elixirc_paths(Mix.env()),
  10       compilers: [:phoenix, :gettext] ++ Mix.compilers(),
  11       elixirc_options: [warnings_as_errors: true],
  12       xref: [exclude: [:eldap]],
  13       start_permanent: Mix.env() == :prod,
  14       aliases: aliases(),
  15       deps: deps(),
  16       test_coverage: [tool: ExCoveralls],
  17       preferred_cli_env: ["coveralls.html": :test],
  18       # Docs
  19       name: "Pleroma",
  20       homepage_url: "https://pleroma.social/",
  21       source_url: "https://git.pleroma.social/pleroma/pleroma",
  22       docs: [
  23         source_url_pattern:
  24           "https://git.pleroma.social/pleroma/pleroma/blob/develop/%{path}#L%{line}",
  25         logo: "priv/static/static/logo.png",
  26         extras: ["README.md", "CHANGELOG.md"] ++ Path.wildcard("docs/**/*.md"),
  27         groups_for_extras: [
  28           "Installation manuals": Path.wildcard("docs/installation/*.md"),
  29           Configuration: Path.wildcard("docs/config/*.md"),
  30           Administration: Path.wildcard("docs/admin/*.md"),
  31           "Pleroma's APIs and Mastodon API extensions": Path.wildcard("docs/api/*.md")
  32         ],
  33         main: "readme",
  34         output: "priv/static/doc"
  35       ],
  36       releases: [
  37         pleroma: [
  38           include_executables_for: [:unix],
  39           applications: [ex_syslogger: :load, syslog: :load],
  40           steps: [:assemble, &copy_files/1, &copy_nginx_config/1]
  41         ]
  42       ]
  43     ]
  44   end
  45
  46   def copy_files(%{path: target_path} = release) do
  47     File.cp_r!("./rel/files", target_path)
  48     release
  49   end
  50
  51   def copy_nginx_config(%{path: target_path} = release) do
  52     File.cp!(
  53       "./installation/pleroma.nginx",
  54       Path.join([target_path, "installation", "pleroma.nginx"])
  55     )
  56
  57     release
  58   end
  59
  60   # Configuration for the OTP application.
  61   #
  62   # Type `mix help compile.app` for more information.
  63   def application do
  64     [
  65       mod: {Pleroma.Application, []},
  66       extra_applications: [:logger, :runtime_tools, :comeonin, :quack],
  67       included_applications: [:ex_syslogger]
  68     ]
  69   end
  70
  71   # Specifies which paths to compile per environment.
  72   defp elixirc_paths(:benchmark), do: ["lib", "benchmarks"]
  73   defp elixirc_paths(:test), do: ["lib", "test/support"]
  74   defp elixirc_paths(_), do: ["lib"]
  75
  76   # Specifies OAuth dependencies.
  77   defp oauth_deps do
  78     oauth_strategy_packages =
  79       System.get_env("OAUTH_CONSUMER_STRATEGIES")
  80       |> to_string()
  81       |> String.split()
  82       |> Enum.map(fn strategy_entry ->
  83         with [_strategy, dependency] <- String.split(strategy_entry, ":") do
  84           dependency
  85         else
  86           [strategy] -> "ueberauth_#{strategy}"
  87         end
  88       end)
  89
  90     for s <- oauth_strategy_packages, do: {String.to_atom(s), ">= 0.0.0"}
  91   end
  92
  93   # Specifies your project dependencies.
  94   #
  95   # Type `mix help deps` for examples and options.
  96   defp deps do
  97     [
  98       {:phoenix, "~> 1.4.8"},
  99       {:tzdata, "~> 0.5.21"},
 100       {:plug_cowboy, "~> 2.0"},
 101       {:phoenix_pubsub, "~> 1.1"},
 102       {:phoenix_ecto, "~> 4.0"},
 103       {:ecto_sql, "~> 3.2"},
 104       {:postgrex, ">= 0.13.5"},
 105       {:oban, "~> 0.8.1"},
 106       {:quantum, "~> 2.3"},
 107       {:gettext, "~> 0.15"},
 108       {:comeonin, "~> 4.1.1"},
 109       {:pbkdf2_elixir, "~> 0.12.3"},
 110       {:trailing_format_plug, "~> 0.0.7"},
 111       {:html_sanitize_ex, "~> 1.3.0"},
 112       {:html_entities, "~> 0.4"},
 113       {:phoenix_html, "~> 2.10"},
 114       {:calendar, "~> 0.17.4"},
 115       {:cachex, "~> 3.0.2"},
 116       {:poison, "~> 3.0", override: true},
 117       {:tesla, "~> 1.3", override: true},
 118       {:jason, "~> 1.0"},
 119       {:mogrify, "~> 0.6.1"},
 120       {:ex_aws, "~> 2.1"},
 121       {:ex_aws_s3, "~> 2.0"},
 122       {:sweet_xml, "~> 0.6.6"},
 123       {:earmark, "~> 1.3"},
 124       {:bbcode, "~> 0.1.1"},
 125       {:ex_machina, "~> 2.3", only: :test},
 126       {:credo, "~> 0.9.3", only: [:dev, :test]},
 127       {:mock, "~> 0.3.3", only: :test},
 128       {:crypt,
 129        git: "https://github.com/msantos/crypt", ref: "1f2b58927ab57e72910191a7ebaeff984382a1d3"},
 130       {:cors_plug, "~> 1.5"},
 131       {:ex_doc, "~> 0.21", only: :dev, runtime: false},
 132       {:web_push_encryption, "~> 0.2.1"},
 133       {:swoosh, "~> 0.23.2"},
 134       {:phoenix_swoosh, "~> 0.2"},
 135       {:gen_smtp, "~> 0.13"},
 136       {:websocket_client, git: "https://github.com/jeremyong/websocket_client.git", only: :test},
 137       {:floki, "~> 0.23.0"},
 138       {:ex_syslogger, github: "slashmili/ex_syslogger", tag: "1.4.0"},
 139       {:timex, "~> 3.5"},
 140       {:ueberauth, "~> 0.4"},
 141       {:auto_linker,
 142        git: "https://git.pleroma.social/pleroma/auto_linker.git",
 143        ref: "95e8188490e97505c56636c1379ffdf036c1fdde"},
 144       {:http_signatures,
 145        git: "https://git.pleroma.social/pleroma/http_signatures.git",
 146        ref: "293d77bb6f4a67ac8bde1428735c3b42f22cbb30"},
 147       {:telemetry, "~> 0.3"},
 148       {:poolboy, "~> 1.5"},
 149       {:prometheus_ex, "~> 3.0"},
 150       {:prometheus_plugs, "~> 1.1"},
 151       {:prometheus_phoenix, "~> 1.3"},
 152       {:prometheus_ecto, "~> 1.4"},
 153       {:recon, github: "ferd/recon", tag: "2.4.0"},
 154       {:quack, "~> 0.1.1"},
 155       {:joken, "~> 2.0"},
 156       {:benchee, "~> 1.0"},
 157       {:esshd, "~> 0.1.0", runtime: Application.get_env(:esshd, :enabled, false)},
 158       {:ex_rated, "~> 1.3"},
 159       {:ex_const, "~> 0.2"},
 160       {:plug_static_index_html, "~> 1.0.0"},
 161       {:excoveralls, "~> 0.11.1", only: :test},
 162       {:flake_id, "~> 0.1.0"},
 163       {:remote_ip,
 164        git: "https://git.pleroma.social/pleroma/remote_ip.git",
 165        ref: "825dc00aaba5a1b7c4202a532b696b595dd3bcb3"},
 166       {:mox, "~> 0.5", only: :test}
 167     ] ++ oauth_deps()
 168   end
 169
 170   # Aliases are shortcuts or tasks specific to the current project.
 171   # For example, to create, migrate and run the seeds file at once:
 172   #
 173   #     $ mix ecto.setup
 174   #
 175   # See the documentation for `Mix` for more info on aliases.
 176   defp aliases do
 177     [
 178       "ecto.migrate": ["pleroma.ecto.migrate"],
 179       "ecto.rollback": ["pleroma.ecto.rollback"],
 180       "ecto.setup": ["ecto.create", "ecto.migrate", "run priv/repo/seeds.exs"],
 181       "ecto.reset": ["ecto.drop", "ecto.setup"],
 182       test: ["ecto.create --quiet", "ecto.migrate", "test"],
 183       docs: ["pleroma.docs", "docs"]
 184     ]
 185   end
 186
 187   # Builds a version string made of:
 188   # * the application version
 189   # * a pre-release if ahead of the tag: the describe string (-count-commithash)
 190   # * branch name
 191   # * build metadata:
 192   #   * a build name if `PLEROMA_BUILD_NAME` or `:pleroma, :build_name` is defined
 193   #   * the mix environment if different than prod
 194   defp version(version) do
 195     identifier_filter = ~r/[^0-9a-z\-]+/i
 196
 197     # Pre-release version, denoted from patch version with a hyphen
 198     {git_tag, git_pre_release} =
 199       with {tag, 0} <-
 200              System.cmd("git", ["describe", "--tags", "--abbrev=0"], stderr_to_stdout: true),
 201            tag = String.trim(tag),
 202            {describe, 0} <- System.cmd("git", ["describe", "--tags", "--abbrev=8"]),
 203            describe = String.trim(describe),
 204            ahead <- String.replace(describe, tag, ""),
 205            ahead <- String.trim_leading(ahead, "-") do
 206         {String.replace_prefix(tag, "v", ""), if(ahead != "", do: String.trim(ahead))}
 207       else
 208         _ ->
 209           {commit_hash, 0} = System.cmd("git", ["rev-parse", "--short", "HEAD"])
 210           {nil, "0-g" <> String.trim(commit_hash)}
 211       end
 212
 213     if git_tag && version != git_tag do
 214       Mix.shell().error(
 215         "Application version #{inspect(version)} does not match git tag #{inspect(git_tag)}"
 216       )
 217     end
 218
 219     # Branch name as pre-release version component, denoted with a dot
 220     branch_name =
 221       with {branch_name, 0} <- System.cmd("git", ["rev-parse", "--abbrev-ref", "HEAD"]),
 222            branch_name <- String.trim(branch_name),
 223            branch_name <- System.get_env("PLEROMA_BUILD_BRANCH") || branch_name,
 224            true <-
 225              !Enum.any?(["master", "HEAD", "release/", "stable"], fn name ->
 226                String.starts_with?(name, branch_name)
 227              end) do
 228         branch_name =
 229           branch_name
 230           |> String.trim()
 231           |> String.replace(identifier_filter, "-")
 232
 233         branch_name
 234       end
 235
 236     build_name =
 237       cond do
 238         name = Application.get_env(:pleroma, :build_name) -> name
 239         name = System.get_env("PLEROMA_BUILD_NAME") -> name
 240         true -> nil
 241       end
 242
 243     env_name = if Mix.env() != :prod, do: to_string(Mix.env())
 244     env_override = System.get_env("PLEROMA_BUILD_ENV")
 245
 246     env_name =
 247       case env_override do
 248         nil -> env_name
 249         env_override when env_override in ["", "prod"] -> nil
 250         env_override -> env_override
 251       end
 252
 253     # Pre-release version, denoted by appending a hyphen
 254     # and a series of dot separated identifiers
 255     pre_release =
 256       [git_pre_release, branch_name]
 257       |> Enum.filter(fn string -> string && string != "" end)
 258       |> Enum.join(".")
 259       |> (fn
 260             "" -> nil
 261             string -> "-" <> String.replace(string, identifier_filter, "-")
 262           end).()
 263
 264     # Build metadata, denoted with a plus sign
 265     build_metadata =
 266       [build_name, env_name]
 267       |> Enum.filter(fn string -> string && string != "" end)
 268       |> Enum.join(".")
 269       |> (fn
 270             "" -> nil
 271             string -> "+" <> String.replace(string, identifier_filter, "-")
 272           end).()
 273
 274     [version, pre_release, build_metadata]
 275     |> Enum.filter(fn string -> string && string != "" end)
 276     |> Enum.join()
 277   end
 278 end