git.squeep.com Git - akkoma/blob - lib/pleroma/web/web_finger/web_finger.ex

   1 defmodule Pleroma.Web.WebFinger do
   2   alias Pleroma.XmlBuilder
   3   alias Pleroma.{Repo, User}
   4   alias Pleroma.Web.{XML, Salmon, OStatus}
   5   require Logger
   6
   7   def host_meta() do
   8     base_url  = Pleroma.Web.base_url
   9     {
  10       :XRD, %{ xmlns: "http://docs.oasis-open.org/ns/xri/xrd-1.0" },
  11       {
  12         :Link, %{ rel: "lrdd", type: "application/xrd+xml", template: "#{base_url}/.well-known/webfinger?resource={uri}"  }
  13       }
  14     }
  15     |> XmlBuilder.to_doc
  16   end
  17
  18   def webfinger(resource) do
  19     host = Pleroma.Web.host
  20     regex = ~r/(acct:)?(?<username>\w+)@#{host}/
  21     case Regex.named_captures(regex, resource) do
  22       %{"username" => username} ->
  23         user = User.get_by_nickname(username)
  24         {:ok, represent_user(user)}
  25       _ -> nil
  26     end
  27   end
  28
  29   def represent_user(user) do
  30     {:ok, user} = ensure_keys_present(user)
  31     {:ok, _private, public} = Salmon.keys_from_pem(user.info["keys"])
  32     magic_key = Salmon.encode_key(public)
  33     {
  34       :XRD, %{xmlns: "http://docs.oasis-open.org/ns/xri/xrd-1.0"},
  35       [
  36         {:Subject, "acct:#{user.nickname}@#{Pleroma.Web.host}"},
  37         {:Alias, user.ap_id},
  38         {:Link, %{rel: "http://schemas.google.com/g/2010#updates-from", type: "application/atom+xml", href: OStatus.feed_path(user)}},
  39         {:Link, %{rel: "salmon", href: OStatus.salmon_path(user)}},
  40         {:Link, %{rel: "magic-public-key", href: "data:application/magic-public-key,#{magic_key}"}}
  41       ]
  42     }
  43     |> XmlBuilder.to_doc
  44   end
  45
  46   def ensure_keys_present(user) do
  47     info = user.info || %{}
  48     if info["keys"] do
  49       {:ok, user}
  50     else
  51       {:ok, pem} = Salmon.generate_rsa_pem
  52       info = Map.put(info, "keys", pem)
  53       Repo.update(Ecto.Changeset.change(user, info: info))
  54     end
  55   end
  56
  57   # FIXME: Make this call the host-meta to find the actual address.
  58   defp webfinger_address(domain) do
  59     "//#{domain}/.well-known/webfinger"
  60   end
  61
  62   defp webfinger_from_xml(doc) do
  63     magic_key = XML.string_from_xpath(~s{//Link[@rel="magic-public-key"]/@href}, doc)
  64     "data:application/magic-public-key," <> magic_key = magic_key
  65     topic = XML.string_from_xpath(~s{//Link[@rel="http://schemas.google.com/g/2010#updates-from"]/@href}, doc)
  66     subject = XML.string_from_xpath("//Subject", doc)
  67     salmon = XML.string_from_xpath(~s{//Link[@rel="salmon"]/@href}, doc)
  68     data = %{
  69       magic_key: magic_key,
  70       topic: topic,
  71       subject: subject,
  72       salmon: salmon
  73     }
  74     {:ok, data}
  75   end
  76
  77   def finger(account, getter \\ &HTTPoison.get/3) do
  78     domain = with [_name, domain] <- String.split(account, "@") do
  79                domain
  80              else _e ->
  81                URI.parse(account).host
  82              end
  83     address = webfinger_address(domain)
  84
  85     # try https first
  86     response = with {:ok, result} <- getter.("https:" <> address, ["Accept": "application/xrd+xml"], [params: [resource: account]]) do
  87                  {:ok, result}
  88                else _ ->
  89                  getter.("http:" <> address, ["Accept": "application/xrd+xml"], [params: [resource: account]])
  90                end
  91
  92     with {:ok, %{status_code: status_code, body: body}} when status_code in 200..299 <- response,
  93          doc <- XML.parse_document(body),
  94          {:ok, data} <- webfinger_from_xml(doc) do
  95       {:ok, data}
  96     else
  97       e ->
  98         Logger.debug("Couldn't finger #{account}.")
  99         Logger.debug(inspect(e))
 100         {:error, e}
 101     end
 102   end
 103 end