git.squeep.com Git - akkoma/blob - lib/pleroma/web/web_finger/web_finger.ex

   1 defmodule Pleroma.Web.WebFinger do
   2   @httpoison Application.get_env(:pleroma, :httpoison)
   3
   4   alias Pleroma.{User, XmlBuilder}
   5   alias Pleroma.Web
   6   alias Pleroma.Web.{XML, Salmon, OStatus}
   7   require Jason
   8   require Logger
   9
  10   def host_meta do
  11     base_url = Web.base_url()
  12
  13     {
  14       :XRD,
  15       %{xmlns: "http://docs.oasis-open.org/ns/xri/xrd-1.0"},
  16       {
  17         :Link,
  18         %{
  19           rel: "lrdd",
  20           type: "application/xrd+xml",
  21           template: "#{base_url}/.well-known/webfinger?resource={uri}"
  22         }
  23       }
  24     }
  25     |> XmlBuilder.to_doc()
  26   end
  27
  28   def webfinger(resource, "JSON") do
  29     host = Pleroma.Web.Endpoint.host()
  30     regex = ~r/(acct:)?(?<username>\w+)@#{host}/
  31
  32     with %{"username" => username} <- Regex.named_captures(regex, resource) do
  33       user = User.get_by_nickname(username)
  34       {:ok, represent_user(user, "JSON")}
  35     else
  36       _e ->
  37         with user when not is_nil(user) <- User.get_cached_by_ap_id(resource) do
  38           {:ok, represent_user(user, "JSON")}
  39         else
  40           _e ->
  41             {:error, "Couldn't find user"}
  42         end
  43     end
  44   end
  45
  46   def webfinger(resource, "XML") do
  47     host = Pleroma.Web.Endpoint.host()
  48     regex = ~r/(acct:)?(?<username>\w+)@#{host}/
  49
  50     with %{"username" => username} <- Regex.named_captures(regex, resource) do
  51       user = User.get_by_nickname(username)
  52       {:ok, represent_user(user, "XML")}
  53     else
  54       _e ->
  55         with user when not is_nil(user) <- User.get_cached_by_ap_id(resource) do
  56           {:ok, represent_user(user, "XML")}
  57         else
  58           _e ->
  59             {:error, "Couldn't find user"}
  60         end
  61     end
  62   end
  63
  64   def represent_user(user, "JSON") do
  65     {:ok, user} = ensure_keys_present(user)
  66     {:ok, _private, public} = Salmon.keys_from_pem(user.info["keys"])
  67     magic_key = Salmon.encode_key(public)
  68
  69     %{
  70       "subject" => "acct:#{user.nickname}@#{Pleroma.Web.Endpoint.host()}",
  71       "aliases" => [user.ap_id],
  72       "links" => [
  73         %{
  74           "rel" => "http://schemas.google.com/g/2010#updates-from",
  75           "type" => "application/atom+xml",
  76           "href" => OStatus.feed_path(user)
  77         },
  78         %{
  79           "rel" => "http://webfinger.net/rel/profile-page",
  80           "type" => "text/html",
  81           "href" => user.ap_id
  82         },
  83         %{"rel" => "salmon", "href" => OStatus.salmon_path(user)},
  84         %{
  85           "rel" => "magic-public-key",
  86           "href" => "data:application/magic-public-key,#{magic_key}"
  87         },
  88         %{"rel" => "self", "type" => "application/activity+json", "href" => user.ap_id},
  89         %{
  90           "rel" => "self",
  91           "type" => "application/ld+json; profile=\"https://www.w3.org/ns/activitystreams\"",
  92           "href" => user.ap_id
  93         },
  94         %{
  95           "rel" => "http://ostatus.org/schema/1.0/subscribe",
  96           "template" => OStatus.remote_follow_path()
  97         }
  98       ]
  99     }
 100   end
 101
 102   def represent_user(user, "XML") do
 103     {:ok, user} = ensure_keys_present(user)
 104     {:ok, _private, public} = Salmon.keys_from_pem(user.info["keys"])
 105     magic_key = Salmon.encode_key(public)
 106
 107     {
 108       :XRD,
 109       %{xmlns: "http://docs.oasis-open.org/ns/xri/xrd-1.0"},
 110       [
 111         {:Subject, "acct:#{user.nickname}@#{Pleroma.Web.Endpoint.host()}"},
 112         {:Alias, user.ap_id},
 113         {:Link,
 114          %{
 115            rel: "http://schemas.google.com/g/2010#updates-from",
 116            type: "application/atom+xml",
 117            href: OStatus.feed_path(user)
 118          }},
 119         {:Link,
 120          %{rel: "http://webfinger.net/rel/profile-page", type: "text/html", href: user.ap_id}},
 121         {:Link, %{rel: "salmon", href: OStatus.salmon_path(user)}},
 122         {:Link,
 123          %{rel: "magic-public-key", href: "data:application/magic-public-key,#{magic_key}"}},
 124         {:Link, %{rel: "self", type: "application/activity+json", href: user.ap_id}},
 125         {:Link,
 126          %{rel: "http://ostatus.org/schema/1.0/subscribe", template: OStatus.remote_follow_path()}}
 127       ]
 128     }
 129     |> XmlBuilder.to_doc()
 130   end
 131
 132   # This seems a better fit in Salmon
 133   def ensure_keys_present(user) do
 134     info = user.info || %{}
 135
 136     if info["keys"] do
 137       {:ok, user}
 138     else
 139       {:ok, pem} = Salmon.generate_rsa_pem()
 140       info = Map.put(info, "keys", pem)
 141
 142       Ecto.Changeset.change(user, info: info)
 143       |> User.update_and_set_cache()
 144     end
 145   end
 146
 147   defp get_magic_key(magic_key) do
 148     "data:application/magic-public-key," <> magic_key = magic_key
 149     {:ok, magic_key}
 150   rescue
 151     MatchError -> {:error, "Missing magic key data."}
 152   end
 153
 154   defp webfinger_from_xml(doc) do
 155     with magic_key <- XML.string_from_xpath(~s{//Link[@rel="magic-public-key"]/@href}, doc),
 156          {:ok, magic_key} <- get_magic_key(magic_key),
 157          topic <-
 158            XML.string_from_xpath(
 159              ~s{//Link[@rel="http://schemas.google.com/g/2010#updates-from"]/@href},
 160              doc
 161            ),
 162          subject <- XML.string_from_xpath("//Subject", doc),
 163          salmon <- XML.string_from_xpath(~s{//Link[@rel="salmon"]/@href}, doc),
 164          subscribe_address <-
 165            XML.string_from_xpath(
 166              ~s{//Link[@rel="http://ostatus.org/schema/1.0/subscribe"]/@template},
 167              doc
 168            ),
 169          ap_id <-
 170            XML.string_from_xpath(
 171              ~s{//Link[@rel="self" and @type="application/activity+json"]/@href},
 172              doc
 173            ) do
 174       data = %{
 175         "magic_key" => magic_key,
 176         "topic" => topic,
 177         "subject" => subject,
 178         "salmon" => salmon,
 179         "subscribe_address" => subscribe_address,
 180         "ap_id" => ap_id
 181       }
 182
 183       {:ok, data}
 184     else
 185       {:error, e} ->
 186         {:error, e}
 187
 188       e ->
 189         {:error, e}
 190     end
 191   end
 192
 193   defp webfinger_from_json(doc) do
 194     data =
 195       Enum.reduce(doc["links"], %{"subject" => doc["subject"]}, fn link, data ->
 196         case {link["type"], link["rel"]} do
 197           {"application/activity+json", "self"} ->
 198             Map.put(data, "ap_id", link["href"])
 199
 200           {"application/ld+json; profile=\"https://www.w3.org/ns/activitystreams\"", "self"} ->
 201             Map.put(data, "ap_id", link["href"])
 202
 203           {_, "magic-public-key"} ->
 204             "data:application/magic-public-key," <> magic_key = link["href"]
 205             Map.put(data, "magic_key", magic_key)
 206
 207           {"application/atom+xml", "http://schemas.google.com/g/2010#updates-from"} ->
 208             Map.put(data, "topic", link["href"])
 209
 210           {_, "salmon"} ->
 211             Map.put(data, "salmon", link["href"])
 212
 213           {_, "http://ostatus.org/schema/1.0/subscribe"} ->
 214             Map.put(data, "subscribe_address", link["template"])
 215
 216           _ ->
 217             Logger.debug("Unhandled type: #{inspect(link["type"])}")
 218             data
 219         end
 220       end)
 221
 222     {:ok, data}
 223   end
 224
 225   def get_template_from_xml(body) do
 226     xpath = "//Link[@rel='lrdd']/@template"
 227
 228     with doc when doc != :error <- XML.parse_document(body),
 229          template when template != nil <- XML.string_from_xpath(xpath, doc) do
 230       {:ok, template}
 231     end
 232   end
 233
 234   def find_lrdd_template(domain) do
 235     with {:ok, %{status_code: status_code, body: body}} when status_code in 200..299 <-
 236            @httpoison.get("http://#{domain}/.well-known/host-meta", [], follow_redirect: true) do
 237       get_template_from_xml(body)
 238     else
 239       _ ->
 240         with {:ok, %{body: body}} <- @httpoison.get("https://#{domain}/.well-known/host-meta", []) do
 241           get_template_from_xml(body)
 242         else
 243           e -> {:error, "Can't find LRDD template: #{inspect(e)}"}
 244         end
 245     end
 246   end
 247
 248   def finger(account) do
 249     account = String.trim_leading(account, "@")
 250
 251     domain =
 252       with [_name, domain] <- String.split(account, "@") do
 253         domain
 254       else
 255         _e ->
 256           URI.parse(account).host
 257       end
 258
 259     address =
 260       case find_lrdd_template(domain) do
 261         {:ok, template} ->
 262           String.replace(template, "{uri}", URI.encode(account))
 263
 264         _ ->
 265           "https://#{domain}/.well-known/webfinger?resource=acct:#{account}"
 266       end
 267
 268     with response <-
 269            @httpoison.get(
 270              address,
 271              [Accept: "application/xrd+xml,application/jrd+json"],
 272              follow_redirect: true
 273            ),
 274          {:ok, %{status_code: status_code, body: body}} when status_code in 200..299 <- response do
 275       doc = XML.parse_document(body)
 276
 277       if doc != :error do
 278         webfinger_from_xml(doc)
 279       else
 280         with {:ok, doc} <- Jason.decode(body) do
 281           webfinger_from_json(doc)
 282         else
 283           {:error, e} -> e
 284         end
 285       end
 286     else
 287       e ->
 288         Logger.debug(fn -> "Couldn't finger #{account}" end)
 289         Logger.debug(fn -> inspect(e) end)
 290         {:error, e}
 291     end
 292   end
 293 end