git.squeep.com Git - akkoma/blob - lib/pleroma/web/web_finger/web_finger.ex

   1 defmodule Pleroma.Web.WebFinger do
   2   alias Pleroma.XmlBuilder
   3   alias Pleroma.{Repo, User}
   4   alias Pleroma.Web.{XML, Salmon, OStatus}
   5   require Logger
   6
   7   def host_meta() do
   8     base_url  = Pleroma.Web.base_url
   9     {
  10       :XRD, %{ xmlns: "http://docs.oasis-open.org/ns/xri/xrd-1.0" },
  11       {
  12         :Link, %{ rel: "lrdd", type: "application/xrd+xml", template: "#{base_url}/.well-known/webfinger?resource={uri}"  }
  13       }
  14     }
  15     |> XmlBuilder.to_doc
  16   end
  17
  18   def webfinger(resource) do
  19     host = Pleroma.Web.host
  20     regex = ~r/(acct:)?(?<username>\w+)@#{host}/
  21     with %{"username" => username} <- Regex.named_captures(regex, resource) do
  22       user = User.get_by_nickname(username)
  23       {:ok, represent_user(user)}
  24     else _e ->
  25       with user when not is_nil(user) <- User.get_cached_by_ap_id(resource) do
  26         {:ok, represent_user(user)}
  27       else _e ->
  28         {:error, "Couldn't find user"}
  29       end
  30     end
  31   end
  32
  33   def represent_user(user) do
  34     {:ok, user} = ensure_keys_present(user)
  35     {:ok, _private, public} = Salmon.keys_from_pem(user.info["keys"])
  36     magic_key = Salmon.encode_key(public)
  37     {
  38       :XRD, %{xmlns: "http://docs.oasis-open.org/ns/xri/xrd-1.0"},
  39       [
  40         {:Subject, "acct:#{user.nickname}@#{Pleroma.Web.host}"},
  41         {:Alias, user.ap_id},
  42         {:Link, %{rel: "http://schemas.google.com/g/2010#updates-from", type: "application/atom+xml", href: OStatus.feed_path(user)}},
  43         {:Link, %{rel: "salmon", href: OStatus.salmon_path(user)}},
  44         {:Link, %{rel: "magic-public-key", href: "data:application/magic-public-key,#{magic_key}"}}
  45       ]
  46     }
  47     |> XmlBuilder.to_doc
  48   end
  49
  50   def ensure_keys_present(user) do
  51     info = user.info || %{}
  52     if info["keys"] do
  53       {:ok, user}
  54     else
  55       {:ok, pem} = Salmon.generate_rsa_pem
  56       info = Map.put(info, "keys", pem)
  57       Repo.update(Ecto.Changeset.change(user, info: info))
  58     end
  59   end
  60
  61   # FIXME: Make this call the host-meta to find the actual address.
  62   defp webfinger_address(domain) do
  63     "//#{domain}/.well-known/webfinger"
  64   end
  65
  66   defp webfinger_from_xml(doc) do
  67     magic_key = XML.string_from_xpath(~s{//Link[@rel="magic-public-key"]/@href}, doc)
  68     "data:application/magic-public-key," <> magic_key = magic_key
  69     topic = XML.string_from_xpath(~s{//Link[@rel="http://schemas.google.com/g/2010#updates-from"]/@href}, doc)
  70     subject = XML.string_from_xpath("//Subject", doc)
  71     salmon = XML.string_from_xpath(~s{//Link[@rel="salmon"]/@href}, doc)
  72     data = %{
  73       magic_key: magic_key,
  74       topic: topic,
  75       subject: subject,
  76       salmon: salmon
  77     }
  78     {:ok, data}
  79   end
  80
  81   def finger(account, getter \\ &HTTPoison.get/3) do
  82     domain = with [_name, domain] <- String.split(account, "@") do
  83                domain
  84              else _e ->
  85                URI.parse(account).host
  86              end
  87     address = webfinger_address(domain)
  88
  89     # try https first
  90     response = with {:ok, result} <- getter.("https:" <> address, ["Accept": "application/xrd+xml"], [params: [resource: account]]) do
  91                  {:ok, result}
  92                else _ ->
  93                  getter.("http:" <> address, ["Accept": "application/xrd+xml"], [params: [resource: account]])
  94                end
  95
  96     with {:ok, %{status_code: status_code, body: body}} when status_code in 200..299 <- response,
  97          doc <- XML.parse_document(body),
  98          {:ok, data} <- webfinger_from_xml(doc) do
  99       {:ok, data}
 100     else
 101       e ->
 102         Logger.debug("Couldn't finger #{account}.")
 103         Logger.debug(inspect(e))
 104         {:error, e}
 105     end
 106   end
 107 end