git.squeep.com Git - akkoma/blob - lib/pleroma/web/websub/websub.ex

   1 defmodule Pleroma.Web.Websub do
   2   alias Pleroma.Repo
   3   alias Pleroma.Web.Websub.{WebsubServerSubscription, WebsubClientSubscription}
   4   alias Pleroma.Web.OStatus.FeedRepresenter
   5   alias Pleroma.Web.{XML, Endpoint, OStatus}
   6   alias Pleroma.Web.Router.Helpers
   7   require Logger
   8
   9   import Ecto.Query
  10
  11   def verify(subscription, getter \\ &HTTPoison.get/3 ) do
  12     challenge = Base.encode16(:crypto.strong_rand_bytes(8))
  13     lease_seconds = NaiveDateTime.diff(subscription.valid_until, subscription.updated_at) |> to_string
  14
  15     params = %{
  16       "hub.challenge": challenge,
  17       "hub.lease_seconds": lease_seconds,
  18       "hub.topic": subscription.topic,
  19       "hub.mode": "subscribe"
  20     }
  21
  22     url = hd(String.split(subscription.callback, "?"))
  23     query = URI.parse(subscription.callback).query || ""
  24     params = Map.merge(params, URI.decode_query(query))
  25     with {:ok, response} <- getter.(url, [], [params: params]),
  26          ^challenge <- response.body
  27     do
  28       changeset = Ecto.Changeset.change(subscription, %{state: "active"})
  29       Repo.update(changeset)
  30     else _e ->
  31       changeset = Ecto.Changeset.change(subscription, %{state: "rejected"})
  32       {:ok, subscription } = Repo.update(changeset)
  33       {:error, subscription}
  34     end
  35   end
  36
  37   def publish(topic, user, activity) do
  38     query = from sub in WebsubServerSubscription,
  39     where: sub.topic == ^topic and sub.state == "active"
  40     subscriptions = Repo.all(query)
  41     Enum.each(subscriptions, fn(sub) ->
  42       response = FeedRepresenter.to_simple_form(user, [activity], [user])
  43       |> :xmerl.export_simple(:xmerl_xml)
  44       |> to_string
  45
  46       signature = sign(sub.secret || "", response)
  47       Logger.debug("Pushing to #{sub.callback}")
  48       HTTPoison.post(sub.callback, response, [
  49             {"Content-Type", "application/atom+xml"},
  50             {"X-Hub-Signature", "sha1=#{signature}"}
  51           ])
  52     end)
  53   end
  54
  55   def sign(secret, doc) do
  56     :crypto.hmac(:sha, secret, to_string(doc)) |> Base.encode16 |> String.downcase
  57   end
  58
  59   def incoming_subscription_request(user, %{"hub.mode" => "subscribe"} = params) do
  60     with {:ok, topic} <- valid_topic(params, user),
  61          {:ok, lease_time} <- lease_time(params),
  62          secret <- params["hub.secret"],
  63          callback <- params["hub.callback"]
  64     do
  65       subscription = get_subscription(topic, callback)
  66       data = %{
  67         state: subscription.state || "requested",
  68         topic: topic,
  69         secret: secret,
  70         callback: callback
  71       }
  72
  73       change = Ecto.Changeset.change(subscription, data)
  74       websub = Repo.insert_or_update!(change)
  75
  76       change = Ecto.Changeset.change(websub, %{valid_until: NaiveDateTime.add(websub.updated_at, lease_time)})
  77       websub = Repo.update!(change)
  78
  79       Pleroma.Web.Federator.enqueue(:verify_websub, websub)
  80
  81       {:ok, websub}
  82     else {:error, reason} ->
  83       Logger.debug("Couldn't create subscription.")
  84       Logger.debug(inspect(reason))
  85
  86       {:error, reason}
  87     end
  88   end
  89
  90   defp get_subscription(topic, callback) do
  91     Repo.get_by(WebsubServerSubscription, topic: topic, callback: callback) || %WebsubServerSubscription{}
  92   end
  93
  94   # Temp hack for mastodon.
  95   defp lease_time(%{"hub.lease_seconds" => ""}) do
  96     {:ok, 60 * 60 * 24 * 3} # three days
  97   end
  98
  99   defp lease_time(%{"hub.lease_seconds" => lease_seconds}) do
 100     {:ok, String.to_integer(lease_seconds)}
 101   end
 102
 103   defp lease_time(_) do
 104     {:ok, 60 * 60 * 24 * 3} # three days
 105   end
 106
 107   defp valid_topic(%{"hub.topic" => topic}, user) do
 108     if topic == OStatus.feed_path(user) do
 109       {:ok, OStatus.feed_path(user)}
 110     else
 111       {:error, "Wrong topic requested, expected #{OStatus.feed_path(user)}, got #{topic}"}
 112     end
 113   end
 114
 115   def subscribe(subscriber, subscribed, requester \\ &request_subscription/1) do
 116     topic = subscribed.info["topic"]
 117     # FIXME: Race condition, use transactions
 118     {:ok, subscription} = with subscription when not is_nil(subscription) <- Repo.get_by(WebsubClientSubscription, topic: topic) do
 119       subscribers = [subscriber.ap_id, subscription.subscribers] |> Enum.uniq
 120       change = Ecto.Changeset.change(subscription, %{subscribers: subscribers})
 121       Repo.update(change)
 122     else _e ->
 123       subscription = %WebsubClientSubscription{
 124         topic: topic,
 125         hub: subscribed.info["hub"],
 126         subscribers: [subscriber.ap_id],
 127         state: "requested",
 128         secret: :crypto.strong_rand_bytes(8) |> Base.url_encode64,
 129         user: subscribed
 130       }
 131       Repo.insert(subscription)
 132     end
 133     requester.(subscription)
 134   end
 135
 136   def gather_feed_data(topic, getter \\ &HTTPoison.get/1) do
 137     with {:ok, response} <- getter.(topic),
 138          status_code when status_code in 200..299 <- response.status_code,
 139          body <- response.body,
 140          doc <- XML.parse_document(body),
 141          uri when not is_nil(uri) <- XML.string_from_xpath("/feed/author[1]/uri", doc),
 142          hub when not is_nil(hub) <- XML.string_from_xpath(~S{/feed/link[@rel="hub"]/@href}, doc) do
 143
 144       name = XML.string_from_xpath("/feed/author[1]/name", doc)
 145       preferredUsername = XML.string_from_xpath("/feed/author[1]/poco:preferredUsername", doc)
 146       displayName = XML.string_from_xpath("/feed/author[1]/poco:displayName", doc)
 147       avatar = OStatus.make_avatar_object(doc)
 148
 149       {:ok, %{
 150         "uri" => uri,
 151         "hub" => hub,
 152         "nickname" => preferredUsername || name,
 153         "name" => displayName || name,
 154         "host" => URI.parse(uri).host,
 155         "avatar" => avatar
 156       }}
 157     else e ->
 158       {:error, e}
 159     end
 160   end
 161
 162   def request_subscription(websub, poster \\ &HTTPoison.post/3, timeout \\ 10_000) do
 163     data = [
 164       "hub.mode": "subscribe",
 165       "hub.topic": websub.topic,
 166       "hub.secret": websub.secret,
 167       "hub.callback": Helpers.websub_url(Endpoint, :websub_subscription_confirmation, websub.id)
 168     ]
 169
 170     # This checks once a second if we are confirmed yet
 171     websub_checker = fn ->
 172       helper = fn (helper) ->
 173         :timer.sleep(1000)
 174         websub = Repo.get_by(WebsubClientSubscription, id: websub.id, state: "accepted")
 175         if websub, do: websub, else: helper.(helper)
 176       end
 177       helper.(helper)
 178     end
 179
 180     task = Task.async(websub_checker)
 181
 182     with {:ok, %{status_code: 202}} <- poster.(websub.hub, {:form, data}, ["Content-type": "application/x-www-form-urlencoded"]),
 183          {:ok, websub} <- Task.yield(task, timeout) do
 184       {:ok, websub}
 185     else e ->
 186       Task.shutdown(task)
 187
 188       change = Ecto.Changeset.change(websub, %{state: "rejected"})
 189       {:ok, websub} = Repo.update(change)
 190
 191       Logger.debug("Couldn't confirm subscription: #{inspect(websub)}")
 192       Logger.debug("error: #{inspect(e)}")
 193
 194       {:error, websub}
 195     end
 196   end
 197 end