git.squeep.com Git - akkoma/blob - mix.exs

   1 defmodule Pleroma.Mixfile do
   2   use Mix.Project
   3
   4   def project do
   5     [
   6       app: :pleroma,
   7       version: version("3.5.0"),
   8       elixir: "~> 1.12",
   9       elixirc_paths: elixirc_paths(Mix.env()),
  10       compilers: [:phoenix, :gettext] ++ Mix.compilers(),
  11       elixirc_options: [warnings_as_errors: warnings_as_errors()],
  12       xref: [exclude: [:eldap]],
  13       start_permanent: Mix.env() == :prod,
  14       aliases: aliases(),
  15       deps: deps(),
  16       test_coverage: [tool: ExCoveralls],
  17       preferred_cli_env: ["coveralls.html": :test],
  18       # Docs
  19       name: "Akkoma",
  20       homepage_url: "https://akkoma.dev/",
  21       source_url: "https://akkoma.dev/AkkomaGang/akkoma",
  22       docs: [
  23         source_url_pattern: "https://akkoma.dev/AkkomaGang/akkoma/blob/develop/%{path}#L%{line}",
  24         logo: "priv/static/images/logo.png",
  25         extras: ["README.md", "CHANGELOG.md"] ++ Path.wildcard("docs/**/*.md"),
  26         groups_for_extras: [
  27           "Installation manuals": Path.wildcard("docs/installation/*.md"),
  28           Configuration: Path.wildcard("docs/config/*.md"),
  29           Administration: Path.wildcard("docs/admin/*.md"),
  30           "Pleroma's APIs and Mastodon API extensions": Path.wildcard("docs/api/*.md")
  31         ],
  32         main: "readme",
  33         output: "priv/static/doc"
  34       ],
  35       releases: [
  36         pleroma: [
  37           include_executables_for: [:unix],
  38           applications: [ex_syslogger: :load, syslog: :load, eldap: :transient],
  39           steps: [:assemble, &put_otp_version/1, &copy_files/1, &copy_nginx_config/1],
  40           config_providers: [{Pleroma.Config.ReleaseRuntimeProvider, []}]
  41         ]
  42       ]
  43     ]
  44   end
  45
  46   def put_otp_version(%{path: target_path} = release) do
  47     File.write!(
  48       Path.join([target_path, "OTP_VERSION"]),
  49       Pleroma.OTPVersion.version()
  50     )
  51
  52     release
  53   end
  54
  55   def copy_files(%{path: target_path} = release) do
  56     File.cp_r!("./rel/files", target_path)
  57     release
  58   end
  59
  60   def copy_nginx_config(%{path: target_path} = release) do
  61     File.cp!(
  62       "./installation/nginx/akkoma.nginx",
  63       Path.join([target_path, "installation", "akkoma.nginx"])
  64     )
  65
  66     release
  67   end
  68
  69   # Configuration for the OTP application.
  70   #
  71   # Type `mix help compile.app` for more information.
  72   def application do
  73     [
  74       mod: {Pleroma.Application, []},
  75       extra_applications: [
  76         :logger,
  77         :runtime_tools,
  78         :comeonin,
  79         :quack,
  80         :fast_sanitize,
  81         :os_mon,
  82         :ssl
  83       ],
  84       included_applications: [:ex_syslogger]
  85     ]
  86   end
  87
  88   # Specifies which paths to compile per environment.
  89   defp elixirc_paths(:benchmark), do: ["lib", "benchmarks", "priv/scrubbers"]
  90   defp elixirc_paths(:test), do: ["lib", "test/support"]
  91   defp elixirc_paths(_), do: ["lib"]
  92
  93   defp warnings_as_errors, do: System.get_env("CI") == "true"
  94
  95   # Specifies OAuth dependencies.
  96   defp oauth_deps do
  97     oauth_strategy_packages =
  98       System.get_env("OAUTH_CONSUMER_STRATEGIES")
  99       |> to_string()
 100       |> String.split()
 101       |> Enum.map(fn strategy_entry ->
 102         with [_strategy, dependency] <- String.split(strategy_entry, ":") do
 103           dependency
 104         else
 105           [strategy] -> "ueberauth_#{strategy}"
 106         end
 107       end)
 108
 109     for s <- oauth_strategy_packages, do: {String.to_atom(s), ">= 0.0.0"}
 110   end
 111
 112   # Specifies your project dependencies.
 113   #
 114   # Type `mix help deps` for examples and options.
 115   defp deps do
 116     [
 117       {:phoenix, "~> 1.6.11"},
 118       {:tzdata, "~> 1.1.1"},
 119       {:plug_cowboy, "~> 2.5"},
 120       {:phoenix_pubsub, "~> 2.1"},
 121       {:phoenix_ecto, "~> 4.4"},
 122       {:ecto_enum, "~> 1.4"},
 123       {:ecto_sql, "~> 3.9.0"},
 124       {:postgrex, ">= 0.16.3"},
 125       {:oban, "~> 2.12.1"},
 126       {:gettext,
 127        git: "https://github.com/tusooa/gettext.git",
 128        ref: "72fb2496b6c5280ed911bdc3756890e7f38a4808",
 129        override: true},
 130       {:bcrypt_elixir, "~> 2.2"},
 131       {:trailing_format_plug, "~> 0.0.7"},
 132       {:fast_sanitize, "~> 0.2.3"},
 133       {:html_entities, "~> 0.5", override: true},
 134       {:phoenix_html, "~> 3.1", override: true},
 135       {:calendar, "~> 1.0"},
 136       {:cachex, "~> 3.4"},
 137       {:poison, "~> 5.0", override: true},
 138       {:tesla, "~> 1.4.4", override: true},
 139       {:castore, "~> 0.1"},
 140       {:cowlib, "~> 2.9", override: true},
 141       {:finch, "~> 0.14.0"},
 142       {:jason, "~> 1.2"},
 143       {:mogrify, "~> 0.9.1"},
 144       {:ex_aws, "~> 2.1.6"},
 145       {:ex_aws_s3, "~> 2.0"},
 146       {:sweet_xml, "~> 0.7.2"},
 147       {:earmark, "~> 1.4.15"},
 148       {:bbcode_pleroma, "~> 0.2.0"},
 149       {:crypt,
 150        git: "https://github.com/msantos/crypt.git",
 151        ref: "f75cd55325e33cbea198fb41fe41871392f8fb76"},
 152       {:cors_plug, "~> 2.0"},
 153       {:web_push_encryption, "~> 0.3.1"},
 154       {:swoosh, "~> 1.0"},
 155       {:phoenix_swoosh, "~> 0.3"},
 156       {:gen_smtp, "~> 0.13"},
 157       {:ex_syslogger, "~> 1.4"},
 158       {:floki, "~> 0.27"},
 159       {:timex, "~> 3.6"},
 160       {:ueberauth, "~> 0.4"},
 161       {:linkify,
 162        git: "https://akkoma.dev/AkkomaGang/linkify.git", branch: "bugfix/line-ending-buffer"},
 163       {:http_signatures, "~> 0.1.1"},
 164       {:telemetry, "~> 0.3"},
 165       {:poolboy, "~> 1.5"},
 166       {:recon, "~> 2.5"},
 167       {:quack, "~> 0.1.1"},
 168       {:joken, "~> 2.0"},
 169       {:benchee, "~> 1.0"},
 170       {:pot, "~> 1.0"},
 171       {:ex_const, "~> 0.2"},
 172       {:plug_static_index_html, "~> 1.0.0"},
 173       {:flake_id, "~> 0.1.0"},
 174       {:concurrent_limiter, "~> 0.1.1"},
 175       {:remote_ip,
 176        git: "https://git.pleroma.social/pleroma/remote_ip.git",
 177        ref: "b647d0deecaa3acb140854fe4bda5b7e1dc6d1c8"},
 178       {:captcha,
 179        git: "https://git.pleroma.social/pleroma/elixir-libraries/elixir-captcha.git",
 180        ref: "e0f16822d578866e186a0974d65ad58cddc1e2ab"},
 181       {:restarter, path: "./restarter"},
 182       {:majic, "~> 1.0"},
 183       {:eblurhash, "~> 1.2.2"},
 184       {:open_api_spex, "3.10.0"},
 185       {:search_parser,
 186        git: "https://github.com/FloatingGhost/pleroma-contrib-search-parser.git",
 187        ref: "08971a81e68686f9ac465cfb6661d51c5e4e1e7f"},
 188       {:nimble_parsec, "~> 1.0", override: true},
 189       {:phoenix_live_dashboard, "~> 0.6.2"},
 190       {:ecto_psql_extras, "~> 0.6"},
 191       {:elasticsearch,
 192        git: "https://akkoma.dev/AkkomaGang/elasticsearch-elixir.git", ref: "main"},
 193       {:mfm_parser,
 194        git: "https://akkoma.dev/AkkomaGang/mfm-parser.git",
 195        ref: "912fba81152d4d572e457fd5427f9875b2bc3dbe"},
 196
 197       # indirect dependency version override
 198       {:plug, "~> 1.10.4", override: true},
 199
 200       ## dev & test
 201       {:ex_doc, "~> 0.22", only: :dev, runtime: false},
 202       {:ex_machina, "~> 2.4", only: :test},
 203       {:credo, "~> 1.6", only: [:dev, :test], runtime: false},
 204       {:mock, "~> 0.3.5", only: :test},
 205       # temporary downgrade for excoveralls, hackney until hackney max_connections bug will be fixed
 206       {:excoveralls, "0.12.3", only: :test},
 207       {:mox, "~> 1.0", only: :test},
 208       {:websockex, "~> 0.4.3", only: :test}
 209     ] ++ oauth_deps()
 210   end
 211
 212   # Aliases are shortcuts or tasks specific to the current project.
 213   # For example, to create, migrate and run the seeds file at once:
 214   #
 215   #     $ mix ecto.setup
 216   #
 217   # See the documentation for `Mix` for more info on aliases.
 218   defp aliases do
 219     [
 220       "ecto.migrate": ["pleroma.ecto.migrate"],
 221       "ecto.rollback": ["pleroma.ecto.rollback"],
 222       "ecto.setup": ["ecto.create", "ecto.migrate", "run priv/repo/seeds.exs"],
 223       "ecto.reset": ["ecto.drop", "ecto.setup"],
 224       test: ["ecto.create --quiet", "ecto.migrate", "test"],
 225       docs: ["pleroma.docs", "docs"],
 226       analyze: ["credo --strict --only=warnings,todo,fixme,consistency,readability"],
 227       copyright: &add_copyright/1,
 228       "copyright.bump": &bump_copyright/1
 229     ]
 230   end
 231
 232   # Builds a version string made of:
 233   # * the application version
 234   # * a pre-release if ahead of the tag: the describe string (-count-commithash)
 235   # * branch name
 236   # * build metadata:
 237   #   * a build name if `PLEROMA_BUILD_NAME` or `:pleroma, :build_name` is defined
 238   #   * the mix environment if different than prod
 239   defp version(version) do
 240     identifier_filter = ~r/[^0-9a-z\-]+/i
 241
 242     git_available? = match?({_output, 0}, System.cmd("sh", ["-c", "command -v git"]))
 243     dotgit_present? = File.exists?(".git")
 244
 245     git_pre_release =
 246       if git_available? and dotgit_present? do
 247         {tag, tag_err} =
 248           System.cmd("git", ["describe", "--tags", "--abbrev=0"], stderr_to_stdout: true)
 249
 250         {describe, describe_err} = System.cmd("git", ["describe", "--tags", "--abbrev=8"])
 251         {commit_hash, commit_hash_err} = System.cmd("git", ["rev-parse", "--short", "HEAD"])
 252
 253         # Pre-release version, denoted from patch version with a hyphen
 254         cond do
 255           tag_err == 0 and describe_err == 0 ->
 256             describe
 257             |> String.trim()
 258             |> String.replace(String.trim(tag), "")
 259             |> String.trim_leading("-")
 260             |> String.trim()
 261
 262           commit_hash_err == 0 ->
 263             "0-g" <> String.trim(commit_hash)
 264
 265           true ->
 266             nil
 267         end
 268       end
 269
 270     # Branch name as pre-release version component, denoted with a dot
 271     branch_name =
 272       with true <- git_available?,
 273            true <- dotgit_present?,
 274            {branch_name, 0} <- System.cmd("git", ["rev-parse", "--abbrev-ref", "HEAD"]),
 275            branch_name <- String.trim(branch_name),
 276            branch_name <- System.get_env("PLEROMA_BUILD_BRANCH") || branch_name,
 277            true <-
 278              !Enum.any?(["master", "HEAD", "release/", "stable"], fn name ->
 279                String.starts_with?(name, branch_name)
 280              end) do
 281         branch_name =
 282           branch_name
 283           |> String.trim()
 284           |> String.replace(identifier_filter, "-")
 285
 286         branch_name
 287       else
 288         _ -> ""
 289       end
 290
 291     build_name =
 292       cond do
 293         name = Application.get_env(:pleroma, :build_name) -> name
 294         name = System.get_env("PLEROMA_BUILD_NAME") -> name
 295         true -> nil
 296       end
 297
 298     env_name = if Mix.env() != :prod, do: to_string(Mix.env())
 299     env_override = System.get_env("PLEROMA_BUILD_ENV")
 300
 301     env_name =
 302       case env_override do
 303         nil -> env_name
 304         env_override when env_override in ["", "prod"] -> nil
 305         env_override -> env_override
 306       end
 307
 308     # Pre-release version, denoted by appending a hyphen
 309     # and a series of dot separated identifiers
 310     pre_release =
 311       [git_pre_release, branch_name]
 312       |> Enum.filter(fn string -> string && string != "" end)
 313       |> Enum.join(".")
 314       |> (fn
 315             "" -> nil
 316             string -> "-" <> String.replace(string, identifier_filter, "-")
 317           end).()
 318
 319     # Build metadata, denoted with a plus sign
 320     build_metadata =
 321       [build_name, env_name]
 322       |> Enum.filter(fn string -> string && string != "" end)
 323       |> Enum.join(".")
 324       |> (fn
 325             "" -> nil
 326             string -> "+" <> String.replace(string, identifier_filter, "-")
 327           end).()
 328
 329     [version, pre_release, build_metadata]
 330     |> Enum.filter(fn string -> string && string != "" end)
 331     |> Enum.join()
 332   end
 333
 334   defp add_copyright(_) do
 335     year = NaiveDateTime.utc_now().year
 336     template = ~s[\
 337 # Pleroma: A lightweight social networking server
 338 # Copyright © 2017-#{year} Pleroma Authors <https://pleroma.social/>
 339 # SPDX-License-Identifier: AGPL-3.0-only
 340 # Akkoma: The cooler pleroma
 341 # Copyright © 2022-#{year} Akkoma Authors <https://akkoma.dev/>
 342 # SPDX-License-Identifier: AGPL-3.0-only
 343
 344 ] |> String.replace("\n", "\\n")
 345
 346     find = "find lib test priv -type f \\( -name '*.ex' -or -name '*.exs' \\) -exec "
 347     grep = "grep -L '# Copyright © [0-9\-]* Pleroma' {} \\;"
 348     xargs = "xargs -n1 sed -i'' '1s;^;#{template};'"
 349
 350     :os.cmd(String.to_charlist("#{find}#{grep} | #{xargs}"))
 351   end
 352
 353   defp bump_copyright(_) do
 354     year = NaiveDateTime.utc_now().year
 355     find = "find lib test priv -type f \\( -name '*.ex' -or -name '*.exs' \\)"
 356
 357     xargs =
 358       "xargs sed -i'' 's;# Copyright © [0-9\-]* Pleroma.*$;# Copyright © 2017-#{year} Pleroma Authors <https://pleroma.social/>;'"
 359
 360     :os.cmd(String.to_charlist("#{find} | #{xargs}"))
 361   end
 362 end