git.squeep.com Git - akkoma/blob - mix.exs

   1 defmodule Pleroma.Mixfile do
   2   use Mix.Project
   3
   4   def project do
   5     [
   6       app: :pleroma,
   7       version: version("1.1.50"),
   8       elixir: "~> 1.8",
   9       elixirc_paths: elixirc_paths(Mix.env()),
  10       compilers: [:phoenix, :gettext] ++ Mix.compilers(),
  11       elixirc_options: [warnings_as_errors: true],
  12       xref: [exclude: [:eldap]],
  13       start_permanent: Mix.env() == :prod,
  14       aliases: aliases(),
  15       deps: deps(),
  16       test_coverage: [tool: ExCoveralls],
  17       preferred_cli_env: ["coveralls.html": :test],
  18       # Docs
  19       name: "Pleroma",
  20       homepage_url: "https://pleroma.social/",
  21       source_url: "https://git.pleroma.social/pleroma/pleroma",
  22       docs: [
  23         source_url_pattern:
  24           "https://git.pleroma.social/pleroma/pleroma/blob/develop/%{path}#L%{line}",
  25         logo: "priv/static/static/logo.png",
  26         extras: ["README.md", "CHANGELOG.md"] ++ Path.wildcard("docs/**/*.md"),
  27         groups_for_extras: [
  28           "Installation manuals": Path.wildcard("docs/installation/*.md"),
  29           Configuration: Path.wildcard("docs/config/*.md"),
  30           Administration: Path.wildcard("docs/admin/*.md"),
  31           "Pleroma's APIs and Mastodon API extensions": Path.wildcard("docs/api/*.md")
  32         ],
  33         main: "readme",
  34         output: "priv/static/doc"
  35       ],
  36       releases: [
  37         pleroma: [
  38           include_executables_for: [:unix],
  39           applications: [ex_syslogger: :load, syslog: :load],
  40           steps: [:assemble, &copy_files/1, &copy_nginx_config/1]
  41         ]
  42       ]
  43     ]
  44   end
  45
  46   def copy_files(%{path: target_path} = release) do
  47     File.cp_r!("./rel/files", target_path)
  48     release
  49   end
  50
  51   def copy_nginx_config(%{path: target_path} = release) do
  52     File.cp!(
  53       "./installation/pleroma.nginx",
  54       Path.join([target_path, "installation", "pleroma.nginx"])
  55     )
  56
  57     release
  58   end
  59
  60   # Configuration for the OTP application.
  61   #
  62   # Type `mix help compile.app` for more information.
  63   def application do
  64     [
  65       mod: {Pleroma.Application, []},
  66       extra_applications: [:logger, :runtime_tools, :comeonin, :quack, :myhtmlex, :swarm],
  67       included_applications: [:ex_syslogger]
  68     ]
  69   end
  70
  71   # Specifies which paths to compile per environment.
  72   defp elixirc_paths(:benchmark), do: ["lib", "benchmarks"]
  73   defp elixirc_paths(:test), do: ["lib", "test/support"]
  74   defp elixirc_paths(_), do: ["lib"]
  75
  76   # Specifies OAuth dependencies.
  77   defp oauth_deps do
  78     oauth_strategy_packages =
  79       System.get_env("OAUTH_CONSUMER_STRATEGIES")
  80       |> to_string()
  81       |> String.split()
  82       |> Enum.map(fn strategy_entry ->
  83         with [_strategy, dependency] <- String.split(strategy_entry, ":") do
  84           dependency
  85         else
  86           [strategy] -> "ueberauth_#{strategy}"
  87         end
  88       end)
  89
  90     for s <- oauth_strategy_packages, do: {String.to_atom(s), ">= 0.0.0"}
  91   end
  92
  93   # Specifies your project dependencies.
  94   #
  95   # Type `mix help deps` for examples and options.
  96   defp deps do
  97     [
  98       {:phoenix, "~> 1.4.8"},
  99       {:tzdata, "~> 0.5.21"},
 100       {:plug_cowboy, "~> 2.0"},
 101       {:phoenix_pubsub, "~> 1.1"},
 102       {:phoenix_ecto, "~> 4.0"},
 103       {:ecto_sql, "~> 3.2"},
 104       {:postgrex, ">= 0.13.5"},
 105       {:oban, "~> 0.8.1"},
 106       {:quantum, "~> 2.3"},
 107       {:gettext, "~> 0.15"},
 108       {:comeonin, "~> 4.1.1"},
 109       {:pbkdf2_elixir, "~> 0.12.3"},
 110       {:trailing_format_plug, "~> 0.0.7"},
 111       {:html_sanitize_ex, "~> 1.3.0"},
 112       {:fast_sanitize, git: "https://git.pleroma.social/pleroma/fast_sanitize.git", ref: "2820d841393b3c2f2183d0377f572bf00f513b7c"},
 113       {:html_entities, "~> 0.4"},
 114       {:phoenix_html, "~> 2.10"},
 115       {:calendar, "~> 0.17.4"},
 116       {:cachex, "~> 3.0.2"},
 117       {:poison, "~> 3.0", override: true},
 118       {:tesla, "~> 1.3", override: true},
 119       {:jason, "~> 1.0"},
 120       {:mogrify, "~> 0.6.1"},
 121       {:ex_aws, "~> 2.1"},
 122       {:ex_aws_s3, "~> 2.0"},
 123       {:sweet_xml, "~> 0.6.6"},
 124       {:earmark, "~> 1.3"},
 125       {:bbcode, "~> 0.1.1"},
 126       {:ex_machina, "~> 2.3", only: :test},
 127       {:credo, "~> 0.9.3", only: [:dev, :test]},
 128       {:mock, "~> 0.3.3", only: :test},
 129       {:crypt,
 130        git: "https://github.com/msantos/crypt", ref: "1f2b58927ab57e72910191a7ebaeff984382a1d3"},
 131       {:cors_plug, "~> 1.5"},
 132       {:ex_doc, "~> 0.21", only: :dev, runtime: false},
 133       {:web_push_encryption, "~> 0.2.1"},
 134       {:swoosh, "~> 0.23.2"},
 135       {:phoenix_swoosh, "~> 0.2"},
 136       {:gen_smtp, "~> 0.13"},
 137       {:websocket_client, git: "https://github.com/jeremyong/websocket_client.git", only: :test},
 138       {:floki, "~> 0.23.0"},
 139       {:ex_syslogger, github: "slashmili/ex_syslogger", tag: "1.4.0"},
 140       {:timex, "~> 3.5"},
 141       {:ueberauth, "~> 0.4"},
 142       {:auto_linker,
 143        git: "https://git.pleroma.social/pleroma/auto_linker.git",
 144        ref: "95e8188490e97505c56636c1379ffdf036c1fdde"},
 145       {:http_signatures,
 146        git: "https://git.pleroma.social/pleroma/http_signatures.git",
 147        ref: "293d77bb6f4a67ac8bde1428735c3b42f22cbb30"},
 148       {:telemetry, "~> 0.3"},
 149       {:poolboy, "~> 1.5"},
 150       {:prometheus_ex, "~> 3.0"},
 151       {:prometheus_plugs, "~> 1.1"},
 152       {:prometheus_phoenix, "~> 1.3"},
 153       {:prometheus_ecto, "~> 1.4"},
 154       {:recon, github: "ferd/recon", tag: "2.4.0"},
 155       {:quack, "~> 0.1.1"},
 156       {:joken, "~> 2.0"},
 157       {:benchee, "~> 1.0"},
 158       {:esshd, "~> 0.1.0", runtime: Application.get_env(:esshd, :enabled, false)},
 159       {:ex_rated, "~> 1.3"},
 160       {:ex_const, "~> 0.2"},
 161       {:plug_static_index_html, "~> 1.0.0"},
 162       {:excoveralls, "~> 0.11.1", only: :test},
 163       {:flake_id, "~> 0.1.0"},
 164       {:remote_ip,
 165        git: "https://git.pleroma.social/pleroma/remote_ip.git",
 166        ref: "825dc00aaba5a1b7c4202a532b696b595dd3bcb3"},
 167       {:mox, "~> 0.5", only: :test}
 168     ] ++ oauth_deps()
 169   end
 170
 171   # Aliases are shortcuts or tasks specific to the current project.
 172   # For example, to create, migrate and run the seeds file at once:
 173   #
 174   #     $ mix ecto.setup
 175   #
 176   # See the documentation for `Mix` for more info on aliases.
 177   defp aliases do
 178     [
 179       "ecto.migrate": ["pleroma.ecto.migrate"],
 180       "ecto.rollback": ["pleroma.ecto.rollback"],
 181       "ecto.setup": ["ecto.create", "ecto.migrate", "run priv/repo/seeds.exs"],
 182       "ecto.reset": ["ecto.drop", "ecto.setup"],
 183       test: ["ecto.create --quiet", "ecto.migrate", "test"],
 184       docs: ["pleroma.docs", "docs"]
 185     ]
 186   end
 187
 188   # Builds a version string made of:
 189   # * the application version
 190   # * a pre-release if ahead of the tag: the describe string (-count-commithash)
 191   # * branch name
 192   # * build metadata:
 193   #   * a build name if `PLEROMA_BUILD_NAME` or `:pleroma, :build_name` is defined
 194   #   * the mix environment if different than prod
 195   defp version(version) do
 196     identifier_filter = ~r/[^0-9a-z\-]+/i
 197
 198     # Pre-release version, denoted from patch version with a hyphen
 199     {git_tag, git_pre_release} =
 200       with {tag, 0} <-
 201              System.cmd("git", ["describe", "--tags", "--abbrev=0"], stderr_to_stdout: true),
 202            tag = String.trim(tag),
 203            {describe, 0} <- System.cmd("git", ["describe", "--tags", "--abbrev=8"]),
 204            describe = String.trim(describe),
 205            ahead <- String.replace(describe, tag, ""),
 206            ahead <- String.trim_leading(ahead, "-") do
 207         {String.replace_prefix(tag, "v", ""), if(ahead != "", do: String.trim(ahead))}
 208       else
 209         _ ->
 210           {commit_hash, 0} = System.cmd("git", ["rev-parse", "--short", "HEAD"])
 211           {nil, "0-g" <> String.trim(commit_hash)}
 212       end
 213
 214     if git_tag && version != git_tag do
 215       Mix.shell().error(
 216         "Application version #{inspect(version)} does not match git tag #{inspect(git_tag)}"
 217       )
 218     end
 219
 220     # Branch name as pre-release version component, denoted with a dot
 221     branch_name =
 222       with {branch_name, 0} <- System.cmd("git", ["rev-parse", "--abbrev-ref", "HEAD"]),
 223            branch_name <- String.trim(branch_name),
 224            branch_name <- System.get_env("PLEROMA_BUILD_BRANCH") || branch_name,
 225            true <-
 226              !Enum.any?(["master", "HEAD", "release/", "stable"], fn name ->
 227                String.starts_with?(name, branch_name)
 228              end) do
 229         branch_name =
 230           branch_name
 231           |> String.trim()
 232           |> String.replace(identifier_filter, "-")
 233
 234         branch_name
 235       end
 236
 237     build_name =
 238       cond do
 239         name = Application.get_env(:pleroma, :build_name) -> name
 240         name = System.get_env("PLEROMA_BUILD_NAME") -> name
 241         true -> nil
 242       end
 243
 244     env_name = if Mix.env() != :prod, do: to_string(Mix.env())
 245     env_override = System.get_env("PLEROMA_BUILD_ENV")
 246
 247     env_name =
 248       case env_override do
 249         nil -> env_name
 250         env_override when env_override in ["", "prod"] -> nil
 251         env_override -> env_override
 252       end
 253
 254     # Pre-release version, denoted by appending a hyphen
 255     # and a series of dot separated identifiers
 256     pre_release =
 257       [git_pre_release, branch_name]
 258       |> Enum.filter(fn string -> string && string != "" end)
 259       |> Enum.join(".")
 260       |> (fn
 261             "" -> nil
 262             string -> "-" <> String.replace(string, identifier_filter, "-")
 263           end).()
 264
 265     # Build metadata, denoted with a plus sign
 266     build_metadata =
 267       [build_name, env_name]
 268       |> Enum.filter(fn string -> string && string != "" end)
 269       |> Enum.join(".")
 270       |> (fn
 271             "" -> nil
 272             string -> "+" <> String.replace(string, identifier_filter, "-")
 273           end).()
 274
 275     [version, pre_release, build_metadata]
 276     |> Enum.filter(fn string -> string && string != "" end)
 277     |> Enum.join()
 278   end
 279 end