git.squeep.com Git - akkoma/blob - lib/pleroma/workers/new_users_digest_worker.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Workers.NewUsersDigestWorker do
   6   alias Pleroma.User
   7   alias Pleroma.Repo
   8   alias Pleroma.Activity
   9
  10   import Ecto.Query
  11
  12   use Pleroma.Workers.WorkerHelper, queue: "new_users_digest"
  13
  14   @impl Oban.Worker
  15   def perform(_args, _job) do
  16     today = NaiveDateTime.utc_now() |> Timex.beginning_of_day()
  17
  18     a_day_ago =
  19       today
  20       |> Timex.shift(days: -1)
  21       |> Timex.beginning_of_day()
  22
  23     users_and_statuses =
  24       %{
  25         local: true,
  26         order_by: :inserted_at
  27       }
  28       |> User.Query.build()
  29       |> where([u], u.inserted_at >= ^a_day_ago and u.inserted_at < ^today)
  30       |> Repo.all()
  31       |> Enum.map(fn user ->
  32         latest_status =
  33           Activity
  34           |> Activity.Queries.by_actor(user.ap_id)
  35           |> Activity.Queries.by_type("Create")
  36           |> Activity.with_preloaded_object()
  37           |> order_by(desc: :inserted_at)
  38           |> limit(1)
  39           |> Repo.one()
  40
  41         total_statuses =
  42           Activity
  43           |> Activity.Queries.by_actor(user.ap_id)
  44           |> Activity.Queries.by_type("Create")
  45           |> Repo.aggregate(:count, :id)
  46
  47         {user, total_statuses, latest_status}
  48       end)
  49
  50     %{is_admin: true}
  51     |> User.Query.build()
  52     |> Repo.all()
  53     |> Enum.map(&Pleroma.Emails.NewUsersDigestEmail.new_users(&1, users_and_statuses))
  54     |> Enum.each(&Pleroma.Emails.Mailer.deliver/1)
  55   end
  56 end