git.squeep.com Git - akkoma/blob - lib/pleroma/web/web_finger/web_finger.ex

   1 defmodule Pleroma.Web.WebFinger do
   2   @httpoison Application.get_env(:pleroma, :httpoison)
   3
   4   alias Pleroma.{User, XmlBuilder}
   5   alias Pleroma.Web
   6   alias Pleroma.Web.{XML, Salmon, OStatus}
   7   require Jason
   8   require Logger
   9
  10   def host_meta do
  11     base_url = Web.base_url()
  12
  13     {
  14       :XRD,
  15       %{xmlns: "http://docs.oasis-open.org/ns/xri/xrd-1.0"},
  16       {
  17         :Link,
  18         %{
  19           rel: "lrdd",
  20           type: "application/xrd+xml",
  21           template: "#{base_url}/.well-known/webfinger?resource={uri}"
  22         }
  23       }
  24     }
  25     |> XmlBuilder.to_doc()
  26   end
  27
  28   def webfinger(resource, "JSON") do
  29     host = Pleroma.Web.Endpoint.host()
  30     regex = ~r/(acct:)?(?<username>\w+)@#{host}/
  31
  32     with %{"username" => username} <- Regex.named_captures(regex, resource) do
  33       user = User.get_by_nickname(username)
  34       {:ok, represent_user(user, "JSON")}
  35     else
  36       _e ->
  37         with user when not is_nil(user) <- User.get_cached_by_ap_id(resource) do
  38           {:ok, represent_user(user, "JSON")}
  39         else
  40           _e ->
  41             {:error, "Couldn't find user"}
  42         end
  43     end
  44   end
  45
  46   def webfinger(resource, "XML") do
  47     host = Pleroma.Web.Endpoint.host()
  48     regex = ~r/(acct:)?(?<username>\w+)@#{host}/
  49
  50     with %{"username" => username} <- Regex.named_captures(regex, resource) do
  51       user = User.get_by_nickname(username)
  52       {:ok, represent_user(user, "XML")}
  53     else
  54       _e ->
  55         with user when not is_nil(user) <- User.get_cached_by_ap_id(resource) do
  56           {:ok, represent_user(user, "XML")}
  57         else
  58           _e ->
  59             {:error, "Couldn't find user"}
  60         end
  61     end
  62   end
  63
  64   def represent_user(user, "JSON") do
  65     {:ok, user} = ensure_keys_present(user)
  66     {:ok, _private, public} = Salmon.keys_from_pem(user.info["keys"])
  67     magic_key = Salmon.encode_key(public)
  68
  69     %{
  70       "subject" => "acct:#{user.nickname}@#{Pleroma.Web.Endpoint.host()}",
  71       "aliases" => [user.ap_id],
  72       "links" => [
  73         %{
  74           "rel" => "http://schemas.google.com/g/2010#updates-from",
  75           "type" => "application/atom+xml",
  76           "href" => OStatus.feed_path(user)
  77         },
  78         %{
  79           "rel" => "http://webfinger.net/rel/profile-page",
  80           "type" => "text/html",
  81           "href" => user.ap_id
  82         },
  83         %{"rel" => "salmon", "href" => OStatus.salmon_path(user)},
  84         %{
  85           "rel" => "magic-public-key",
  86           "href" => "data:application/magic-public-key,#{magic_key}"
  87         },
  88         %{"rel" => "self", "type" => "application/activity+json", "href" => user.ap_id},
  89         %{"rel" => "self", "type" => "application/ld+json; profile=\"https://www.w3.org/ns/activitystreams\"", "href" => user.ap_id},
  90         %{
  91           "rel" => "http://ostatus.org/schema/1.0/subscribe",
  92           "template" => OStatus.remote_follow_path()
  93         }
  94       ]
  95     }
  96   end
  97
  98   def represent_user(user, "XML") do
  99     {:ok, user} = ensure_keys_present(user)
 100     {:ok, _private, public} = Salmon.keys_from_pem(user.info["keys"])
 101     magic_key = Salmon.encode_key(public)
 102
 103     {
 104       :XRD,
 105       %{xmlns: "http://docs.oasis-open.org/ns/xri/xrd-1.0"},
 106       [
 107         {:Subject, "acct:#{user.nickname}@#{Pleroma.Web.Endpoint.host()}"},
 108         {:Alias, user.ap_id},
 109         {:Link,
 110          %{
 111            rel: "http://schemas.google.com/g/2010#updates-from",
 112            type: "application/atom+xml",
 113            href: OStatus.feed_path(user)
 114          }},
 115         {:Link,
 116          %{rel: "http://webfinger.net/rel/profile-page", type: "text/html", href: user.ap_id}},
 117         {:Link, %{rel: "salmon", href: OStatus.salmon_path(user)}},
 118         {:Link,
 119          %{rel: "magic-public-key", href: "data:application/magic-public-key,#{magic_key}"}},
 120         {:Link, %{rel: "self", type: "application/activity+json", href: user.ap_id}},
 121         {:Link,
 122          %{rel: "http://ostatus.org/schema/1.0/subscribe", template: OStatus.remote_follow_path()}}
 123       ]
 124     }
 125     |> XmlBuilder.to_doc()
 126   end
 127
 128   # This seems a better fit in Salmon
 129   def ensure_keys_present(user) do
 130     info = user.info || %{}
 131
 132     if info["keys"] do
 133       {:ok, user}
 134     else
 135       {:ok, pem} = Salmon.generate_rsa_pem()
 136       info = Map.put(info, "keys", pem)
 137
 138       Ecto.Changeset.change(user, info: info)
 139       |> User.update_and_set_cache()
 140     end
 141   end
 142
 143   defp webfinger_from_xml(doc) do
 144     magic_key = XML.string_from_xpath(~s{//Link[@rel="magic-public-key"]/@href}, doc)
 145     "data:application/magic-public-key," <> magic_key = magic_key
 146
 147     topic =
 148       XML.string_from_xpath(
 149         ~s{//Link[@rel="http://schemas.google.com/g/2010#updates-from"]/@href},
 150         doc
 151       )
 152
 153     subject = XML.string_from_xpath("//Subject", doc)
 154     salmon = XML.string_from_xpath(~s{//Link[@rel="salmon"]/@href}, doc)
 155
 156     subscribe_address =
 157       XML.string_from_xpath(
 158         ~s{//Link[@rel="http://ostatus.org/schema/1.0/subscribe"]/@template},
 159         doc
 160       )
 161
 162     ap_id =
 163       XML.string_from_xpath(
 164         ~s{//Link[@rel="self" and @type="application/activity+json"]/@href},
 165         doc
 166       )
 167
 168     data = %{
 169       "magic_key" => magic_key,
 170       "topic" => topic,
 171       "subject" => subject,
 172       "salmon" => salmon,
 173       "subscribe_address" => subscribe_address,
 174       "ap_id" => ap_id
 175     }
 176
 177     {:ok, data}
 178   end
 179
 180   defp webfinger_from_json(doc) do
 181     data =
 182       Enum.reduce(doc["links"], %{"subject" => doc["subject"]}, fn link, data ->
 183         case {link["type"], link["rel"]} do
 184           {"application/activity+json", "self"} ->
 185             Map.put(data, "ap_id", link["href"])
 186
 187           {"application/ld+json; profile=\"https://www.w3.org/ns/activitystreams\"", "self"} ->
 188             Map.put(data, "ap_id", link["href"])
 189
 190           {_, "magic-public-key"} ->
 191             "data:application/magic-public-key," <> magic_key = link["href"]
 192             Map.put(data, "magic_key", magic_key)
 193
 194           {"application/atom+xml", "http://schemas.google.com/g/2010#updates-from"} ->
 195             Map.put(data, "topic", link["href"])
 196
 197           {_, "salmon"} ->
 198             Map.put(data, "salmon", link["href"])
 199
 200           {_, "http://ostatus.org/schema/1.0/subscribe"} ->
 201             Map.put(data, "subscribe_address", link["template"])
 202
 203           _ ->
 204             Logger.debug("Unhandled type: #{inspect(link["type"])}")
 205             data
 206         end
 207       end)
 208
 209     {:ok, data}
 210   end
 211
 212   def get_template_from_xml(body) do
 213     xpath = "//Link[@rel='lrdd' and @type='application/xrd+xml']/@template"
 214
 215     with doc when doc != :error <- XML.parse_document(body),
 216          template when template != nil <- XML.string_from_xpath(xpath, doc) do
 217       {:ok, template}
 218     end
 219   end
 220
 221   def find_lrdd_template(domain) do
 222     with {:ok, %{status_code: status_code, body: body}} when status_code in 200..299 <-
 223            @httpoison.get("http://#{domain}/.well-known/host-meta", [], follow_redirect: true) do
 224       get_template_from_xml(body)
 225     else
 226       _ ->
 227         with {:ok, %{body: body}} <- @httpoison.get("https://#{domain}/.well-known/host-meta", []) do
 228           get_template_from_xml(body)
 229         else
 230           e -> {:error, "Can't find LRDD template: #{inspect(e)}"}
 231         end
 232     end
 233   end
 234
 235   def finger(account) do
 236     account = String.trim_leading(account, "@")
 237
 238     domain =
 239       with [_name, domain] <- String.split(account, "@") do
 240         domain
 241       else
 242         _e ->
 243           URI.parse(account).host
 244       end
 245
 246     address =
 247       case find_lrdd_template(domain) do
 248         {:ok, template} ->
 249           String.replace(template, "{uri}", URI.encode(account))
 250
 251         _ ->
 252           "http://#{domain}/.well-known/webfinger?resource=acct:#{account}"
 253       end
 254
 255     with response <-
 256            @httpoison.get(
 257              address,
 258              [Accept: "application/xrd+xml,application/jrd+json"],
 259              follow_redirect: true
 260            ),
 261          {:ok, %{status_code: status_code, body: body}} when status_code in 200..299 <- response do
 262       doc = XML.parse_document(body)
 263
 264       if doc != :error do
 265         webfinger_from_xml(doc)
 266       else
 267         {:ok, doc} = Jason.decode(body)
 268         webfinger_from_json(doc)
 269       end
 270     else
 271       e ->
 272         Logger.debug(fn -> "Couldn't finger #{account}" end)
 273         Logger.debug(fn -> inspect(e) end)
 274         {:error, e}
 275     end
 276   end
 277 end