git.squeep.com Git - akkoma/blob - lib/pleroma/web/web_finger/web_finger.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.WebFinger do
   6   alias Pleroma.HTTP
   7   alias Pleroma.User
   8   alias Pleroma.Web
   9   alias Pleroma.Web.Federator.Publisher
  10   alias Pleroma.Web.XML
  11   alias Pleroma.XmlBuilder
  12   require Jason
  13   require Logger
  14
  15   def host_meta do
  16     base_url = Web.base_url()
  17
  18     {
  19       :XRD,
  20       %{xmlns: "http://docs.oasis-open.org/ns/xri/xrd-1.0"},
  21       {
  22         :Link,
  23         %{
  24           rel: "lrdd",
  25           type: "application/xrd+xml",
  26           template: "#{base_url}/.well-known/webfinger?resource={uri}"
  27         }
  28       }
  29     }
  30     |> XmlBuilder.to_doc()
  31   end
  32
  33   def webfinger(resource, fmt) when fmt in ["XML", "JSON"] do
  34     host = Pleroma.Web.Endpoint.host()
  35     regex = ~r/(acct:)?(?<username>[a-z0-9A-Z_\.-]+)@#{host}/
  36
  37     with %{"username" => username} <- Regex.named_captures(regex, resource),
  38          %User{} = user <- User.get_cached_by_nickname(username) do
  39       {:ok, represent_user(user, fmt)}
  40     else
  41       _e ->
  42         with %User{} = user <- User.get_cached_by_ap_id(resource) do
  43           {:ok, represent_user(user, fmt)}
  44         else
  45           _e ->
  46             {:error, "Couldn't find user"}
  47         end
  48     end
  49   end
  50
  51   defp gather_links(%User{} = user) do
  52     [
  53       %{
  54         "rel" => "http://webfinger.net/rel/profile-page",
  55         "type" => "text/html",
  56         "href" => user.ap_id
  57       }
  58     ] ++ Publisher.gather_webfinger_links(user)
  59   end
  60
  61   def represent_user(user, "JSON") do
  62     {:ok, user} = User.ensure_keys_present(user)
  63
  64     %{
  65       "subject" => "acct:#{user.nickname}@#{Pleroma.Web.Endpoint.host()}",
  66       "aliases" => [user.ap_id],
  67       "links" => gather_links(user)
  68     }
  69   end
  70
  71   def represent_user(user, "XML") do
  72     {:ok, user} = User.ensure_keys_present(user)
  73
  74     links =
  75       gather_links(user)
  76       |> Enum.map(fn link -> {:Link, link} end)
  77
  78     {
  79       :XRD,
  80       %{xmlns: "http://docs.oasis-open.org/ns/xri/xrd-1.0"},
  81       [
  82         {:Subject, "acct:#{user.nickname}@#{Pleroma.Web.Endpoint.host()}"},
  83         {:Alias, user.ap_id}
  84       ] ++ links
  85     }
  86     |> XmlBuilder.to_doc()
  87   end
  88
  89   defp get_magic_key("data:application/magic-public-key," <> magic_key) do
  90     {:ok, magic_key}
  91   end
  92
  93   defp get_magic_key(nil) do
  94     Logger.debug("Undefined magic key.")
  95     {:ok, nil}
  96   end
  97
  98   defp get_magic_key(_) do
  99     {:error, "Missing magic key data."}
 100   end
 101
 102   defp webfinger_from_xml(doc) do
 103     with magic_key <- XML.string_from_xpath(~s{//Link[@rel="magic-public-key"]/@href}, doc),
 104          {:ok, magic_key} <- get_magic_key(magic_key),
 105          topic <-
 106            XML.string_from_xpath(
 107              ~s{//Link[@rel="http://schemas.google.com/g/2010#updates-from"]/@href},
 108              doc
 109            ),
 110          subject <- XML.string_from_xpath("//Subject", doc),
 111          salmon <- XML.string_from_xpath(~s{//Link[@rel="salmon"]/@href}, doc),
 112          subscribe_address <-
 113            XML.string_from_xpath(
 114              ~s{//Link[@rel="http://ostatus.org/schema/1.0/subscribe"]/@template},
 115              doc
 116            ),
 117          ap_id <-
 118            XML.string_from_xpath(
 119              ~s{//Link[@rel="self" and @type="application/activity+json"]/@href},
 120              doc
 121            ) do
 122       data = %{
 123         "magic_key" => magic_key,
 124         "topic" => topic,
 125         "subject" => subject,
 126         "salmon" => salmon,
 127         "subscribe_address" => subscribe_address,
 128         "ap_id" => ap_id
 129       }
 130
 131       {:ok, data}
 132     else
 133       {:error, e} ->
 134         {:error, e}
 135
 136       e ->
 137         {:error, e}
 138     end
 139   end
 140
 141   defp webfinger_from_json(doc) do
 142     data =
 143       Enum.reduce(doc["links"], %{"subject" => doc["subject"]}, fn link, data ->
 144         case {link["type"], link["rel"]} do
 145           {"application/activity+json", "self"} ->
 146             Map.put(data, "ap_id", link["href"])
 147
 148           {"application/ld+json; profile=\"https://www.w3.org/ns/activitystreams\"", "self"} ->
 149             Map.put(data, "ap_id", link["href"])
 150
 151           {_, "magic-public-key"} ->
 152             "data:application/magic-public-key," <> magic_key = link["href"]
 153             Map.put(data, "magic_key", magic_key)
 154
 155           {"application/atom+xml", "http://schemas.google.com/g/2010#updates-from"} ->
 156             Map.put(data, "topic", link["href"])
 157
 158           {_, "salmon"} ->
 159             Map.put(data, "salmon", link["href"])
 160
 161           {_, "http://ostatus.org/schema/1.0/subscribe"} ->
 162             Map.put(data, "subscribe_address", link["template"])
 163
 164           _ ->
 165             Logger.debug("Unhandled type: #{inspect(link["type"])}")
 166             data
 167         end
 168       end)
 169
 170     {:ok, data}
 171   end
 172
 173   def get_template_from_xml(body) do
 174     xpath = "//Link[@rel='lrdd']/@template"
 175
 176     with doc when doc != :error <- XML.parse_document(body),
 177          template when template != nil <- XML.string_from_xpath(xpath, doc) do
 178       {:ok, template}
 179     end
 180   end
 181
 182   def find_lrdd_template(domain) do
 183     with {:ok, %{status: status, body: body}} when status in 200..299 <-
 184            HTTP.get("http://#{domain}/.well-known/host-meta", []) do
 185       get_template_from_xml(body)
 186     else
 187       _ ->
 188         with {:ok, %{body: body}} <- HTTP.get("https://#{domain}/.well-known/host-meta", []) do
 189           get_template_from_xml(body)
 190         else
 191           e -> {:error, "Can't find LRDD template: #{inspect(e)}"}
 192         end
 193     end
 194   end
 195
 196   @spec finger(String.t()) :: {:ok, map()} | {:error, any()}
 197   def finger(account) do
 198     account = String.trim_leading(account, "@")
 199
 200     domain =
 201       with [_name, domain] <- String.split(account, "@") do
 202         domain
 203       else
 204         _e ->
 205           URI.parse(account).host
 206       end
 207
 208     address =
 209       case find_lrdd_template(domain) do
 210         {:ok, template} ->
 211           String.replace(template, "{uri}", URI.encode(account))
 212
 213         _ ->
 214           "https://#{domain}/.well-known/webfinger?resource=acct:#{account}"
 215       end
 216
 217     with response <-
 218            HTTP.get(
 219              address,
 220              Accept: "application/xrd+xml,application/jrd+json"
 221            ),
 222          {:ok, %{status: status, body: body}} when status in 200..299 <- response do
 223       doc = XML.parse_document(body)
 224
 225       if doc != :error do
 226         webfinger_from_xml(doc)
 227       else
 228         with {:ok, doc} <- Jason.decode(body) do
 229           webfinger_from_json(doc)
 230         end
 231       end
 232     else
 233       e ->
 234         Logger.debug(fn -> "Couldn't finger #{account}" end)
 235         Logger.debug(fn -> inspect(e) end)
 236         {:error, e}
 237     end
 238   end
 239 end