git.squeep.com Git - akkoma/blob - lib/pleroma/web/web_finger/web_finger.ex

   1 defmodule Pleroma.Web.WebFinger do
   2   @httpoison Application.get_env(:pleroma, :httpoison)
   3
   4   alias Pleroma.{Repo, User, XmlBuilder}
   5   alias Pleroma.Web
   6   alias Pleroma.Web.{XML, Salmon, OStatus}
   7   require Logger
   8
   9   def host_meta do
  10     base_url  = Web.base_url
  11     {
  12       :XRD, %{xmlns: "http://docs.oasis-open.org/ns/xri/xrd-1.0"},
  13       {
  14         :Link, %{rel: "lrdd", type: "application/xrd+xml", template: "#{base_url}/.well-known/webfinger?resource={uri}"}
  15       }
  16     }
  17     |> XmlBuilder.to_doc
  18   end
  19
  20   def webfinger(resource) do
  21     host = Pleroma.Web.Endpoint.host
  22     regex = ~r/(acct:)?(?<username>\w+)@#{host}/
  23     with %{"username" => username} <- Regex.named_captures(regex, resource) do
  24       user = User.get_by_nickname(username)
  25       {:ok, represent_user(user)}
  26     else _e ->
  27       with user when not is_nil(user) <- User.get_cached_by_ap_id(resource) do
  28         {:ok, represent_user(user)}
  29       else _e ->
  30         {:error, "Couldn't find user"}
  31       end
  32     end
  33   end
  34
  35   def represent_user(user) do
  36     {:ok, user} = ensure_keys_present(user)
  37     {:ok, _private, public} = Salmon.keys_from_pem(user.info["keys"])
  38     magic_key = Salmon.encode_key(public)
  39     {
  40       :XRD, %{xmlns: "http://docs.oasis-open.org/ns/xri/xrd-1.0"},
  41       [
  42         {:Subject, "acct:#{user.nickname}@#{Pleroma.Web.Endpoint.host}"},
  43         {:Alias, user.ap_id},
  44         {:Link, %{rel: "http://schemas.google.com/g/2010#updates-from", type: "application/atom+xml", href: OStatus.feed_path(user)}},
  45         {:Link, %{rel: "http://webfinger.net/rel/profile-page", type: "text/html", href: user.ap_id}},
  46         {:Link, %{rel: "salmon", href: OStatus.salmon_path(user)}},
  47         {:Link, %{rel: "magic-public-key", href: "data:application/magic-public-key,#{magic_key}"}},
  48         {:Link, %{rel: "http://ostatus.org/schema/1.0/subscribe", template: OStatus.remote_follow_path()}}
  49       ]
  50     }
  51     |> XmlBuilder.to_doc
  52   end
  53
  54   # This seems a better fit in Salmon
  55   def ensure_keys_present(user) do
  56     info = user.info || %{}
  57     if info["keys"] do
  58       {:ok, user}
  59     else
  60       {:ok, pem} = Salmon.generate_rsa_pem
  61       info = Map.put(info, "keys", pem)
  62       Repo.update(Ecto.Changeset.change(user, info: info))
  63     end
  64   end
  65
  66   defp webfinger_from_xml(doc) do
  67     magic_key = XML.string_from_xpath(~s{//Link[@rel="magic-public-key"]/@href}, doc)
  68     "data:application/magic-public-key," <> magic_key = magic_key
  69     topic = XML.string_from_xpath(~s{//Link[@rel="http://schemas.google.com/g/2010#updates-from"]/@href}, doc)
  70     subject = XML.string_from_xpath("//Subject", doc)
  71     salmon = XML.string_from_xpath(~s{//Link[@rel="salmon"]/@href}, doc)
  72     data = %{
  73       "magic_key" => magic_key,
  74       "topic" => topic,
  75       "subject" => subject,
  76       "salmon" => salmon
  77     }
  78     {:ok, data}
  79   end
  80
  81   def get_template_from_xml(body) do
  82     xpath = "//Link[@rel='lrdd' and @type='application/xrd+xml']/@template"
  83     with doc when doc != :error <- XML.parse_document(body),
  84       template when template != nil <- XML.string_from_xpath(xpath, doc) do
  85       {:ok, template}
  86     end
  87   end
  88
  89   def find_lrdd_template(domain) do
  90     with {:ok, %{status_code: status_code, body: body}} when status_code in 200..299 <- @httpoison.get("http://#{domain}/.well-known/host-meta", [], follow_redirect: true) do
  91       get_template_from_xml(body)
  92     else
  93       _ ->
  94         with {:ok, %{body: body}} <- @httpoison.get("https://#{domain}/.well-known/host-meta", []) do
  95           get_template_from_xml(body)
  96         else
  97           e -> {:error, "Can't find lrdd template: #{inspect(e)}"}
  98         end
  99     end
 100   end
 101
 102   def finger(account) do
 103     domain = with [_name, domain] <- String.split(account, "@") do
 104                domain
 105              else _e ->
 106                URI.parse(account).host
 107              end
 108
 109     with {:ok, template} <- find_lrdd_template(domain),
 110          address <- String.replace(template, "{uri}", URI.encode(account)),
 111          response <- @httpoison.get(address, ["Accept": "application/xrd+xml"]),
 112          {:ok, %{status_code: status_code, body: body}} when status_code in 200..299 <- response,
 113          doc when doc != :error<- XML.parse_document(body),
 114          {:ok, data} <- webfinger_from_xml(doc) do
 115       {:ok, data}
 116     else
 117       e ->
 118         Logger.debug(fn -> "Couldn't finger #{account}." end)
 119         Logger.debug(fn -> inspect(e) end)
 120         {:error, e}
 121     end
 122   end
 123 end