git.squeep.com Git - akkoma/blob - lib/pleroma/workers/attachments_cleanup_worker.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Workers.AttachmentsCleanupWorker do
   6   import Ecto.Query
   7
   8   alias Pleroma.Object
   9   alias Pleroma.Repo
  10
  11   require Logger
  12
  13   use Pleroma.Workers.WorkerHelper, queue: "attachments_cleanup"
  14
  15   @impl Oban.Worker
  16   def perform(
  17         %{
  18           "op" => "cleanup_attachments",
  19           "object" => %{"data" => %{"attachment" => [_ | _] = attachments, "actor" => actor}}
  20         },
  21         _job
  22       ) do
  23     hrefs =
  24       Enum.flat_map(attachments, fn attachment ->
  25         Enum.map(attachment["url"], & &1["href"])
  26       end)
  27
  28     names = Enum.map(attachments, & &1["name"])
  29
  30     uploader = Pleroma.Config.get([Pleroma.Upload, :uploader])
  31
  32     # find all objects for copies of the attachments, name and actor doesn't matter here
  33     delete_ids =
  34       from(o in Object,
  35         where:
  36           fragment(
  37             "to_jsonb(array(select jsonb_array_elements((?)#>'{url}') ->> 'href' where jsonb_typeof((?)#>'{url}') = 'array'))::jsonb \\?| (?)",
  38             o.data,
  39             o.data,
  40             ^hrefs
  41           )
  42       )
  43       # The query above can be time consumptive on large instances until we
  44       # refactor how uploads are stored
  45       |> Repo.all(timeout: :infinity)
  46       # we should delete 1 object for any given attachment, but don't delete
  47       # files if there are more than 1 object for it
  48       |> Enum.reduce(%{}, fn %{
  49                                id: id,
  50                                data: %{
  51                                  "url" => [%{"href" => href}],
  52                                  "actor" => obj_actor,
  53                                  "name" => name
  54                                }
  55                              },
  56                              acc ->
  57         Map.update(acc, href, %{id: id, count: 1}, fn val ->
  58           case obj_actor == actor and name in names do
  59             true ->
  60               # set id of the actor's object that will be deleted
  61               %{val | id: id, count: val.count + 1}
  62
  63             false ->
  64               # another actor's object, just increase count to not delete file
  65               %{val | count: val.count + 1}
  66           end
  67         end)
  68       end)
  69       |> Enum.map(fn {href, %{id: id, count: count}} ->
  70         # only delete files that have single instance
  71         with 1 <- count do
  72           prefix =
  73             case Pleroma.Config.get([Pleroma.Upload, :base_url]) do
  74               nil -> "media"
  75               _ -> ""
  76             end
  77
  78           base_url = Pleroma.Config.get([Pleroma.Upload, :base_url], Pleroma.Web.base_url())
  79
  80           file_path = String.trim_leading(href, "#{base_url}/#{prefix}")
  81
  82           Logger.warn("Deleting file #{file_path} (orig: #{href}, base_url: #{base_url})")
  83           uploader.delete_file(file_path)
  84         end
  85
  86         id
  87       end)
  88
  89     from(o in Object, where: o.id in ^delete_ids)
  90     |> Repo.delete_all()
  91   end
  92
  93   def perform(%{"op" => "cleanup_attachments", "object" => _object}, _job), do: :ok
  94 end