git.squeep.com Git - akkoma/blob - lib/pleroma/web/websub/websub.ex

   1 defmodule Pleroma.Web.Websub do
   2   alias Ecto.Changeset
   3   alias Pleroma.Repo
   4   alias Pleroma.Web.Websub.{WebsubServerSubscription, WebsubClientSubscription}
   5   alias Pleroma.Web.OStatus.FeedRepresenter
   6   alias Pleroma.Web.{XML, Endpoint, OStatus}
   7   alias Pleroma.Web.Router.Helpers
   8   require Logger
   9
  10   import Ecto.Query
  11
  12   @httpoison Application.get_env(:pleroma, :httpoison)
  13
  14   def verify(subscription, getter \\ &@httpoison.get/3) do
  15     challenge = Base.encode16(:crypto.strong_rand_bytes(8))
  16     lease_seconds = NaiveDateTime.diff(subscription.valid_until, subscription.updated_at)
  17     lease_seconds = lease_seconds |> to_string
  18
  19     params = %{
  20       "hub.challenge": challenge,
  21       "hub.lease_seconds": lease_seconds,
  22       "hub.topic": subscription.topic,
  23       "hub.mode": "subscribe"
  24     }
  25
  26     url = hd(String.split(subscription.callback, "?"))
  27     query = URI.parse(subscription.callback).query || ""
  28     params = Map.merge(params, URI.decode_query(query))
  29     with {:ok, response} <- getter.(url, [], [params: params]),
  30          ^challenge <- response.body
  31     do
  32       changeset = Changeset.change(subscription, %{state: "active"})
  33       Repo.update(changeset)
  34     else _e ->
  35       changeset = Changeset.change(subscription, %{state: "rejected"})
  36       {:ok, subscription} = Repo.update(changeset)
  37       {:error, subscription}
  38     end
  39   end
  40
  41   def publish(topic, user, activity) do
  42     # TODO: Only send to still valid subscriptions.
  43     query = from sub in WebsubServerSubscription,
  44     where: sub.topic == ^topic and sub.state == "active"
  45     subscriptions = Repo.all(query)
  46     Enum.each(subscriptions, fn(sub) ->
  47       response = user
  48       |> FeedRepresenter.to_simple_form([activity], [user])
  49       |> :xmerl.export_simple(:xmerl_xml)
  50       |> to_string
  51
  52       data = %{
  53         xml: response,
  54         topic: topic,
  55         callback: sub.callback,
  56         secret: sub.secret
  57       }
  58       Pleroma.Web.Federator.enqueue(:publish_single_websub, data)
  59     end)
  60   end
  61
  62   def sign(secret, doc) do
  63     :crypto.hmac(:sha, secret, to_string(doc)) |> Base.encode16 |> String.downcase
  64   end
  65
  66   def incoming_subscription_request(user, %{"hub.mode" => "subscribe"} = params) do
  67     with {:ok, topic} <- valid_topic(params, user),
  68          {:ok, lease_time} <- lease_time(params),
  69          secret <- params["hub.secret"],
  70          callback <- params["hub.callback"]
  71     do
  72       subscription = get_subscription(topic, callback)
  73       data = %{
  74         state: subscription.state || "requested",
  75         topic: topic,
  76         secret: secret,
  77         callback: callback
  78       }
  79
  80       change = Changeset.change(subscription, data)
  81       websub = Repo.insert_or_update!(change)
  82
  83       change = Changeset.change(websub, %{valid_until:
  84                                           NaiveDateTime.add(websub.updated_at, lease_time)})
  85       websub = Repo.update!(change)
  86
  87       Pleroma.Web.Federator.enqueue(:verify_websub, websub)
  88
  89       {:ok, websub}
  90     else {:error, reason} ->
  91       Logger.debug("Couldn't create subscription.")
  92       Logger.debug(inspect(reason))
  93
  94       {:error, reason}
  95     end
  96   end
  97
  98   defp get_subscription(topic, callback) do
  99     Repo.get_by(WebsubServerSubscription, topic: topic, callback: callback) ||
 100       %WebsubServerSubscription{}
 101   end
 102
 103   # Temp hack for mastodon.
 104   defp lease_time(%{"hub.lease_seconds" => ""}) do
 105     {:ok, 60 * 60 * 24 * 3} # three days
 106   end
 107
 108   defp lease_time(%{"hub.lease_seconds" => lease_seconds}) do
 109     {:ok, String.to_integer(lease_seconds)}
 110   end
 111
 112   defp lease_time(_) do
 113     {:ok, 60 * 60 * 24 * 3} # three days
 114   end
 115
 116   defp valid_topic(%{"hub.topic" => topic}, user) do
 117     if topic == OStatus.feed_path(user) do
 118       {:ok, OStatus.feed_path(user)}
 119     else
 120       {:error, "Wrong topic requested, expected #{OStatus.feed_path(user)}, got #{topic}"}
 121     end
 122   end
 123
 124   def subscribe(subscriber, subscribed, requester \\ &request_subscription/1) do
 125     topic = subscribed.info["topic"]
 126     # FIXME: Race condition, use transactions
 127     {:ok, subscription} = with subscription when not is_nil(subscription) <- Repo.get_by(WebsubClientSubscription, topic: topic) do
 128       subscribers = [subscriber.ap_id | subscription.subscribers] |> Enum.uniq
 129       change = Ecto.Changeset.change(subscription, %{subscribers: subscribers})
 130       Repo.update(change)
 131     else _e ->
 132       subscription = %WebsubClientSubscription{
 133         topic: topic,
 134         hub: subscribed.info["hub"],
 135         subscribers: [subscriber.ap_id],
 136         state: "requested",
 137         secret: :crypto.strong_rand_bytes(8) |> Base.url_encode64,
 138         user: subscribed
 139       }
 140       Repo.insert(subscription)
 141     end
 142     requester.(subscription)
 143   end
 144
 145   def gather_feed_data(topic, getter \\ &@httpoison.get/1) do
 146     with {:ok, response} <- getter.(topic),
 147          status_code when status_code in 200..299 <- response.status_code,
 148          body <- response.body,
 149          doc <- XML.parse_document(body),
 150          uri when not is_nil(uri) <- XML.string_from_xpath("/feed/author[1]/uri", doc),
 151          hub when not is_nil(hub) <- XML.string_from_xpath(~S{/feed/link[@rel="hub"]/@href}, doc) do
 152
 153       name = XML.string_from_xpath("/feed/author[1]/name", doc)
 154       preferredUsername = XML.string_from_xpath("/feed/author[1]/poco:preferredUsername", doc)
 155       displayName = XML.string_from_xpath("/feed/author[1]/poco:displayName", doc)
 156       avatar = OStatus.make_avatar_object(doc)
 157       bio = XML.string_from_xpath("/feed/author[1]/summary", doc)
 158
 159       {:ok, %{
 160         "uri" => uri,
 161         "hub" => hub,
 162         "nickname" => preferredUsername || name,
 163         "name" => displayName || name,
 164         "host" => URI.parse(uri).host,
 165         "avatar" => avatar,
 166         "bio" => bio
 167       }}
 168     else e ->
 169       {:error, e}
 170     end
 171   end
 172
 173   def request_subscription(websub, poster \\ &@httpoison.post/3, timeout \\ 10_000) do
 174     data = [
 175       "hub.mode": "subscribe",
 176       "hub.topic": websub.topic,
 177       "hub.secret": websub.secret,
 178       "hub.callback": Helpers.websub_url(Endpoint, :websub_subscription_confirmation, websub.id)
 179     ]
 180
 181     # This checks once a second if we are confirmed yet
 182     websub_checker = fn ->
 183       helper = fn (helper) ->
 184         :timer.sleep(1000)
 185         websub = Repo.get_by(WebsubClientSubscription, id: websub.id, state: "accepted")
 186         if websub, do: websub, else: helper.(helper)
 187       end
 188       helper.(helper)
 189     end
 190
 191     task = Task.async(websub_checker)
 192
 193     with {:ok, %{status_code: 202}} <- poster.(websub.hub, {:form, data}, ["Content-type": "application/x-www-form-urlencoded"]),
 194          {:ok, websub} <- Task.yield(task, timeout) do
 195       {:ok, websub}
 196     else e ->
 197       Task.shutdown(task)
 198
 199       change = Ecto.Changeset.change(websub, %{state: "rejected"})
 200       {:ok, websub} = Repo.update(change)
 201
 202       Logger.debug(fn -> "Couldn't confirm subscription: #{inspect(websub)}" end)
 203       Logger.debug(fn -> "error: #{inspect(e)}" end)
 204
 205       {:error, websub}
 206     end
 207   end
 208
 209   def refresh_subscriptions(delta \\ 60 * 60 * 24) do
 210     Logger.debug("Refreshing subscriptions")
 211
 212     cut_off = NaiveDateTime.add(NaiveDateTime.utc_now, delta)
 213
 214     query = from sub in WebsubClientSubscription,
 215       where: sub.valid_until < ^cut_off
 216
 217     subs = Repo.all(query)
 218
 219     Enum.each(subs, fn (sub) ->
 220       Pleroma.Web.Federator.enqueue(:request_subscription, sub)
 221     end)
 222   end
 223 end