git.squeep.com Git - akkoma/blob - lib/pleroma/workers/attachments_cleanup_worker.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Workers.AttachmentsCleanupWorker do
   6   import Ecto.Query
   7
   8   alias Pleroma.Object
   9   alias Pleroma.Repo
  10
  11   use Pleroma.Workers.WorkerHelper, queue: "attachments_cleanup"
  12
  13   @impl Oban.Worker
  14   def perform(%Job{
  15         args: %{
  16           "op" => "cleanup_attachments",
  17           "object" => %{"data" => %{"attachment" => [_ | _] = attachments, "actor" => actor}}
  18         }
  19       }) do
  20     attachments
  21     |> Enum.flat_map(fn item -> Enum.map(item["url"], & &1["href"]) end)
  22     |> fetch_objects
  23     |> prepare_objects(actor, Enum.map(attachments, & &1["name"]))
  24     |> filter_objects
  25     |> do_clean
  26
  27     {:ok, :success}
  28   end
  29
  30   def perform(%Job{args: %{"op" => "cleanup_attachments", "object" => _object}}), do: {:ok, :skip}
  31
  32   defp do_clean({object_ids, attachment_urls}) do
  33     uploader = Pleroma.Config.get([Pleroma.Upload, :uploader])
  34
  35     base_url =
  36       String.trim_trailing(
  37         Pleroma.Upload.base_url(),
  38         "/"
  39       )
  40
  41     Enum.each(attachment_urls, fn href ->
  42       href
  43       |> String.trim_leading("#{base_url}")
  44       |> uploader.delete_file()
  45     end)
  46
  47     delete_objects(object_ids)
  48   end
  49
  50   defp delete_objects([_ | _] = object_ids) do
  51     Repo.delete_all(from(o in Object, where: o.id in ^object_ids))
  52   end
  53
  54   defp delete_objects(_), do: :ok
  55
  56   # we should delete 1 object for any given attachment, but don't delete
  57   # files if there are more than 1 object for it
  58   defp filter_objects(objects) do
  59     Enum.reduce(objects, {[], []}, fn {href, %{id: id, count: count}}, {ids, hrefs} ->
  60       with 1 <- count do
  61         {ids ++ [id], hrefs ++ [href]}
  62       else
  63         _ -> {ids ++ [id], hrefs}
  64       end
  65     end)
  66   end
  67
  68   defp prepare_objects(objects, actor, names) do
  69     objects
  70     |> Enum.reduce(%{}, fn %{
  71                              id: id,
  72                              data: %{
  73                                "url" => [%{"href" => href}],
  74                                "actor" => obj_actor,
  75                                "name" => name
  76                              }
  77                            },
  78                            acc ->
  79       Map.update(acc, href, %{id: id, count: 1}, fn val ->
  80         case obj_actor == actor and name in names do
  81           true ->
  82             # set id of the actor's object that will be deleted
  83             %{val | id: id, count: val.count + 1}
  84
  85           false ->
  86             # another actor's object, just increase count to not delete file
  87             %{val | count: val.count + 1}
  88         end
  89       end)
  90     end)
  91   end
  92
  93   defp fetch_objects(hrefs) do
  94     from(o in Object,
  95       where:
  96         fragment(
  97           "to_jsonb(array(select jsonb_array_elements((?)#>'{url}') ->> 'href' where jsonb_typeof((?)#>'{url}') = 'array'))::jsonb \\?| (?)",
  98           o.data,
  99           o.data,
 100           ^hrefs
 101         )
 102     )
 103     # The query above can be time consumptive on large instances until we
 104     # refactor how uploads are stored
 105     |> Repo.all(timeout: :infinity)
 106   end
 107 end